Envío de correos con INDY9

[mRoman]

Empezado por Neftali [Germán.Estévez]

A ver si te ayuda este hilo:
https://www.clubdelphi.com/foros/showthread.php?t=96482

En las especificaciones de la versión también debería especifocar algo sobre TLS

Gracias German.

Lo cheque..pero en realidad no entiendo mucho, instalar DLL, librerias...en algunas páginas que he consultado mencionan un EXE de instalación, super mas comodo, pero ya no está disponible la página, sería mas fácil la instalación.

En fin...se esta complicando un poco esto de envíar correos con delphi.

Seguiré buscando la solución.

[mRoman]

Hola de nuevo...

Ya me conseguí los Indy10, pero ahora como se instalan??. En el foro hay unas instrucciones pero consulto el link que dice ahi y ya no hay nada....

https://www.clubdelphi.com/foros/showthread.php?t=66412

Del "tocayo" Román.

Y los pude bajar de aqui, pero no se como se instalan...con los Indy9 habia unos dpk, pero aqui en esta version nos los veo.

Vamos amigos...despues de 18 años aprox programando en Delphi, no me he atorado con nada....hasta ahora, espero que no. Hasta ahorita todo lo he resulto con Delphi, no quiero que esto de envío de correo sea el primero en no poderlo resolver con delphi.

Saludos.

[Casimiro Notevi]

Instalar las indy lleva su tiempo porque tienes que asegurarte antes de haber eliminado absolutamente todo lo que exista de la versión que tengas instalada.
Te aconsejo una buena copia de seguridad de lo que tienes antes de seguir.
La descarga y la documentación sobre la instalación las puedes encontrar aquí:
https://www.indyproject.org/download/v10/
La documentación está en varios formatos:
https://www.indyproject.org/documentation/
Te copio una captura de pantalla con los parámetros con los que está funcionando con gmail.

Si tienes cualquier duda, pregunta.

[Casimiro Notevi]

Y no olvides las DLL actualizadas también.
Aquí están.

[Casimiro Notevi]

Yo probaría antes con la que tienes instalada, la v9, porque vayas a estropear tu delphi 6 intentando instalar la v10 y te quedes sin una y sin la otra.
En mi caso la v10 está instalada en un delphi 2007

[mRoman]

Empezado por Casimiro Notevi

Yo probaría antes con la que tienes instalada, la v9, porque vayas a estropear tu delphi 6 intentando instalar la v10 y te quedes sin una y sin la otra.
En mi caso la v10 está instalada en un delphi 2007

Hola Casimiro...demasiado tarde tu comentario. Ya desinstale la 9....

Espero poder reinstalar...

[Casimiro Notevi]

Empezado por mRoman

Hola Casimiro...demasiado tarde tu comentario. Ya desinstale la 9....
Espero poder reinstalar...

También te dije antes de nada: "Te aconsejo una buena copia de seguridad de lo que tienes antes de seguir."


Espero que te sea leve el proceso.

[mRoman]

Empezado por mRoman

Hola Casimiro...demasiado tarde tu comentario. Ya desinstale la 9....

Espero poder reinstalar...

Logré instalar nuevamente los componentes Indy9...

[mRoman]

Empezado por Casimiro Notevi

Y no olvides las DLL actualizadas también.
Aquí están.

Y donde las debo de copiar/instalar...se copian solamente?...y en donde?

[Casimiro Notevi]

Empezado por mRoman

Y donde las debo de copiar/instalar...se copian solamente?...y en donde?

Junto a tu ejecutable.

[mRoman]

Empezado por Casimiro Notevi

Instalar las indy lleva su tiempo porque tienes que asegurarte antes de haber eliminado absolutamente todo lo que exista de la versión que tengas instalada.
Te aconsejo una buena copia de seguridad de lo que tienes antes de seguir.
La descarga y la documentación sobre la instalación las puedes encontrar aquí:
https://www.indyproject.org/download/v10/
La documentación está en varios formatos:
https://www.indyproject.org/documentation/
Te copio una captura de pantalla con los parámetros con los que está funcionando con gmail.

Si tienes cualquier duda, pregunta.

Casimiro...lamento decirte que los links ya no accesan a la documentación, me envía un aviso de error que dice "No se puede acceder a este sitio"...

[Casimiro Notevi]

Empezado por mRoman

Casimiro...lamento decirte que los links ya no accesan a la documentación, me envía un aviso de error que dice "No se puede acceder a este sitio"...

Pero también están en la página de github
https://github.com/IndySockets/Indy/wiki
Ahí a la derecha tienes la wiki, la documentación y la "updating indy", está todo, lo acabo de comprobar.

[mRoman]

Si refieres a los de la pantalla q enviaste...como se los defino al componente?.

Intente esto:

Código Delphi [-]
         with smtp do
     begin
          Port := 587;
          Host := 'smtp.gmail.com';
          AuthenticationType := atLogin;
          UserId:='correo@origen.com';
          Password := 'fayhxquevbflre';
          IOHandler := SSL;
          UseTLS:=utUseExplicitTLS;
     end;

Me salen estos errores...

[Error] ImprimirEnviarTCK.pas(99): Undeclared identifier: 'IOHandler'
[Error] ImprimirEnviarTCK.pas(99): Undeclared identifier: 'SSL'
[Error] ImprimirEnviarTCK.pas(100): Undeclared identifier: 'UseTLS'
[Fatal Error] Laundry.dpr(104): Could not compile used unit 'ImprimirEnviarTCK.pas'

Ahora...si estos erroes tienen q ver con las DLL q me enviaste, como las actualizo o copio y en donde?

Gracias Casimiro.

[Casimiro Notevi]

Mira si te sirve de ejemplo:

Código Delphi [-]
// Es la función que nos permite enviar el Mail con Indy 10. 
// en la cabecera están definidos los parámetros 
function SendEmailIndy10(AEmailEnvio:string; AListaAdjuntos: TStringList; 
                         AHostSMTP: string; APortSMTP: Integer; 
                         AAsunto: string; ACuerpoMensaje: string; 
                         ANombreUsuario: string; APasswordUsuario: string; 
                         AFromText:string; 
                         AListaParametros:TStrings; 
                         AListaParamsDB:TStrings; 
                         AListaParamsIMG:TStrings; 
                         tls:TIdUseTLS; 
                         sslVersion:TIdSSLVersion; 
                         AFormatoPlano:boolean; 
                         var outMessage:String; 
                         procStatus:TidStatusEvent=nil): integer; 
var 
    ServidorSMTP: TIdSmtp; 
    sslHandler: TIdSSLIOHandlerSocketOpenSSL; 
    Mensaje: TIdMessage; 
    idText: TIdText; 
    i: Integer; 
    TS:TStrings; 
begin 
    // ini 
    Result := 0; 
    outMessage := ''; 
 
    // Creamos los objetos y componentes necesarios 
    ServidorSMTP := TIdSmtp.Create(nil); 
    sslHandler := TIdSSLIOHandlerSocketOpenSSL.Create(nil); 
    Mensaje := TIdMessage.Create(nil); 
 
    // proteccion para liberar 
    try 
        // Si la lista de paámetros está asignada, los sustituimos por los valores 
        if Assigned(AListaParametros) then begin 
          ACuerpoMensaje := SustituirParametros(ACuerpoMensaje, AListaParametros); 
        end; 
        // Si recibimos parámetros dinámicos de la BD, los sustituimos por los valores 
        if Assigned(AListaParamsDB) then begin 
          ACuerpoMensaje := SustituirParametros(ACuerpoMensaje, AListaParamsDB); 
        end; 
        // si recibimos alguna imagen en la lista, la sustituimos por sus urls 
        if Assigned(AListaParamsIMG) then begin 
          if not(AFormatoPlano) then  // si no es texto, sino que sí es html... 
            ACuerpoMensaje := SustituirParametrosImagen(ACuerpoMensaje, AListaParamsIMG); 
        end; 
        // 
        // Proteccion para liberar 
        try 
            // configuraciones básicas para el server SMTP 
            ServidorSMTP.Host := AHostSMTP; 
            ServidorSMTP.Port := APortSMTP; 
            ServidorSMTP.Username := ANombreUsuario; 
            ServidorSMTP.Password := APasswordUsuario; 
 
            // Timeout; Necesario para algunas versiones de las Indy 
            ServidorSMTP.ReadTimeout := 30000; 
 
            // Procedimientos de Callback (opcionales) 
            ServidorSMTP.OnStatus := procStatus; 
 
            //·································································· 
            // Podríamos llegar a usarlos, pero no es necesario... de momento 
            // ServidorSMTP..OnConnected :=IdSMTP1Connected; 
            // ServidorSMTP..OnDisconnected :=IdSMTP1Disconnected; 
            // ServidorSMTP..OnFailedRecipient :=IdSMTP1FailedRecipient; 
            // ServidorSMTP..OnStatus :=IdSMTP1Status; 
            // ServidorSMTP..OnTLSNotAvailable :=IdSMTP1TLSNotAvailable; 
            // ServidorSMTP..OnWork :=IdSMTP1Work; 
            //·································································· 
 
            // Cambios segun si el server soporta o no TSL 
            if (tls <> utNoTLSSupport) then 
            begin   // Valores estandard 
              sslHandler.Destination := AHostSMTP + ':' + IntToStr(APortSMTP); 
              sslHandler.Host := AHostSMTP; 
              sslHandler.Port := APortSMTP; 
              sslHandler.SSLOptions.Method := sslVersion; 
              sslHandler.ReadTimeout := 30000; 
              ServidorSMTP.IOHandler := sslHandler; 
              ServidorSMTP.UseTLS := tls; 
            end; 
 
            // Configuración básica del mensaje 
            Mensaje.From.Address := ANombreUsuario; 
            Mensaje.From.Text := AFromText; 
            Mensaje.Recipients.EMailAddresses := AEmailEnvio; 
            Mensaje.Subject := AAsunto; 
            Mensaje.ContentType := 'multipart/mixed'; 
 
            // Preparamos lo necesario para "montar" el cuerpo del mensaje 
            TS := TStringList.Create(); 
            // protección para liberar 
            try 
              TS.Text := ACuerpoMensaje; 
 
              // Si estamos en modo texto? 
              if (AFormatoPlano) then begin 
                idText := TIdText.Create(Mensaje.MessageParts, TS); 
                idText.ContentType := 'text/plain'; 
              end 
              else begin 
                idText := TIdText.Create(Mensaje.MessageParts, TS); 
                idText.ContentType := 'text/html'; 
                idText.ContentTransfer := '7bit'; 
                Mensaje.ContentTransferEncoding := 'text/html'; 
              end; 
            finally 
              FreeAndNil(TS); 
            end; 
 
            // Asignada la lista de ficheros Adjuntos? 
            if Assigned(AListaAdjuntos) then begin 
              // recorer la lista y añadir los ficheros... 
              for i := 0 to (AListaAdjuntos.Count - 1) do begin 
                // si existe, lo añadimos... 
                if FileExists(AListaAdjuntos[i]) then begin 
                  TIdAttachmentFile.Create(Mensaje.MessageParts, AListaAdjuntos[i]); 
                end; 
              end; 
            end; 
 
            // proteccion para la conexion 
            try 
              ServidorSMTP.Connect;                          // PASO 1: conexion 
              // proteccion para el envio 
              try 
                ServidorSMTP.Send(Mensaje);                 // PASO 2 : envío 
                //-Debug- showmessage('El mensaje se envió correctamente'); 
                Result := Result + ID_ENVIO_OK;  // OK 
              except 
                on E:Exception do begin 
                  //-Debug- showmessage('Se produjo un fallo durante el envío del mensaje; ' + sLineBreak + E.Message); 
                  Result := ID_ENVIO_ERROR_ENVIO {-20}; 
                  outMessage := rsErrorAlEnviar + E.Message; 
                end; 
              end; 
            except 
              on E:Exception do begin 
                //-Debug- showmessage('Se produjo un fallo durante la conexión con el servidor; ' + sLineBreak + E.Message); 
                Result := ID_ENVIO_ERROR_CONEXION {-10}; 
                outMessage := rsErrorAlConectar + E.Message; 
              end; 
            end; 
 
            //si nos hemos conectado correctamente, al finalizar, desconectamos,... 
            if (ServidorSMTP.Connected) then begin 
              ServidorSMTP.Disconnect;                    // PASO3: desconexion 
            end; 
        finally 
          // Liberar los componentes creados 
          Mensaje.Free; 
          sslHandler.Free; 
          ServidorSMTP.Free; 
        end; 
      except 
        // en caso de excepción "desconocida" devolvemos esto... 
        on E:exception do begin 
          Result := -1; // desconocido 
          outMessage := rsErrorDesconocido + E.Message; 
        end; 
    end; 
end;

[mRoman]

Empezado por Casimiro Notevi

Mira si te sirve de ejemplo:

Código Delphi [-]
// Es la función que nos permite enviar el Mail con Indy 10. 
// en la cabecera están definidos los parámetros 
function SendEmailIndy10(AEmailEnvio:string; AListaAdjuntos: TStringList; 
                         AHostSMTP: string; APortSMTP: Integer; 
                         AAsunto: string; ACuerpoMensaje: string; 
                         ANombreUsuario: string; APasswordUsuario: string; 
                         AFromText:string; 
                         AListaParametros:TStrings; 
:
:

Muchas gracias por el ejemplo. Pero de momento estaré tratando de resolver el problema de los errores del post anterior.

Saludos.