Obtener resultados de ShellExecute

[m@kio]

Tengo este procedimiento que obtuve de el foro, k es para ejecutar con shellexecute:

Código Delphi [-]
 procedure EjecutarPrograma(rutaPrograma,
   parametros: string; esperar: boolean);
 var
  salida: DWord;
  punteroInfo: PShellExecuteInfo;
  infoEjecucion: TShellExecuteInfo;
 begin
  with infoEjecucion do
  begin
   cbSize := SizeOf(infoEjecucion);
   fMask := SEE_MASK_NOCLOSEPROCESS;
   wnd := GetActiveWindow;
   lpVerb := nil;
   lpFile := PChar(rutaPrograma);
   lpParameters := Pchar(parametros + #0);
   lpDirectory := nil;
   nShow := SW_NORMAL;
   hInstApp := 0;
  end;
  punteroInfo:= @infoEjecucion;
  ShellExecuteEx(punteroInfo);
  if esperar then
   repeat
    salida := WaitForSingleObject(infoEjecucion.hProcess, 500);
    Application.ProcessMessages;
   until (salida <> WAIT_TIMEOUT);
 end;

y la mando llamar de la siguiente forma:

Código Delphi [-]
 EjecutarPrograma('osql','-L',true);

osql -L me trae en lina de comandos los Servidores SQL en la red.
Algo asi:

 c:\>osql -L
 
 Servers:
 	  (local)
 	  EB0
 	  EB3
 	  EB8

Lo que quiero es traer esa consulta a delphi ya sea en un listbox o en un combobox, para asi elegir a k servidor voy a realizar la conexión.

Espero k me puedan ayudar.

[dec]

Hola,

No sé hasta qué punto podrás obtener el resultado del programa que ejecutas si no existe una vía de comunicación de por medio *, claro está. Tal vez sea una chapuza, pero, ¿qué tal hacer que el programa envíe el resultado a un determinado archivo y luego leer dicho archivo desde tu aplicación?

Probablemente hay algún otro remedio, pero, a falta de pan... etc., como suele decirse. Supongo que lo sabrás (o sea, que, en parte estás buscando otro remedio), pero, para conseguir lo dicho podrías ejecutar el programa más o menos de este modo, por ejemplo:

c:\>osql -L > C:\Windows\Temp\archivo.temp

* Nota: tal vez en la documentación del programa que vas a ejecutar se indique alguna otra forma de hacer esto, puesto que quien lo programara tuviera en cuenta este tipo de situaciones... no lo sé... acaso incluso teniéndolas en cuenta no lo estimaron conveniente.

[delphi.com.ar]

¿Se trata de una aplicación de consola?... de ser así siempre tienes los mimos pipelines para poder hablar con el proceso, ¡la consola!... pero mas que hacer un ShellExecute, haría un CreateProcess donde definiría mis propio Start.hStdInput (y lpStartupInfo.hStdOutput en el caso de necesitarlo).... Si de esto se trata, te puedo subir algo de código.

Saludos!

[m@kio]

Pues si me serviria, gracias por sus respuestas, ya lo probe como lo indico dec y no me funciono no me guardo el archivo de texto, si puedes subir el codigo te lo agradeceria mucho, y buscare en el foro algo de lo que mencionas sobre CreateProcess.

Gracias a los 2 por darme ideas para solucionar el problema

[delphi.com.ar]

A ver si les gusta:

Código Delphi [-]
const
  BUFFER_SIZE = 2400;

function GetConsoleText(ACommandLine: string): string;
var
  lSecAttr: TSecurityAttributes;
  hReadPipe,
  hWritePipe: THandle;
  Buffer: PChar;
  lStartupInfo: TStartUpInfo;
  lProcessInfo: TProcessInformation;
  dwBytesRead,
  dwExitCode: DWORD;
begin
  Result := '';
  with lSecAttr do
  begin
    nlength := SizeOf(TSecurityAttributes) ;
    bInheritHandle := True; { Para que tenga la el mismo profile
                              de quien ejecuta el proceso }
    lpSecurityDescriptor := nil;
  end;

  { Crea los canales de comunicación }
  if CreatePipe(hReadPipe, hWritePipe, @lSecAttr, 0) then
    try
      Buffer := AllocMem(BUFFER_SIZE + 1);
      try
        FillChar(lStartupInfo, Sizeof(lStartupInfo), #0);

        with lStartupInfo do
        begin
          cb := SizeOf(lStartupInfo);
          hStdOutput := hWritePipe;
          hStdInput := hReadPipe;
          dwFlags := STARTF_USESTDHANDLES + STARTF_USESHOWWINDOW;
          wShowWindow := SW_HIDE;
        end;

        { Crea el proceso oculto y con herencia de descriptores }
        if CreateProcess(nil, PChar(ACommandLine), @lSecAttr, @lSecAttr, TRUE,
                         NORMAL_PRIORITY_CLASS, nil, nil, lStartupInfo, lProcessInfo) then
          try
            { Espera que termine el proceso }
            repeat
              dwExitCode := WaitForSingleObject(lProcessInfo.hProcess, 1000);
              Application.ProcessMessages;
            until dwExitCode <> WAIT_TIMEOUT;
            {
            repeat
              Application.HandleMessage;
              GetExitCodeProcess(lProcessInfo.hProcess, dwExitCode);
            until dwExitCode <> STILL_ACTIVE;
            }

            { Lee lo que se escribió en el pipeline hReadPipe }
            repeat
              dwBytesRead := 0;
              ReadFile(hReadPipe, Buffer[0], BUFFER_SIZE, dwBytesRead, nil);
              Buffer[dwBytesRead] := #0;
              OemToAnsi(Buffer, Buffer);
              Result := Result + string(Buffer);
            until (dwBytesRead < BUFFER_SIZE);

          finally
            CloseHandle(lProcessInfo.hProcess);
            CloseHandle(lProcessInfo.hThread);
          end;
      finally
        FreeMem(Buffer);
      end;
    finally
      CloseHandle(hReadPipe);
      CloseHandle(hWritePipe);
    end;
end;

{ Ejemplo de uso }
procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.Lines.Text := GetConsoleText('CMD /C DIR C:\*.*');
end;

Este ejemplo lee lo que se ha generado en un proceso de consola, este código lo utilizo hace un tiempo, en un "Extended Procedure" de SqlServer 2000 para leer unas claves generadas por programas de consola...

Saludos!

[johncook]

Lo que dijo dec funciona a la perfeccion.
C:\osql -L > prueba.txt

Saludos.