Componente que hay que activar en ejecucion, aunque se ve en fase diseño?

[[José Luis Garcí]]

Gracias por la informacion Maeyanes, lo he intentado, pero sigo sin saber por que falla, es mas ahorame da un error de Access Violation al probar la demo, pongo el código completo del componente, para saber si me echan una mano.

Código Delphi [-]
unit UCCDShadow;

interface

uses
  Windows, Messages, SysUtils, Controls, ComCtrls,Classes, Forms, QGraphics, Graphics;

type
  TCCDShadow = class(TComponent)
  private
    { Private declarations }
  FDeph : Integer;
  FColor: Tcolor;
  ParentForm: TForm;
  protected
  { Protected declarations }
    procedure ShadowDraw;
    procedure Setdeph(value : Integer);
    procedure Setcolor(Value: TColor);
    //procedure Loaded; virtual;
    procedure Notification(AComponent: TComponent; Operation: TOperation); override;
     
  public
    { Public declarations }
    constructor Create(aOwner: TComponent); override;
    destructor Destroy(); override;
  published
    { Published declarations }
    property Deph: Integer read FDeph write SetDeph default 3;
    property Color: Tcolor read FColor write SetColor default clAqua;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('CLub Delphi', [TCCDShadow]);
end;
constructor TCCDShadow.Create(aOwner: TComponent);
begin
    inherited Create(aOwner);
    ParentForm:=TForm(AOwner);
    Fcolor:=clAqua;
    Fdeph:=3;
    ShadowDraw;
end;

destructor TCCDShadow.Destroy();
begin
   inherited Destroy();
end;

Procedure TCCDShadow.SetColor(value : TColor);
begin
  if (FColor <> value) then FColor:= value;
  ShadowDraw;
end;

procedure TCCDShadow.SetDeph(value : Integer);
begin
  if (Fdeph <> value) then FDeph:= value;
  ShadowDraw;
end;

procedure TCCDShadow.ShadowDraw;
var
I: Integer;
rect: TRect;
old: TColor;
Component : TComponent;
begin
      ParentForm.Repaint;
      for I:= 0 to ParentForm.ControlCount -1 do
      begin
        with ParentForm do
        begin
          Component:=Components[i];
          if Component is TControl then
          begin
             rect := Controls[i].BoundsRect;
             canvas.fillrect(rect);
             rect.Left := rect.Left + FDeph;
             rect.Top := rect.Top + FDeph;
             rect.Right := rect.Right + FDeph;
         rect.Bottom := rect.Bottom + FDeph;
             old := Canvas.brush.color;
             canvas.brush.Color :=  Fcolor;
             canvas.fillrect(rect);

             canvas.brush.Color := old;
             Controls[i].Repaint
          end;
        end;
      end;
end;
procedure TCCDShadow.Notification(AComponent: TComponent; Operation: TOperation);
begin
  inherited Notification(AComponent,Operation);
  if (Operation = opinsert) and (AComponent is TCCDShadow) then  ShadowDraw;
  TCCDShadow(AComponent).ShadowDraw;
 end;

end.

[[maeyanes]]

Hola...

Prueba este código y me dices que tal...

Código Delphi [-]
unit UCCDShadow;

interface

uses
  Windows, Messages, SysUtils, Controls, ComCtrls,Classes, Forms, Graphics;

type
  TCCDShadow = class(TComponent)
  private
    { Private declarations }
    FActive: Boolean;
    FDeph: Integer;
    FColor: Tcolor;
    ParentForm: TForm;
    procedure SetActive(Value: Boolean);
    procedure Setdeph(value : Integer);
    procedure Setcolor(Value: TColor);
  protected
    { Protected declarations }
    procedure ShadowDraw;
    procedure Notification(AComponent: TComponent; Operation: TOperation); override;
  public
    { Public declarations }
    constructor Create(AOwner: TComponent); override;
  published
    { Published declarations }
    property Active: Boolean read FActive write SetActive default True;
    property Deph: Integer read FDeph write SetDeph default 3;
    property Color: Tcolor read FColor write SetColor default clAqua;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('CLub Delphi', [TCCDShadow]);
end;

constructor TCCDShadow.Create(AOwner: TComponent);
var
  I: Integer;
begin
  if not (AOwner is TForm) then
    raise Exception.Create('The owner must be a Form');
  ParentForm := TForm(AOwmer);
  for I := 0 to Pred(ParentForm.ComponentCount) do
    if ParentForm.Components[i] is TCCDShadow then
      raise Exception.Create('Only one TCCDShadow can exist in a Form');
  inherited Create(AOwner);
  Fcolor := clAqua;
  Fdeph := 3;
  FActive := True;
  ShadowDraw
end;

procedure TCCDShadow.SetActive(Value: Boolean);
begin
  if FActive <> Value then
  begin
    FActive := Value;
    ShadowDraw
  end
end;

Procedure TCCDShadow.SetColor(value : TColor);
begin
  if (FColor <> value) then
  begin
    FColor:= value;
    ShadowDraw
  end
end;

procedure TCCDShadow.SetDeph(value : Integer);
begin
  if (Fdeph <> value) then
  begin
    FDeph:= value;
    ShadowDraw
  end
end;

procedure TCCDShadow.ShadowDraw;
var
  I: Integer;
  rect: TRect;
  old: TColor;
  Component : TComponent;

begin
  if not FActive then
    Exit;
  ParentForm.Repaint;
  for I := 0 to ParentForm.ControlCount -1 do
    with ParentForm do
    begin
      Component:=Components[i];
      if Component is TControl then
      begin
       rect := Controls[i].BoundsRect;
       canvas.fillrect(rect);
       rect.Left := rect.Left + FDeph;
       rect.Top := rect.Top + FDeph;
       rect.Right := rect.Right + FDeph;
       rect.Bottom := rect.Bottom + FDeph;
       old := Canvas.brush.color;
       canvas.brush.Color :=  Fcolor;
       canvas.fillrect(rect);
       canvas.brush.Color := old;
       Controls[i].Repaint
      end
    end
end;

procedure TCCDShadow.Notification(AComponent: TComponent; Operation: TOperation);
begin
  inherited Notification(AComponent,Operation);
  { Cada que agregamos un control o eliminamos un control de la forma,
    redibujamos las sombras }
  ShadowDraw;
end;

end.

Si te fijas, le agregué una propiedad llamada Active para especificar si quieres dibujar o no las sombras...

También, cada que eliminas o agregas un control en la forma, el componente redibuja las sombras...

Otro cambio que tiene es que si el owner del componente no es una forma, te salta un error y también solo puede existir un componente del tipo TCCDShadow en la forma.


Saludos...

[[José Luis Garcí]]

Maeyanes no e podido probar el codigo ya que me da un error en la linea

Código Delphi [-]
ParentForm := TForm(AOwmer);

ÇPero por lo que veo y lo que me comentas supongo tengas razón, perdona que tarde entre respuesta y respuesta pero es que donde programo no tiene enlace a internet. Gracias mil de todas manaeras por tu ayuda

[[maeyanes]]

Cual es el error que te da?


Saludos...

[[basti]]

No deberías llamar al procedimiento ShadowDraw desde el Create, es posible que no se hayan cargado todos los controles en el formulario, por eso no te muestra los cambios al ejecutar hasta que cambias una propiedad y vuelves a llamar a ShadowDraw. Además es posible que el error de Access Violation venga también de ahí.

Prueba a sobreescribir el procedimiento Loaded, que se ejecuta una vez se ha cargado el form.

Código Delphi [-]
  protected
    { Protected declarations }
    procedure Loaded; override;
.
.
.
  procedure TCCDShadow.Loaded;
  begin
     ShadowDraw;
  end;

[[maeyanes]]

Hola...

Empezado por basti

No deberías llamar al procedimiento ShadowDraw desde el Create, es posible que no se hayan cargado todos los controles en el formulario, por eso no te muestra los cambios al ejecutar hasta que cambias una propiedad y vuelves a llamar a ShadowDraw. Además es posible que el error de Access Violation venga también de ahí.

Prueba a sobreescribir el procedimiento Loaded, que se ejecuta una vez se ha cargado el form.

Solo una pequeña corrección...

Código Delphi [-]
  protected
    { Protected declarations }
    procedure Loaded; override;
.
.
.
  procedure TCCDShadow.Loaded;
  begin
    inherited;
    ShadowDraw;
  end;

[[basti]]

Empezado por maeyanes

Solo una pequeña corrección...

Pequeña no, enorme...

[[Al González]]

¡Hola!

Agregaría que un método virtual redefinido que todo lo que hace es llamar a su versión heredada, es innecesario, como es el caso del destructor:

Código Delphi [-]
destructor TCCDShadow.Destroy();
begin
   inherited Destroy();
end;

Por otra parte, en el constructor, la sentencia

Código Delphi [-]
ParentForm:=TForm(AOwner);

asume que el parámetro AOwner es una forma (lo cual está bien para la mayoría de los casos, donde el objeto es agregado a una forma en tiempo de diseño), pero ¿qué tal si el objeto es instanciado en tiempo de ejecución enviándole como parámetro otro tipo de dueño, incluso un Nil? O bien, el objeto es insertado en tiempo de diseño en un módulo de datos.

Concuerdo en que no debe realizarse una operación de dibujo / despliegue desde el constructor. Es prematuro. Loaded se ejecuta cuando ya toda la forma y sus componentes han sido cargados y están listos para la acción (aunque tomando en cuenta que aún no están visibles).

Un abrazo compuesto.

Al González.