TIBquery y campos persistentes en tiempo de ejecucion

[mjjj]

Hola, este tema no se si deberia estar aca, pero tiene que ver con una consulta y campos persistentes (o al menos creo que se llaman asi).

Tengo una aplicación que utiliza TIBQuery para cunsultar a una BD Firebird. En tiempo de diseño he creado algunos campos persistentes (propios de la query en cuestion "Fields Editor"). La aplicacion puede consultar a 2 BD distintas, lo cual se selecciona con un radiobutton. En el evento OnClick del radiobutton tengo el siguiente codigo.

Código Delphi [-]
ibquery2.destroy;
query := tibquery.Create(self);
query.Name := 'ibquery2';
query.SQL.add('select notas, noc, ncorr, t.nombre, cantidad, unitario, descuento, cantidad * unitario as subtotal,');
query.SQL.add('cantidad * unitario - descuento afecto from COMPRAS_detalle d');
query.SQL.add('inner join insumos_servicios t on t. id = d.id_item and d.que_es = t.que_es');
query.SQL.add('where noc =:noc order by ncorr');
query.DataSource := datasource1;
datasource2.DataSet := query;
 
if radiobutton3.checked then
begin
ibquery2.Database:=    mainform.DB_empresa_server;
ibquery2.Transaction:= mainform.TR_empresa_server;
end else
begin
ibquery2.Database:=    mainform.DB_empresa_local;
ibquery2.Transaction:= mainform.TR_empresa_local;
end;

Esto funciona perfecto, el problema es que los campos persistentes definidos en tiempo de diseño no se asignan al query creado nuevamente, a pesar que tiene el mismmo nombre. Algun de estos son IBQuery2SUBTOTAL, IBQuery2CANTIDAD, etc. La idea des esto es poder darle un formato "lindo" al campo en cuestión, lo que defino en diseño así:

Código Delphi [-]
IBQuery2CANTIDAD.displayformat := '#,##0';

Como puedo resolver esto?
Existe alguna forma de asignar los campos persistentes, después de volver a crear al query.

Nota: Anteriormente solo cambiaba la BD del query despues de cerrarla, pero al volver abrirla me arrojaba un error, por eso decidí destruir el componente y volver a crearlo.

Espero me puedan ayudar.

[[maeyanes]]

Hola...

Tendrías que crear de nuevo los campos un tiempo de ejecución.

Para hacer lo que deseas, puedes hacerlo en tiempo de ejecución (sin crear los campos persistente en tiempo de diseño), más o menos así:

Código Delphi [-]
var
  IntField: TIntegerField;

begin
  IntField := IBQuery2.FieldByName('CANTIDAD') as TIntegerField;
  IntField.DisplayFormat := '#,##0'
end;

Saludos...

[mjjj]

No hay caso, no logro resolver esto.
Una cosa que me percaté es que al destruir el query, no se destruyen los campos persistentes.

Una idea... podré volver asignar esos campos al query nuevo creado en ejecución? como lo hago?

Ayuda porfa.

[[maeyanes]]

Hola...

¿Leiste las recomendaciones que te hice?


Saludos...

[mjjj]

claro que si, pero no logro que esto funcione.

Recuerda que en el evento onclick del radiobutton, destruyo el query. En ese mismo evento destruyo los campos persistentes y vuelvo a crearlos con las propiedades correctas, sin embargo, me arroja un error que no concuerda el tipo de dato... espera BCD y es wildstring, en un campo de varchar de 200.

Código Delphi [-]
var field: tibbcdfield;
begin
...
ibquery2notas.Destroy;
ibquery2.destroy;
 
field := tibbcdfield.Create(Self);
field.Name := 'ibquery2notas';
field.FieldKind := fkdata;
field.FieldName := 'notas';
field.Size := 200;
field.DisplayWidth := 200;
field.DataSet := query;
...
end;

Además tengo que hacerlo con cada campo, y son varios... tiene que existir una mejor forma de hacerlo.

[[maeyanes]]

Hola...

Leyendo mejor tu duda, veo que estás haciendo mal algunas cosas. Primero, veo que destruyes el objeto ibquery2 y creas un nuevo objeto y lo asignas a la variable ibquery al cual le pones como nombre 'ibquery2'. Esto no significa que automáticamente los campos persistentes van a reconocer el nuevo objeto como padre. Y todo esto sin contar con el detalle de los tipos de campos.

Para lograr lo que deseas, podrías hacer algo como:

Código Delphi [-]
begin
  ibquery2.Close;
  // Asignas los objetos de base de datos y transacción de acuerdo al checkbox
  if radiobutton3.checked then
  begin
    ibquery2.Database:=    mainform.DB_empresa_server;
    ibquery2.Transaction:= mainform.TR_empresa_server
  end
  else
  begin
    ibquery2.Database:=    mainform.DB_empresa_local;
    ibquery2.Transaction:= mainform.TR_empresa_local
  end;
  // Aquí podrías crear la nueva consulta o asignar parámetros.
  ibquery2.Open
end

Si las tablas son exactamente iguales en ambas bases de datos, no deberías tener problemas. Ahora, esto nunca lo he hecho así y el código que te pongo no lo he probado.


Saludos...

[mjjj]

Estimado, sigo sin poder resolver esto... tal como tu lo expones (en teoría debería funcionar), pero no es así, me arroja un error a pesar que las tablas son identicas.

Finalmente estoy tratando de crear los campos persistenes en ejecución con el siguiente copdigo (en diseño no existen), por ejemplo para algunos de los campos persistentes

Código Delphi [-]
..
var query: tibquery;
var field: tibbcdfield;
..
field := tibbcdfield.Create(Self);
field.Name := 'ibquery2notas';
field.FieldKind := fkdata;
field.FieldName := 'notas';
field.Size := 200;
field.DisplayWidth := 200;
field.origin := 'COMPRAS_DETALLE.NOTAS';
field.DataSet := query;
 
field := tibbcdfield.Create(Self);
field.Name := 'ibquery2noc';
field.FieldKind := fkdata;
field.FieldName := 'noc';
field.DataSet := query;

field := tibbcdfield.Create(Self);
field.Name := 'ibquery2ncorr';
field.FieldKind := fkdata;
field.FieldName := 'ncorr';
field.DataSet := query;
field := tibbcdfield.Create(Self);
field.Name := 'ibquery2nombre';
field.FieldKind := fkinternalcalc;
field.FieldName := 'nombre';
field.Size := 30;
field.DataSet := query;
field := tibbcdfield.Create(Self);
field.Name := 'ibquery2cantidad';
field.FieldKind := fkdata;
field.FieldName := 'cantidad';
field.Precision := 18;
field.Size := 4;
field.DataSet := query;
field.DisplayFormat :='#,##0';

El error que me arroja dice así:
Para el campo Notas: field 'notas' expecting: BCD actual WideString
Para el campo Noc: field 'noc' expecting: BCD actual: Largeint

asi sucecivamente para el resto de los campos.

Como puedo resolver esto?
Espero me puedan ayudar.

[ecfisa]

Hola.

Te pongo un ejemplo con tres tipos de campos que tal vez te sirva de guía:

Código Delphi [-]
...
var
  Query: TIBquery;
  QueryID: TIntegerField;
  QueryTipo: TIBStringField;
  QueryMonto: TFloatField;

procedure TForm1.btnCrearPersistentesClick(Sender: TObject);
begin
  Query:= TIBQuery.Create(Self);
  Query.Database:= IBDatabase1;
  Query.Transaction:= IBTransaction1;
  Query.SQL.Text:= 'SELECT * FROM TABLA';
  
  QueryID:= TIntegerField.Create(Query);
  with QueryID do
  begin
    FieldName:= 'ID';
    Name:= 'QueryID';
    FieldKind:= fkData;
    DisplayLabel:= 'ID';
    DataSet:= Query
  end;

  QueryTipo:= TIBStringField.Create(Query);
  with QueryTipo do
  begin
    FieldName:= 'TIPO';
    Name:= 'QueryTipo';
    FieldKind:= fkData;
    DisplayLabel:= 'TIPO';
    Size:= 1;
    DataSet:= Query
  end;

  QueryMonto:= TFloatField.Create(Query);
  with QueryMonto do
  begin
    FieldName:= 'MONTO';
    Name:= 'QueryMonto';
    FieldKind:= fkData;
    DisplayLabel:= 'MONTO';
    DisplayWidth:= 10;
    DisplayFormat:= '0.00';
    DataSet:= Query;
  end;
  Query.Open;
  ShowMessage(QueryID.AsString+' - '+QueryTipo.AsString+' - '+QueryMonto.AsString);
end;

Saludos.

[mjjj]

Vamos mejorando, todos los campos persistentes de tipo string e integer esta funcionando bien, pero los de tipo float, me arroja el siguiente error

Ibquery2: Type mismatch for firld 'CANTIDAD', expecting: FLoat actual BCD'

el código que utiliza está así

Código Delphi [-]
var queryfloat:   Tfloatfield;
..
 queryfloat:= TFloatField.Create(Query);
  with queryfloat do
  begin
    FieldName:= 'cantidad';
    Name:= 'IBquery2cantidad';
    FieldKind:= fkData;
    precision := 18;
    DisplayLabel:= 'CANTIDAD';
    DisplayWidth:= 19;
    DisplayFormat:= '#,##0';
    DataSet:= Query;
  end;

Que es BCD??
Como lo soluciono?

Gracias

[[maeyanes]]

Hola...

Yo sigo insistiendo que no necesitas crear los campos así en tiempo de ejecución. El componente TIBQuery ya crea los campos al momento de ejecutar la consulta, lo único que tienes que hacer es configurar los campos que quieras:

Código Delphi [-]
begin
  TFloatField(IBQuery2.FieldByName('CANTIDAD')).DisplayFormat := '#,##0'
end;

Saludos...

[ecfisa]

Empezado por maeyanes

Hola...

Yo sigo insistiendo que no necesitas crear los campos así en tiempo de ejecución. El componente TIBQuery ya crea los campos al momento de ejecutar la consulta, lo único que tienes que hacer es configurar los campos que quieras:

Eso es totalmente cierto, basta con hacer:

Código Delphi [-]
var
  Query: TIBQuery;
begin
  Query:= TIBQuery.Create(Self);
  with Query do
  begin
    Database:= IBdatabase1;
    Transaction:= IBTransaction1;
    SQL.Text:= 'SELECT * FROM UNA_TABLA';
    open;
  end;
  TFloatField(Query.FieldByName('CANTIDAD')).DisplayFormat := '#,##0'; // (copio código de maeyanes)
  Datasource1.DataSet:= Query;

Para que estén todos los campos disponibles. Hay que acceder con FieldByName como bién mostras en tu mensaje anterior y no por el nombre de variable del campo persistente. A mí entender es un detalle sin importancia y no amerita escribir tanto código, pero como ví que antes lo mencionaste y se continuó por el lado de la creación manual...

Saludos.

[mjjj]

Eso era todo!!

Gracias por su ayuda, esta funcionando perfecto.
Salu2