Convertir un cadena donde cada Palabra Primera con mayuscula

[jhonny]

Yo tampoco recuerdo una función que haga eso y también propongo una función, para el caso:

Código Delphi [-]
 
function Capitalize(S: String): String;
var
  ListaVar: TStringList;
  Cadena  : String;
  i:  Integer;
begin
  ListaVar      :=  TStringList.Create;
  Result     :=  '';
  try
    ExtractStrings([' '],[' '], PCHAR(S), ListaVar);
    for I := 0 to ListaVar.Count - 1 do
    begin
      Cadena      :=  ListaVar[i];
      Cadena      :=  LowerCase(Cadena);
      Cadena[1]   :=  UpCase(Cadena[1]);
      Result   :=  Result + Cadena  + ' ';
    end;
    SetLength(Result, Length(Result)-1);
  finally
    ListaVar.Free;
  end;
end;

[[cHackAll]]

Estas subastas de código son fantásticas, yo pongo el mío;

Código Delphi [-]
function Capitalize(Str: string): string;
var Index: Cardinal;
begin
 for Index := 1 to Length(Str) do
  if (Index = 1) or (Str[Index - 1] = ' ') then
   if Str[Index] in ['a'..'z'] then
    Dec(Str[Index], 32) else // verdad que parecería que sobra ese "else" ?
  else
   if Str[Index] in ['A'..'Z'] then
    Inc(Str[Index], 32);
 Result := Str;
end;

[jhonny]

Bueno, lo que me parece curioso es que aunque no es difícil de incluir, ninguna de las tres funciones tienen en cuenta los caracteres especiales, tales como la Ñ o las mayúsculas con tildes .

[[cHackAll]]

Cierto (SP), la corrijo:

Código Delphi [-]
function Capitalize(Str: string): string;
var Index: Cardinal;
begin
 for Index := 1 to Length(Str) do
  if (Index = 1) or (Str[Index - 1] = ' ') then
   if Str[Index] in ['a'..'z','á','é','í','ó','ú','ñ'] then
    Dec(Str[Index], 32) else
  else
   if Str[Index] in ['A'..'Z','Á','É','Í','Ó','Ú','Ñ'] then
    Inc(Str[Index], 32);
 Result := Str;
end;

Saludos

[shoulder]

La verdad deben patentar la funciòn, anda perfecta, estuve horas buscando en internet una funcion interna como tiene access que es la strconv y no existe y sirve muchisimo para los nombres y apellidos.

Un gran abrazo a los genios virtuales.

[[Delphius]]

Este reto me gustó. Propongo una nueva variante:

Código Delphi [-]
function TForm1.Capitalize(Text: string): string;
var Aux, Capital: string;
begin
  Capital := AnsiUpperCase(Text[1]);
  Aux := AnsiLowerCase(Text);
  Aux[1] := Capital[1];
  result := Aux;
end;

function TForm1.CapitalizeAll(Text: string): string;
var i: integer;
    CopyText: string;
    CapitalizeText: string;
begin
 for i := 1 to Length(Text) do
   begin
     if (Text[i] <> ' ') or (i = Length(Text))
        then CopyText := CopyText + Text[i]
        else begin
               CapitalizeText := CapitalizeText + ' ' + Capitalize(CopyText);
               CopyText := '';
             end;
   end;
 result := CapitalizeText + ' ' + Capitalize(Copytext);
end;

En teoría debería funcionar con cualquier caracter que se venga...

Saludos,

[roman]

Empezado por cHackAll

// verdad que parecería que sobra ese "else" ?

¡Vaya! ¡Qué interesante! Aunque parece que sólo a mi me sorprende.

Yo siempre había pensado que pascal tenía un defecto de sintaxis al no permitir

Código Delphi [-]
if X then
  if Y then
    A;
else
  B;

que tendría que ser válido puesto que el else corresponde al primer if. Por lo general recurría a

Código Delphi [-]
if X then
begin
  if Y then
    A;
end
else
  B;

Ahora veo que también lo puedes resolver con

Código Delphi [-]
if X then
  if Y then
    A
  else
else
  B;

Siempre se aprende algo nuevo

// Saludos

[[Lepe]]

idem roman.

[Delfino]

Propongo la función mas económica y rentable para capitalizar la primera letra de una palabra,

IVA incluido y descuento
O se queda satisfecho o le devolvemos su dinero
Si encuentra mas barato le abonamos la diferencia

Código Delphi [-]
cadena :=  StuffString(Texto,1,1,UpperCase(LeftStr(Texto,1)))

[santiago14]

Empezado por roman

¡Vaya! ¡Qué interesante! Aunque parece que sólo a mi me sorprende.
....

Ahora veo que también lo puedes resolver con

Código Delphi [-]
if X then
  if Y then
    A
  else
else
  B;

Pues no es al único que sorprende haber visto ese pedazo de código, a mí también me causó "impresión" cuando lo ví. Ya lo dijeron... siempre se aprende algo nuevo... y bueno.

Santiago.

[santiago14]

Empezado por Delphius

Este reto me gustó. Propongo una nueva variante:

Código Delphi [-]
function TForm1.Capitalize(Text: string): string;
var Aux, Capital: string;
begin
  Capital := AnsiUpperCase(Text[1]);
  Aux := AnsiLowerCase(Text);
  Aux[1] := Capital[1];
  result := Aux;
end;

function TForm1.CapitalizeAll(Text: string): string;
var i: integer;
    CopyText: string;
    CapitalizeText: string;
begin
 for i := 1 to Length(Text) do
   begin
     if (Text[i] <> ' ') or (i = Length(Text))
        then CopyText := CopyText + Text[i]
        else begin
               CapitalizeText := CapitalizeText + ' ' + Capitalize(CopyText);
               CopyText := '';
             end;
   end;
 result := CapitalizeText + ' ' + Capitalize(Copytext);
end;

En teoría debería funcionar con cualquier caracter que se venga...

Saludos,

Medio viejito el post pero siempre vigente.
Igual, de gran utilidad.

Gracias de nuevo.

[[Al González]]

No había visto este hilo.

Para Santiago: ¡Gracias por revivirlo!

Para Román: Esas dos cosas que aprendiste hace casi cuatro años, ahora las he aprendido yo. Por cierto, llevas ya algunos meses de ausencia "pública", espero que todo vaya bien.

Para Javier (cHackAll): Gracias por ese par de tremendas revelaciones.

* El uso de Else vacío para forzar la correspondencia If-Else.

* A diferencia de la tabla ASCII, la tabla de caracteres ANSI presenta la misma distancia entre las mayúsculas y las minúsculas de todas las letras del alfabeto latino (no sólo las no acentuadas).

Vuelve pronto a los foros, Javier. Estoy seguro que hay mucho que podemos seguir aprendiendo de ti.

Un abrazo.

Al.