Club Delphi  
    FTP   CCD     Buscar   Trucos   Trabajo   Foros

Retroceder   Foros Club Delphi > Principal > OOP
Registrarse FAQ Miembros Calendario Guía de estilo Buscar Temas de Hoy Marcar Foros Como Leídos


Respuesta
 
Herramientas Buscar en Tema Desplegado
  #1  
Antiguo 11-12-2015
Avatar de AgustinOrtu
[AgustinOrtu] AgustinOrtu is offline
Miembro Premium
 
Registrado: Aug 2013
Ubicación: Argentina
Posts: 1.858
Poder: 10
AgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en bruto
TDBGrid, pintar/negrita texto celda parcial

Saludos

Estoy usando Delphi 2010, y el efecto que quiero lograr es poner en negrita (o colorear, en fin cualquier forma de resaltar texto me vendria bien) parte del contenido de una celda de un TDBGrid; la idea es lanzar una busqueda y resaltar todas los campos en donde coincide el texto buscado

Ejemplo: busco "agustin" entonces el DBGrid deberia mostrar

Código Delphi [-]
Nombre             Direccion                           ...
Agustin    Calle agustincito        ...

Al grid ademas le asigno estas propiedades:

Código Delphi [-]
DefaultDrawing := False 
Options := [dgTitles, dgIndicator, dgColumnResize, dgColLines, dgRowLines, dgTabs, dgRowSelect,
    dgAlwaysShowSelection, dgCancelOnExit, dgTitleClick, dgTitleHotTrack];

Lo que hice fue agregar un manejador al evento OnDrawColumnCell, este es el codigo:

Código Delphi [-]
TForm1.(Sender: TObject; const Rect: TRect; DataCol: Integer; Column: TColumn;
  State: TGridDrawState);
var
  R: TRect;
  LCanvas: TCanvas;
  LFieldValue, LChar: string;
  I: Integer;
begin
  LCanvas := TDBGrid(Sender).Canvas;
  if DataCol in [0 .. 1] then
  begin
    LFieldValue := Column.Field.AsString;

    if not AnsiContainsText(LFieldValue, FSearchString) then
    begin
      LCanvas.Font.Style := LCanvas.Font.Style - [fsBold];
      TDBGrid(Sender).DefaultDrawColumnCell(Rect, DataCol, Column, State);
      Exit;
    end;

    R := Rect;
    for I := 1 to Length(LFieldValue) do
    begin
      LChar := LFieldValue[i];

      // desplazamiento del rectangulo
      if I > 1 then
        R.Left := R.Left + LCanvas.TextWidth(LChar);

      if (Length(FSearchString) >= I) and (AnsiSameText(LChar, FSearchString[i])) then
        LCanvas.Font.Style := LCanvas.Font.Style + [fsBold]
      else
        LCanvas.Font.Style := LCanvas.Font.Style - [fsBold];

      // dibujar cada caracter
      LCanvas.TextRect(R, LChar);
    end;
  end
  else
  begin
    LCanvas.Font.Style := LCanvas.Font.Style - [fsBold];
    TDBGrid(Sender).DefaultDrawColumnCell(Rect, DataCol, Column, State);
  end;
end;

Basicamente voy pintando caracter a caracter, en negrita o no, segun se vaya cumpliendo la coincidencia parcial

Pero me queda "feo" el texto, asi es como sale:



Curiosamente para numeros parece "ir bien", pero el texto sale horrible

Alguien puede arrojar algo del luz?

PD: Otras alternativas de haberlas, encantado de oirlas; por ejemplo, si con otro control VCL es facil lograr el efecto, aunque no sea data-aware, podria escribir la parte de llenar el contenido (un ListView por ejemplo). En lo posible prefiero no usar componentes de terceros
Responder Con Cita
  #2  
Antiguo 12-12-2015
Avatar de ecfisa
ecfisa ecfisa is offline
Moderador
 
Registrado: Dec 2005
Ubicación: Tres Arroyos, Argentina
Posts: 10.120
Poder: 30
ecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to behold
Hola Agustín.

Fijate si podes sacar algo de provecho de este código de prueba:


Código Delphi [-]
...
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var
  a,b,c: string;
  p    : Integer;
  cv   : TCanvas;
  fs   : TFontStyles;
begin
  p := AnsiPos(FSearched, Column.Field.AsString);
  if (p <> 0) and (Column.Field is TStringField) then
  begin
    a := Copy(Column.Field.AsString, 1, p - 1);
    b := Copy(Column.Field.AsString, p, Length(FSearched));
    c := Copy(Column.Field.AsString, p + Length(FSearched), MaxInt);
    cv := TDBGrid(Sender).Canvas;
    cv.FillRect(Rect);

    p  := Rect.Left + 2;
    fs := cv.Font.Style;
    cv.Font.Style := [];
    cv.TextOut(p, Rect.Top + 2, a);

    Inc(p, cv.TextWidth(a));
    cv.Font.Style := [fsBold];
    cv.TextOut(p, Rect.Top + 2, b);

    Inc(p, cv.TextWidth(b));
    cv.Font.Style := [];
    cv.TextOut(p , Rect.Top + 2, c);
  end;
end;

procedure TForm1.Edit1Change(Sender: TObject);
begin
  FSearched := Edit1.Text;
  DBGrid1.Invalidate;
end;
...
Esta para ser usado sobre TStringFields (y tendrías que filtrar las columnas deseadas en el condicional)

Saludos
__________________
Daniel Didriksen

Guía de estilo - Uso de las etiquetas - La otra guía de estilo ....
Responder Con Cita
  #3  
Antiguo 12-12-2015
Avatar de AgustinOrtu
[AgustinOrtu] AgustinOrtu is offline
Miembro Premium
 
Registrado: Aug 2013
Ubicación: Argentina
Posts: 1.858
Poder: 10
AgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en bruto
Daniel, funciona excelente, muchas gracias

Fue cuestion solamente de hacer un par de ajustes para que quede perfecto

Por cierto, es necesario en este caso que DBGrid.DefaultDrawing este a True

Saludos
Responder Con Cita
  #4  
Antiguo 12-12-2015
Avatar de ecfisa
ecfisa ecfisa is offline
Moderador
 
Registrado: Dec 2005
Ubicación: Tres Arroyos, Argentina
Posts: 10.120
Poder: 30
ecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to beholdecfisa is a splendid one to behold
Me alegro mucho que te haya servido

Aunque no influye en el funcionamiento del ejemplo, hay un detalle que se me escapó entre las pruebas y que ahora veo... debería ser:
Código Delphi [-]
procedure TForm1.DBGrid1DrawColumnCell(Sender: TObject; const Rect: TRect;
  DataCol: Integer; Column: TColumn; State: TGridDrawState);
var
  a,b,c: string;
  p    : Integer;
  cv   : TCanvas;
  fs   : TFontStyles;
begin
  p := AnsiPos(FSearched, Column.Field.AsString);
  if (p <> 0) and (Column.Field is TStringField) then
  begin
    a := Copy(Column.Field.AsString, 1, p - 1);
    b := Copy(Column.Field.AsString, p, Length(FSearched));
    c := Copy(Column.Field.AsString, p + Length(FSearched), MaxInt);
    cv := TDBGrid(Sender).Canvas;
    fs := cv.Font.Style;
    cv.FillRect(Rect);

    p  := Rect.Left + 2;
    cv.Font.Style := fs;  // <-- 
    cv.TextOut(p, Rect.Top + 2, a);

    Inc(p, cv.TextWidth(a));
    cv.Font.Style := [fsBold];
    cv.TextOut(p, Rect.Top + 2, b);

    Inc(p, cv.TextWidth(b));
    cv.Font.Style := fs;  // <--
    cv.TextOut(p , Rect.Top + 2, c);
  end;
end;

Saludos
__________________
Daniel Didriksen

Guía de estilo - Uso de las etiquetas - La otra guía de estilo ....
Responder Con Cita
  #5  
Antiguo 12-12-2015
Avatar de AgustinOrtu
[AgustinOrtu] AgustinOrtu is offline
Miembro Premium
 
Registrado: Aug 2013
Ubicación: Argentina
Posts: 1.858
Poder: 10
AgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en bruto
Entiendo, es para usar la fuente original del canvas y no forzar a sin estilo (que seria un conjunto vacio, [])

Saludos
Responder Con Cita
  #6  
Antiguo 12-12-2015
Avatar de AgustinOrtu
[AgustinOrtu] AgustinOrtu is offline
Miembro Premium
 
Registrado: Aug 2013
Ubicación: Argentina
Posts: 1.858
Poder: 10
AgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en brutoAgustinOrtu Es un diamante en bruto
Cita:
Empezado por AgustinOrtu Ver Mensaje
Daniel, funciona excelente, muchas gracias

Fue cuestion solamente de hacer un par de ajustes para que quede perfecto

Por cierto, es necesario en este caso que DBGrid.DefaultDrawing este a True
Correccion, DefaultDraw debe estar desactivado (False), sino se escribe el texto dos veces (una el DBGrid, otra el evento)

Si no se pinta el texto en este evento, es necesario invocar al metodo DefaultDrawColumnCell

por ejemplo:

Código Delphi [-]
  p := AnsiPos(FSearched, Column.Field.AsString);
  if (p <> 0) and (Column.Field is TStringField) then
  begin
   ...
  end
  else
    TDBGrid(Sender).DefaultDrawColumnCell(Rect, DataCol, Column, State);
Responder Con Cita
Respuesta


Herramientas Buscar en Tema
Buscar en Tema:

Búsqueda Avanzada
Desplegado

Normas de Publicación
no Puedes crear nuevos temas
no Puedes responder a temas
no Puedes adjuntar archivos
no Puedes editar tus mensajes

El código vB está habilitado
Las caritas están habilitado
Código [IMG] está habilitado
Código HTML está deshabilitado
Saltar a Foro

Temas Similares
Tema Autor Foro Respuestas Último mensaje
texto en negrita NEG1414 C++ Builder 2 05-02-2009 16:22:28
Pintar filas TDBGrid ManuelPerez Varios 11 12-08-2008 11:09:47
pintar una celda... eli.vidal Impresión 1 14-11-2005 16:31:27
pintar una celda... eli.vidal Gráficos 1 14-11-2005 16:30:49
Como Pintar Solo la Celda y No Toda la Columna de la Celda de un dbGrid?? AGAG4 Varios 11 15-11-2004 20:53:28


La franja horaria es GMT +2. Ahora son las 17:26:35.


Powered by vBulletin® Version 3.6.8
Copyright ©2000 - 2018, Jelsoft Enterprises Ltd.
Traducción al castellano por el equipo de moderadores del Club Delphi
Copyright 1996-2007 Club Delphi