Mensaje "error catastrófico" sino dejo libre tráfico de campos blobs

[Tcmn]

Hola compañeros:

De antena agradezco el tiempo que se toman en leer este hilo. Como lo menciono en el título tengo un problema con un sistema el cual trabajaba con normalidad hasta este día que me han pedido una actualización. La cual consta en que se pueda guardar el sistema una imagen de la identificación del cliente y también su contrato.
Anteriormente ya había hecho esto en otros sistemas sin complicaciones pero no se que este pasando en esta ocasión.
Tengo una máquina con procesador de 64 bits con Windows 7 ultimate, Ibexpert 2013.2, delphi 6 enterprise y firebird 2.1 la conexión a la base de datos la hago con los componentes de la paleta interbase y DATASETPROVIDER junto con los clientdataset.
En cuanto a la base de datos le añadi los campos Blob de tipo binario con size de 80 y en delphi modifique el DATASETPROVIDER para que no mandará los campos blob sino era requerida su prescencia. Para ello en las opciones puse con el object inspector

PoFetchBlobsOnDemand=true

Tanto en el proveedor de la tabla "clientes"(esta tabla es la maestra) como en el proveedor de la tabla de "contratos"(esta tabla es la de detalles), y cuando quiero guardar un registro en el que he cargado los escaneos en formato JPEG, me manda el mensaje en el IDE:"Project Programa.exe raised exception class EDBClient with message ". Process stopped. Use step or run to continúe.
Y después en el programa (ya no en el IDE) me aparece el mensaje "ERROR CATASTRÓFICO"
Sin embargo, si yo dejo en false la propiedad para que así puedan venirse los campos blob con cada registro ya no hay ningún mensaje de error pero el sistema se vuelve mega lento y que trabaja en red. La pregunta es cual será la configuración correcta para que me acepte guardar dichos registros junto con su campo blob pero que no se vengan los campos blob a menos que expresamente lo solicíte el usuario? Espero haber sido claro. Muchas gracias por la ayuda que puedan otorgarme. Buen día

[[duilioisola]]

Quizás debas insertar esta imagen en una función separada y si es necesario para mostrarlo, refrescar el registro de la tabla que lo contiene.
Este es código que tengo en uno de mis programas.
Trabaja con otro componente de base de datos, pero supongo que no tendrás problemas utilizando los tuyos.
En principio, creo un DataSet con el InsertSQL que deseo.
Luego lo ejecuto, cargando el campo BLOB mediante streams.

Código Delphi [-]
function TDMMain.ImportarImagen(Archivo: string; EnBaseDeDatos: boolean = True): integer;
var
  DS : TFIBDataSet;
  m, f : TStream;
  aFileName, aFileExt : string;
  OPDImagen : TOpenDialog;
begin
  /// Carga una imagen en SYS_IMAGENES desde un archivo y devuelve su ID
  /// Si el archivo esta vacio, abre un dialogo.

  Result := 0;

  if (Archivo = '') then
  begin
     OPDImagen := TOpenDialog.Create(nil);
     try
        with OPDImagen do
        begin
           Filter := _('Todas las imágenes|*.bmp;*.jpg;*.gif;*.png|BitMap Images (*.bmp)|*.bmp|JPG Images (*.jpg)|*.jpg|GIF Images (*.gif)|*.gif|PNG Images (*.png)|*.png');
           FilterIndex := 1;
           Title := _('Carga de Imagen');
           if (Execute) then
              Archivo := FileName;
        end;
     finally
        OPDImagen.Free;
     end;
  end;

  if (Archivo > '') then
  begin
     // Si la extensión es JPEG, la transformo en JPG
     aFileExt := AnsiUpperCase(ExtractFileExt(Archivo));
     if aFileExt = '.JPEG' then
        aFileExt := '.JPG';
     aFileExt := Copy(aFileExt, 2, 3);
     aFileName := ExtractFileName(Archivo);

     DS := TFIBDataSet.Create(nil);
     try
        with DS do
        begin
           Transaction := TFIBTransaction.Create(nil);
           try
              Close;
              DataBase := Self.DataBase;
              with Transaction do
              begin
                 DefaultDatabase := Self.DataBase;
                 TRParams.Clear;
                 TRParams.Add('read_committed');
                 TRParams.Add('rec_version');
                 TRParams.Add('nowait');
                 if (not InTransaction) then
                    StartTransaction;
              end;
              // SelectSQL que no devuelve ningún registro. Solo para que el DataSet genere los campos
              SelectSQL.Text := 'SELECT CODIGO, NOMBRE, IMAGEN, FORMATO, ORIGEN, RUTA FROM SYS_IMAGENES WHERE CODIGO = 0';
              InsertSQL.Text := 'INSERT INTO SYS_IMAGENES (CODIGO, NOMBRE, IMAGEN, FORMATO, ORIGEN, RUTA) VALUES (?CODIGO, ?NOMBRE, ?IMAGEN, ?FORMATO, ?ORIGEN, ?RUTA)';
              Open;

              // Comienza el insert
              Insert;
              Result := DMMain.Contador_GEN(DS, 'CONTA_IMAGENES', 'CODIGO');
              FieldByName('NOMBRE').AsString := aFileName;
              FieldByName('FORMATO').AsString := aFileExt;
              FieldByName('RUTA').AsString := Archivo;

              if EnBaseDeDatos then
              begin
                 FieldByName('ORIGEN').AsInteger := 0;
                 m := DS.CreateBlobStream(FieldByName('IMAGEN'), bmWrite);
                 try
                    f := TFileStream.Create(Archivo, fmOpenRead);
                    try
                       m.CopyFrom(f, f.Size);
                    finally
                       f.Free;
                    end;
                 finally
                    m.Free;
                 end;
              end
              else
                 FieldByName('ORIGEN').AsInteger := 1;
              Post;
              Close;
              Transaction.Commit;
           finally
              Transaction.Free;
           end;
        end;
     finally
        FreeAndNil(DS);
     end;
  end;
end;

[Tcmn]

Me parece buena idea. Creo que mejor así lo haré para que se carguen las imágenes y poder mostrarlas con una consulta aparte. Muchas gracias y saludos