Determinar mes a partir de una fecha

[ekstase]

Hola amigos. Otra vez necesito su ayuda. Utilizo delphi 7 y Mysql, la consulta es la siguiente: De una fecha necesito determinar a cual mes corresponde por ejemplo:

03/01/2011 = Enero
02/04/2011 = Abril
Etc..

Pero esto me gustaria hacerlo con funciones de delphi, dado que tomo la fecha de una Datetimepicker. Desde ya Muchas Gracias.-
Y perdon si no estoy en el foro correcto es que no encontre donde más. Graicas.

[ecfisa]

Hola ekstase.

Podrías hacer una función que lo devuelva:

Código Delphi [-]
uses DateUtils;

function NombreDelMes(ADate: TDate): string;
const
   MESES: array[1..12] of string=('Enero','Febrero','Marzo','Abril','Mayo','Junio','Julio', 
                                 'Agosto','Septiembre','Octubre','Noviembre','Diciembre');
begin
  Result:= MESES[MonthOf(ADate)];
end;

Una llamada de ejemplo:

Código Delphi [-]
procedure TForm1.DateTimePicker1Change(Sender: TObject);
begin
  ShowMessage(NombreDelMes(DateTimePicker1.Date));
end;

Un saludo.

[[Caral]]

Hola
Bueno, si eres como yo que no entiendes bien las funciones que los maestros nos ponen de ejemplo entonces nos buscamos la manera de no usarlas y generar lo mismo sin estas.

Código Delphi [-]
  private
    { Private declarations }
  public
    { Public declarations }
  end;

const
meses: array[1..12] of string=('Enero','Febrero','Marzo','Abril','Mayo','Junio','Julio',
                                 'Agosto','Septiembre','Octubre','Noviembre','Diciembre');

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.DateTimePicker1Change(Sender: TObject);
var
  a: string;
begin
  a:= FormatDateTime('m',Datetimepicker1.Date);
  Label1.Caption:= meses[StrToInt(a)];
end;

end.

Saludos

[cloayza]

Para que inventar la rueda amigos...

Ya existen los vectores que contienen los nombres de los meses, estan en la unit SysUtils.

Código Delphi [-]
procedure TForm1.DateTimePicker1Change(Sender: TObject);
begin
      ShowMessage(SysUtils.ShortMonthNames[ MonthOf(DateTimePicker1.Date) ]); //Ene, Feb, Mar
      ShowMessage(SysUtils.LongMonthNames[ MonthOf(DateTimePicker1.Date) ]); //Enero, Febrero, ...
end;

Saludos cordiales

[[Chris]]

algo un poco más simple talvez :

Código Delphi [-]
    ShowMessage(FormatDateTime('mmmm', mi_variable_fecha))

Nota: El único inconveniente es que este código depende de la configuración regional y de idiomas configuradas en el sistema. Si por ejemplo un usuario tiene configurado Inglés (EEUU) entonces los nombre de los meses apareceran en Inglés. Para solucionar esto es necesario pasar una variable de tipo TDatetimeSettings en el último parámetro de la función FormatDateTime.

[[Caral]]

Hola
Bueno, no se, pero a mi no me va este ejemplo.
Me dice que no he declarado MonthOf.
Me da la impresion de que es por el Delphi 6 que uso.
Por si las dudas, si he declarado SysUtils.
Que hago mal?
Saludos

[cloayza]

Puede ser lo que tu dices...

Yo tengo el D2007...La función MonthOf, esta en la unit DateUtils.

Saludos