¿Cuantas imagenes puedo cargar en un exe?

[JesusG]

Hola, me explico. Estoy haciendo algo como un libro electronico en Delphi, esencialmente son imagenes jpeg, más de 100, almacenadas en varios Timagelist, las cuales se van presentando una a una. En el disco duro ocupan entre 2 y 3 Mb.
¿Tendre algun problema en cuanto al uso de memoria ?. Es decir, cuando lanzamos el ejecutable ¿se cargan todas la imagenes contenidas a la vez en memoria?, lo cual podria consumir los recursos de muchos sistemas. O no es asi y cada vez que se presenta una imagen se devuelve al sistema la memoria consumida por la anterior.
Por cierto, me podrias decir alguna forma sencilla de hacer un efecto fade.
Gracias.

[[Bicho]]

Hola,

yo personalmente y en tú caso no dispondría todas esas imágenes en el ejecutable, los sacaria del exe y los metería en una carpeta normal y corriente, usaría un TImage simple e iria pasando de imágen en imagen, para así sólo tener cargada una imágen a la vez.

Con respecto a lo del fade tengo ésta función pero sólo funciona si las imágenes son bitmap de 16 o 32 bits, no se si será tu caso, pero yo la dejo aquí por si a alguien le sirve.

Código Delphi [-]
procedure Apaga(const BMP:TImage; Pausa:integer);
var BytesPorScan, w, h, Pasadas : integer;
    p : pByteArray;
begin
  try  
    BytesPorScan := Abs(Integer(BMP.Picture.Bitmap.ScanLine[1]) - Integer(BMP.Picture.Bitmap.ScanLine[0]));
  except
    raise exception.create('Error');
  end;
  for Pasadas := 1 to 256 do begin   {Decrementamos las componentes RGB de cada pixel}
    for h := 0 to BMP.Picture.Bitmap.Height - 1 do begin
      P := BMP.Picture.Bitmap.ScanLine[h];
      for w := 0 to BytesPorScan - 1 do if P^[w] > 0 then P^[w] := P^[w] - 1;
    end;
    Sleep(Pausa);
    BMP.Refresh;
  end;
end;

También buscando por los trucos, he visto éste de seonae, un poco más complicado pero que puedes personalizar y sirve para muchos más formatos

Cambiar brillo y color de una imagen

Espero te sirva

Saludos

[Neftali [Germán.Estévez]]

Empezado por JesusG

...más de 100, almacenadas en varios Timagelist

Yo las almacenaría en disco y a medida que las vayas necesitando las vas cargando (LoadFromFile); Tus sospechas son ciertas, si las pones en un ImagesList consumirás muchas más memoria de la necesaria.

En cuanto a los efectos, aparte del código citado, puedes echarle un vistazo a la librería Graphics32 para Delphi y Open Source.

[JesusG]

Me va bien el codigo para el efecto fade, trabajo con imagenes de 16 bit.
Lo de dejar las imagenes en una carpeta fuera del ejecutable siempre lo puedo hacer pero no quisiera dar demasiadas facilidades para que alguien se aproveche de ellas, me esta llevando mucho trabajo el diseñarlas, incluso cambiando su extendion por un .dat, por ejemplo, para intentar ocultarlas, me parece un metodo muy debil de proteccion.
De todas formas se me ocurre lo siguiente. ¿Se podria añadir una especie de marca de agua en las imagenes almacenadas en una carpeta y que desapareciera al cargarse en tiempo de ejecucion?, seria un magnifico metodo de preservar la "copia".
Gracias

[pcicom]

Si lo que no quieres es dar facilidades de copia de tus imagenes protegelas grabandolas encriptadas y al ser visualisadas en tu applicacion desencriptalas.. y listo... ya en tu programa estaria el codigo de cnriptacin/desencriptacion...

por ahi vi un truco de encriptacion en TRUCOMANIA...

[dec]

Hola,

por ahi vi un truco de encriptacion en TRUCOMANIA...

Bueno. No está nada mal. Empero, no hay que ir más lejos que al apartado de Trucos del ClubDelphi. Y el propio buscador de los Foros ofrecerá información a buen seguro sobre cifrar y descifrar archivos. Se ha tratado en más de una ocasión el tema.

[Ñuño Martínez]

También puedes guardar las imágenes en un ZIP encriptado. Creo que había algún componente que era capaz de obtener datos de archivos ZIP, RAR y algún formato más.

[[seoane]]

Veo que se me adelantaron, pero por lo menos dejame aportar un poco de código. Aquí te dejo una encriptacion sencilla, dado que aunque uses una encriptacion fuerte la clave tendrá que guardarse dentro de tu ejecutable, no veo la necesidad de complicarse la vida, solo se trata de ponérselo un poco mas difícil.

Código Delphi [-]
procedure Cifrar(Buffer: PByte; Key: Longint; Count: Cardinal);
begin
  RandSeed:= Key;
  while Count > 0 do
  begin
    Buffer^:= Buffer^ XOR Byte(Random($FF));
    inc(Buffer);
    dec(Count);
  end;
end;

// Para cifrar el archivo
begin
  with TMemoryStream.Create do
  try
    LoadFromFile('d:\1.jpg');
    Cifrar(Memory,1978,Size);
    SaveToFile('d:\1.dat');
  finally
    Free;
  end;
end;

// Para usarlo una vez cifrado
var
  Stream: TMemoryStream;
  Jpg: TJPEGImage;
begin
  Stream:= TMemoryStream.Create;
  Jpg:= TJPEGImage.Create;
  try
    Stream.LoadFromFile('d:\1.dat');
    Cifrar(Stream.Memory,1978,Stream.Size);
    Jpg.LoadFromStream(Stream);
    // Aqui ya tenemos la imagen cargada, podemos mostrarla
    // en un TImage, por ejemplo
    Image1.Picture.Assign(Jpg);
  finally
    Jpg.Free;
    Stream.Free;
  end;
end;

En cuanto al código del Fade que te paso Bicho, solo añadir que la imagen tienen que ser un Bmp para que funcione, si es un jpg tendrás que convertirla primero.

Y por ultimo, la marca de agua seria sencilla si las imágenes se guardaran en formato bmp, pero siendo jpg la cosa se complica.

[Ñuño Martínez]

Una anotación respecto al código de seoane: usar la función Random es peligroso. La razón es que existen múltiples algoritmos para generar números (pseudo)aleatorios y ya se han dado casos de que se ha re-escrito las librerías de algún compilador y eso dió problemas en los algoritmos de encriptación<->desencriptación. Si es posible busca algún algoritmo que genere números aleatorios e implementalo tú mismo.

[[seoane]]

Empezado por Ñuño Martínez

Una anotación respecto al código de seoane: usar la función Random es peligroso. La razón es que existen múltiples algoritmos para generar números (pseudo)aleatorios y ya se han dado casos de que se ha re-escrito las librerías de algún compilador y eso dió problemas en los algoritmos de encriptación<->desencriptación. Si es posible busca algún algoritmo que genere números aleatorios e implementalo tú mismo.

¿que te parece esta otra?, ya no uso el random. Ahora la clave es un string.

Código Delphi [-]
procedure Cifrar(Buffer: PByte; Key: String; Count: Cardinal);
var
  i: integer;
begin
  if Length(Key)=0 then
    Exit;
  i:= 1;
  while Count > 0 do
  begin
    Buffer^:= Buffer^ XOR Byte(Key[i]);
    inc(Buffer);
    dec(Count);
    i:= (i mod Length(Key)) + 1;
  end;
end;

Ya se que son algoritmos muy simples, pero ya que la clave se va a guardar en el ejecutable, no hay necesidad de usar algoritmos mas complejos.

[Ñuño Martínez]

Este me gusta más (que conste que el anterior tampoco estaba mal, siempre que Random use un algoritmo concreto). Con el uso de una String, además, puede guardarse la clave (key) en un archivo de texto (por ejemplo, usar el archivo README.TXT).

[JesusG]

El procedimiento de encriptar/desencriptar ya lo utilice, pero veo que el codigo que poneis es mas sencillo que el que use, asi que lo probare.
seoane dice que poner una marca de agua es falcil en una .bmp, y que despues dicha marca no aparezca en ejecucion, ¿podriais darme una pista de como hacerlo?.
Gracias por las respuestas.

[[seoane]]

Empezado por JesusG

seoane dice que poner una marca de agua es falcil en una .bmp, y que despues dicha marca no aparezca en ejecucion, ¿podriais darme una pista de como hacerlo?.

Para marcar la imagen dibujaremos sobre la ella una marca, utilizando el metodo XOR. Para eliminarla solo tenemos que volver a dibujar sobre la imagen la misma marca utilizando el otra vez metodo XOR, y como es bien sabido (a xor b) xor b = a

Código Delphi [-]
procedure Marcar(Bitmap: TBitmap; Texto: String);
var
  Marca: TBitmap;
  i,j: Integer;
begin
  Marca:= TBitmap.Create;
  try
    Marca.Canvas.Brush.Color:= clBlack;
    Marca.Canvas.Font.Name:= 'Arial';
    // Ajusta el tamaño de la fuente si es necesario
    Marca.Canvas.Font.Size:= 72;
    Marca.Canvas.Font.Color:= clWhite;
    Marca.Canvas.Font.Style:= [fsBold, fsItalic];
    Marca.Width:= Marca.Canvas.TextWidth(Texto);
    Marca.Height:= Marca.Canvas.TextHeight(Texto);
    Marca.Canvas.TextOut(0,0,Texto);
    i:= (Bitmap.Width - Marca.Width) div 2;
    j:= (Bitmap.Height - Marca.Height) div 2;
    Bitblt(Bitmap.Canvas.Handle,i,j,Marca.Width,Marca.Height,
      Marca.Canvas.Handle, 0, 0, SRCINVERT);
  finally
    Marca.Free;
  end;
end;

procedure MarcarArchivo(Origen, Destino: string; Texto: String);
var
  Bitmap: TBitmap;
begin
  Bitmap:= TBitmap.Create;
  with Bitmap do
  try
    LoadFromFile(Origen);
    Marcar(Bitmap,Texto);
    SaveTofile(Destino);
  finally
    Free;
  end;
end;



// Para marcar el archivo
 MarcarArchivo('d:\1.bmp','d:\2.bmp','Marca');

// Para cargar la imagen marcada en un TImage
var
  Bitmap: TBitmap;
begin
  Bitmap:= TBitmap.Create;
  with Bitmap do
  try
    LoadFromFile('d:\2.bmp');
    // El texto debe ser el mismo que se utilizo al marcarla
    Marcar(Bitmap,'Marca');
    Image1.Picture.Assign(Bitmap);
  finally
    Free;
  end;
end;

[[seoane]]

Continuando mi mensaje anterior, para que nadie caiga en la tentación de usar el photoshop para eliminar la marca de agua, vamos a complicarlo un poquito mas:

Código Delphi [-]
// Esto provoca un efecto muy bonito y dificil de reproducir con el photshop
procedure Colorear(Bitmap: TBitmap);
var
  P: PByte;
  i,j: Integer;
begin
  Bitmap.PixelFormat:= pf24bit;
  for j:= 0 to Bitmap.Height - 1 do
  begin
    P:= Bitmap.ScanLine[j];
    for i := 0 to (Bitmap.Width*3)-1 do
    begin
      if P^ > 0 then
        P^:= Byte(i * j);
      inc(P);
    end;
  end;
end;

procedure Marcar(Bitmap: TBitmap; Texto: String);
var
  Marca: TBitmap;
  i,j: Integer;
begin
  Marca:= TBitmap.Create;
  try
    Marca.Canvas.Brush.Color:= clBlack;
    Marca.Canvas.Font.Name:= 'Arial';
    // Ajusta el tamaño de la fuente si es necesario
    Marca.Canvas.Font.Size:= 72;
    Marca.Canvas.Font.Color:= clWhite;
    Marca.Canvas.Font.Style:= [fsBold, fsItalic];
    Marca.Width:= Marca.Canvas.TextWidth(Texto);
    Marca.Height:= Marca.Canvas.TextHeight(Texto);
    Marca.Canvas.TextOut(0,0,Texto);
    Colorear(Marca);  // Esto es lo nuevo
    i:= (Bitmap.Width - Marca.Width) div 2;
    j:= (Bitmap.Height - Marca.Height) div 2;
    Bitblt(Bitmap.Canvas.Handle,i,j,Marca.Width,Marca.Height,
      Marca.Canvas.Handle, 0, 0, SRCINVERT);
  finally
    Marca.Free;
  end;
end;