Fecha Modificacion fichero

[jhonalone]

Hola, amigos.
Estoy intentando ver la fecha de modificación de un fichero que está en mi página de internet.
Por más vueltas que he dado, no he encontrado nada. La function FileAge, no funciona, pues el fichero de internet viene dado como puntero y no como string.
Agradezco cualquier información.
Saludos.

[Casimiro Notevi]

¿Cómo lo haces, con indy?

[jhonalone]

No sé cómo hacerlo. No he usado Indi. Pero admito cualquier solución.
Gracias Casi.

[jhonalone]

Estoy más o menos aquí en este fragmento de código

Código Delphi [-]
hFile := CreateFile(PChar(Archivo), GENERIC_WRITE, 0, nil, CREATE_ALWAYS,
    FILE_ATTRIBUTE_NORMAL, 0);
  if (hFile <> INVALID_HANDLE_VALUE) then
  begin
    hNet := InternetOpen('agent', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
    if (hNet <> nil) then  //Si existe conexion a internet
    begin
      hUrl := InternetOpenUrl(hNet, PChar(Url), nil, 0, INTERNET_FLAG_RELOAD, 0);
      if (hUrl <> nil) then  // Existe el fichero en internet
      begin   
      FechaModiFileInternet:=FileAge(hFile);

[jhonalone]

Mañana tengo que madrugar para ir a trabajar. Perdonar si no os contesto esta noche.
Saludos.

[ecfisa]

Hola jhonalone.

Empezado por jhonalone

No sé cómo hacerlo. No he usado Indi. Pero admito cualquier solución.
Gracias Casi.

Usando el componente TidHTTP de Indy es muy simple:

Código Delphi [-]
uses idHTTP;

function GetInternetFileDateTime(aFileName: string): TDateTime;
begin
  with TidHTTP.Create(nil) do
  try
    Head(aFileName);
    Result:= Response.LastModified;
  finally
    Free;
  end;
end;

Saludos

[[nlsgarcia]]

jhonalone,

Empezado por jhonalone

...Estoy intentando ver la fecha de modificación de un fichero que está en mi página de internet...

Revisa este código:

Código Delphi [-]
 unit Unit1;
 
 interface
 
 uses
   Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
   Dialogs, StdCtrls, WinInet;
 
 type
   TForm1 = class(TForm)
     Button1: TButton;
     procedure Button1Click(Sender: TObject);
   private
     { Private declarations }
   public
     { Public declarations }
   end;
 
 var
   Form1: TForm1;
 
 implementation
 
 {$R *.dfm}
 
 // Obtiene la última fecha de modificación de un archivo en internet
 function GetLastModifiedDate(Url : String) : TDateTime;
 var
    hInet : HINTERNET;
    hUrl : HINTERNET;
    LastModifiedDate : SYSTEMTIME;
    SizeDate : DWORD;
    Index : DWORD;
 begin
    try
       hInet := InternetOpen(PChar(Application.Title),INTERNET_OPEN_TYPE_PRECONFIG,nil,nil,0);
       hUrl := InternetOpenURL(hInet,PChar(Url),nil,0,0,0);
       SizeDate := SizeOf(LastModifiedDate);
       Index := 0;
       if HttpQueryInfo(hUrl,
                        HTTP_QUERY_LAST_MODIFIED or HTTP_QUERY_FLAG_SYSTEMTIME,
                        @LastModifiedDate,
                        SizeDate,
                        Index)
       then
          Result := SystemTimeToDateTime(LastModifiedDate)
       else
          Result := 0;
    finally
       InternetCloseHandle(hUrl);
       InternetCloseHandle(hInet);
    end;
 end;
 
 // Muestra la última fecha de modificación de un archivo en internet
 procedure TForm1.Button1Click(Sender: TObject);
 var
    Url : String;
    LastModifiedDate : String;
 begin
    Url := 'http://www.math-magic.com/pdf_files/basic_memorization/prime.pdf';
    LastModifiedDate := FormatDateTime('yyyy/mm/dd hh:mm:ss',GetLastModifiedDate(Url));
    MessageDlg(LastModifiedDate,mtInformation,[mbOK],0);
 end;
 
 end.

El código anterior en Delphi 7 sobre Windows 7 Professional x32, obtiene la fecha de última modificación de un recurso url por medio de las funciones de Windows Internet (WinINet) application programming interface (API) .

Espero sea útil

Nelson.

[jhonalone]

Primero: gracias a Ecfisa y a Nelson (por orden de respuestas), por vuestro esfuerzo al responderme.

Segundo: os cuento.

Ecfisa, Todavía no me puedo creer que un código tuyo no funcione a la primera. Me da un error en la línea del result, con la excepción EIdHTTPProtocolException con el mensaje "HTTP/1.1 404 Not Found" Puede que los Indy que he instalado estén obsoletos, son los que venían con Dephi7.

Nelson, tu código funciona perfectamente, excepto con algunas extensiones de ficheros. Concretamente con ".php", no sé si con alguna otra. Ah, la función discrimina entre mayúsculas y minúsculas, en el nombre de la url, por le interesa a alguien.

Nuevamente gracias a ambos por vuestro esfuerzo e interés.

Saludos.

Juan Manuel.