Ayuda con TPanel

[FideRosado]

hola, tendo que cambiar el color a un tpanel a traves de la asignacion de un evento, es decir ,, tengo una lista de tpanel creandoce y dentro tengo un tchekbox, luego asigno una funcion al evento onclick del chekbox , pero no se como al seleccionar el check box me cambie el color del panel, trate de usar parent.name para obtener el nombre del panel pero hasta ahy me quedo,

aca les paso el codigo..

en public
--------------------------------------

Código Delphi [-]
 procedure ChkClick(Sender: TObject);

en implementation
-------------------------------------

Código Delphi [-]
procedure TForm1.ChkClick(Sender: TObject);
begin

  with Sender as TCheckBox  do
  begin
    ShowMessage( Parent.Name );

      with Parent do
      begin
          Color:=$00C67200;
      end;

  end;

end;

procedure TForm1.RzToolButton1Click(Sender: TObject);
begin

    Pnl := TRzPanel.Create(nil);
    Pnl.Name:= 'PnlUser'+IntToStr(numberpanel);
   // Pnl.OnClick := ChkClick;
    Pnl.Caption:='';
    //'Hola al panel '+IntToStr(numberpanel);
    Pnl.Align:= alTop;
    if changecolor = 0 then
    begin
      Pnl.Color:=$00F7F7F7;
      changecolor:=1;
    end else begin
      Pnl.Color:=clBtnHighlight;
      changecolor:=0;
    end;

    Pnl.Height:=60;
    Pnl.BorderSides:=[];
    Pnl.Parent:= ScrollBox1;
   
   //  ckekbox
   //  Chk := TCheckBox.Create(Pnl);

   with TCheckBox.Create(nil) do
   begin
    OnClick := ChkClick;
    Name:= 'CheckMail'+IntToStr(numberpanel);
    Caption:='';
    left:=16;
    top:=21;
    Width:=17;
    Parent:= Pnl;
   end;

end;

[Casimiro Notevi]

Bienvenido a clubdelphi, ¿ya leiste nuestra guía de estilo?, gracias por tu colaboración

Recuerda poner los tags al código fuente, ejemplo:



Gracias

Por cierto, has puesto tu pregunta en el foro "Internet" y no tiene nada que ver.

De nuevo, Bienvenido


.

[ecfisa]

Hola FideRosado, bienvenido a Club Delphi

Como a todos los que se inician te invitamos a que leas nuestra guía de estilo.

También te recomiendo que cuando incluyas código en tus mensajes utilices TAG's, una imágen del uso:


Con respecto a tu consulta, entiendo que deseas que los paneles cambien de color de acuerdo a si el TCheckBox que contiene esté o no marcado.

No uso el control TRzPanel, pero te pongo un ejemplo basado en tu código usando el control TPanel:

Código Delphi [-]
...
procedure TForm1.CheckBoxClick(Sender: TObject);
begin
  if TCheckBox(Sender).Checked then
    TPanel(TCheckBox(Sender).Parent).Color := clRed 
  else
    TPanel(TCheckBox(Sender).Parent).Color := clBtnFace
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  Pnl         := TPanel.Create(nil);
  Pnl.Name    := 'PnlUser' + IntToStr(numberpanel);
  Pnl.Caption := '';
  Pnl.Align   := alTop;
  Pnl.Height  := 60;
  Pnl.Parent  := ScrollBox1;
  Pnl.ParentBackground := False;
  
  with TCheckBox.Create(nil) do
  begin
    OnClick := CheckBoxClick;
    Name    := 'CheckMail'+ IntToStr(numberpanel);
    Caption := '';
    left    := 16;
    top     := 21;
    Width   := 17;
    Parent  := Pnl;
  end;
end;

Saludos.

Edito: (Disculpas Casimiro, no había visto tu mensaje mientras escribía)

[Casimiro Notevi]

Empezado por ecfisa

Edito: (Disculpas Casimiro, no había visto tu mensaje mientras escribía)

Tu respuesta es muchísimo mejor que la mia, y además le has resuelto la duda

[FideRosado]

la verdad es que estoy tan concentrado en el problema que ni lo note ,.. ahora mismo pruebo el codigo, para ver si me funciona, la verdad este es un foro de lo mejor..
yo uso trz componentes desde hace rato y la verdad es que es bueno, tiene muchas facilidades,..con los estilos y otros..
echenles un vistazo..

[FideRosado]

aca les envio una actualizacion del codigo
uso la misma propiedad color para tomar y debolver el estado del chekbox...

Código Delphi [-]
procedure TForm1.ChkClick(Sender: TObject);
begin
  if TRzCheckBox(Sender).Checked then
  begin
    TRzCheckBox(Sender).Color:= TRzPanel(TRzCheckBox(Sender).Parent).Color;
    TRzPanel(TRzCheckBox(Sender).Parent).ParentColor:=false;
    TRzPanel(TRzCheckBox(Sender).Parent).Color := $00CAF0FF;
  end
  else
  begin
    TRzPanel(TRzCheckBox(Sender).Parent).Color := TRzCheckBox(Sender).Color
  end;
end;

aqui agrego unas lineas, que parecen bobas pero nos permiten guardar independientemente el color de fondo..
y que se mantenga alternados..los colores
.. pero me di cuenta que cuando selecciono mas de dos y los desmarco no se me ponen los colores como son ,, que se le puede sumar a este tema para solucionarlo..

bueno me puse a trabajar en eso y lo consegui..

primero use un TRzCheckBox en vez de TCheckBox , porque?? este cambio , pues , trz me permite asignar un color mientras lo pongo transparente, ahi esta el truco, mantener el color de fondo, guardandolo en el mismo objeto que lo ejecuta...

Código Delphi [-]
  with TRzCheckBox.Create(nil) do
  begin
    OnClick := ChkClick;
    Name:= 'CheckMail'+IntToStr(numberpanel);
    Caption:='';     ParentColor:=false;
    Transparent:=true;
    left:=16;
    top:=21;
    Width:=17;
    Parent:= Pnl;
  end;

[FideRosado]

ahora estoy pensando en incorporar una funcion o procedimiento en un boton que me permita saber si entre los paneles , que he creado tengo un checkbox activo, pero no encuentro la forma de hacerlo,.. necesito ayuda con eso ...

estoy tratando pero no se me ocurre nada..

[ecfisa]

Hola FideRosado.

Código Delphi [-]
function ActiveCheckBoxes(SB: TScrollBox): Integer;
var
  i,j: Integer;
begin
  Result := 0;
  for i:= 0 to SB.ControlCount - 1 do
    if SB.Controls[i] is TPanel then
      for j:= 0 to TPanel(SB.Controls[i]).ControlCount-1 do
        if TPanel(SB.Controls[i]).Controls[j] is TCheckBox then
          Inc(Result, Integer(TCheckBox(TPanel(SB.Controls[i]).Controls[j]).Checked))
end;

Un ejemplo de uso:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var
  n: Integer;
begin
  n := ActiveCheckBoxes(ScrollBox1);
  if n > 0 then
    ShowMessage(Format('Hay %d casillas marcadas',[n]))
end;

Saludos

[FideRosado]

con ese mismo codigo , quiero q1ue el penel que es el padre del checkbox, que esta activado ,, o cuantos de ellos esten activados, se eliminen del ScrollBox1,he resuelto el padre segun el estado del checkbox, pero, la verdadd es que lo he intentado muchas veces con resultados negativos , alguna idea por parte de ustedes ..

[ecfisa]

Empezado por FideRosado

con ese mismo codigo , quiero q1ue el penel que es el padre del checkbox, que esta activado ,, o cuantos de ellos esten activados, se eliminen del ScrollBox1,he resuelto el padre segun el estado del checkbox, pero, la verdadd es que lo he intentado muchas veces con resultados negativos , alguna idea por parte de ustedes ..

Hola.

Código Delphi [-]
procedure TForm1.btnDelSelectPnlClick(Sender: TObject);
var
  i,j: Integer;
begin
  for i:= ScrollBox1.ControlCount - 1 downto 0 do
    if ScrollBox1.Controls[i] is TPanel then
      for j:= 0 to TPanel(ScrollBox1.Controls[i]).ControlCount-1 do
        if (TPanel(ScrollBox1.Controls[i]).Controls[j] is TCheckBox) and
           (TCheckBox(TPanel(ScrollBox1.Controls[i]).Controls[j]).Checked) then
          ScrollBox1.Controls[i].Free;
end;

Saludos

[FideRosado]

he probado el codigo , pero me da vateo ,
pondre aca algo parecido a lo que estoy tratando de hacer..

-scrolbox1
|
|-panel1
| |
| -checkbox1
|-panel2
| |
| -checkbox2
|-pane3
| |
| -checkbox3
|-panel4
| |
| -checkbox4


aca tengo representado como estan hubicados los elementos, pero cuando elimino uno , me doy cuenta que estamos haciendo la operacion dentro de un ford, el cual nos da error en list.bound cuando el cuenta..
y solo elimina 1 pero he intentedo eliminar mas de uno a la vez y dada ,.. creo que restando al for el i puede que salga..

rectifiquenme aver que sale de esto..

[FideRosado]

he probado algo parecido pero no me sale la verdad , será que se me esta escapando algo..mi mente y mi cuerpo esta cansado jejje, dormire un rato pero les pondre este cod que estoy provando , tirando piedras , como se dice

Código Delphi [-]
procedure TForm1.RzPanel15Click(Sender: TObject);
 var
  u,h:integer;
  n,m: string;
  var t:Tcomponent;
begin
  n :=  ActiveCheckBoxes(ScrollBox1);

if n <> '' then begin

    u:= CharCount(n,'|');
    for h:= 1 to u do begin
     m:= GetToken( n, '|' , h );
     // t.Name:= m;
      t := FindComponent(m);
          if  Assigned(t) then begin

             ShowMessage('se lozalizo el control ' + t.Name);
             //t.Free;

            end else begin

             ShowMessage('No se lozalizo el control ' + t.Name);

            end;
    end;
  end;
end;

acuerdence que yo aca envio una string con los nombres a los que voy a eliminar, separados por una barra vertival,, | ,
de esta forma se podra hacer diganme si hay variantes..

[ecfisa]

Hola.

Empezado por FideRosado

pero cuando elimino uno , me doy cuenta que estamos haciendo la operacion dentro de un ford, el cual nos da error en list.bound cuando el cuenta..

Por casualidad... ¿Invertiste el órden del for exterior del código del mensaje #10 dándole sentido creciente ?

Empezado por FideRosado

...
solo elimina 1 pero he intentedo eliminar mas de uno a la vez y dada ,.. creo que restando al for el i puede que salga

Debido a que no publicas el código que estás utilizando, no se que cuál fue el error de transcripción que provoca los fallos, pero te adjunto un demo para que puedas revisarlo con comodidad.

El demo utiliza sólo código que se ha sido tratado en este hilo, esta probado y funciona correctamente: Crea los paneles, los pinta cuando el CheckBox es seleccionado y elimina ninguno, uno, varios o todos acorde estén seleccionados.

Saludos

[FideRosado]

si, me parece que puse el forn en creciente , entonces eso elimina la posibilidad del error...

[FideRosado]

he echo unos cambios y aca los comparto con ustedes..
en este pedazo colorea denuevo los paneles creados dentro sel srolbox para que mantenda un estilo en la aplicacion..

Código Delphi [-]
function ColoreaPanels(SB: TScrollBox): string;
var i,j: Integer;
begin
  Result := '';
  changecolor := 0;
  for i:= 0 to SB.ControlCount - 1 do
  begin
    if SB.Controls[i] is TRzPanel then
    begin
      if changecolor = 0 then
      begin
        if TRzPanel( SB.Controls[i] ).Color <> $00F0E7E1 then
        begin
          TRzPanel( SB.Controls[i] ).Color:=$00F7F7F7;
        end;
        changecolor:=1;
      end
      else
      if changecolor = 1 then
      begin
        if TRzPanel( SB.Controls[i] ).Color <> $00F0E7E1 then
        begin
          TRzPanel( SB.Controls[i] ).Color:=clBtnHighlight;
        end;
        changecolor:=0;
      end;
    end;
  end;
end;

aca crea un checkbox que me marque todos los de su tipo en el area que kieran ..

Código Delphi [-]
procedure TForm1.RzCheckBox1Click(Sender: TObject);
begin
  if RzCheckBox1.Checked then
  begin
    CheckAllPanels(ScrollBox1, true );
  end
  else
  begin
    CheckAllPanels(ScrollBox1, false );
  end;
end;

function CheckAllPanels(SB: TScrollBox; condition: Boolean ): string;
var i,j: Integer;
begin
  Result := '';
  for i:= 0 to SB.ControlCount - 1 do
  begin
    if SB.Controls[i] is TRzPanel then
    begin
      for j:= 0 to TRzPanel(SB.Controls[i]).ControlCount-1 do
      begin
        if TRzPanel(SB.Controls[i]).Controls[j] is TRzCheckBox then
        begin
          TRzCheckBox(TRzPanel(SB.Controls[i]).Controls[j]).Checked := condition;
        end;
      end;
    end;
  end;
end;

cuando pense en eliminar el panel dentro de el area, pence en hacerlo de muchas formas, pero me he despertado de buena gana y mente , aqui puedes mandar a buscar el panel por su nombre y luego eliminarlo, asi no hay que hacer un for...

Código Delphi [-]
procedure TForm1.RzPanel15Click(Sender: TObject);
var u,h:integer;
  n,m: string;
var t:TControl;
begin
  n := ActiveCheckBoxes(ScrollBox1);
  if n <> '' then
  begin
    u:= CharCount(n,'|');
    for h:= 1 to u do
    begin
      m:= GetToken( n, '|' , h );
      // t.Name:= m; t := ScrollBox1.FindChildControl(m);
      if t is TControl then
      begin
        // ShowMessage('se lozalizo el control ' + t.Name);
        t.Free; RzCheckBox1.Checked:=false;
      end
      else
      begin
        ShowMessage('No se lozalizo el control ' + t.Name);
      end;
    end;
    ColoreaPanels(ScrollBox1);
  end;
end;

[ecfisa]

Empezado por FideRosado

cuando pense en eliminar el panel dentro de el area, pence en hacerlo de muchas formas, pero me he despertado de buena gana y mente , aqui puedes mandar a buscar el panel por su nombre y luego eliminarlo, asi no hay que hacer un for...

Hola.

En realidad si haces un simple cambio en la creación de los TPanel y TCheckBox cambiando su owner (propietario),

Código Delphi [-]
  Pnl := TPanel.Create(Self); // (donde Self es Form1)
  ...
  with TCheckBox.Create(Self) do

te sería mucho mas simple eliminar un panel por su nombre.

Código Delphi [-]
...
var
  C: TComponent;
begin
  C := FindComponent('PnlUser1');
  if Assigned(C) then 
    C.Free;
end;

Saludos

[ecfisa]

Hola.

Recordé que sólo se deben borrar aquellos paneles cuyos CheckBox estén chequeados...

Dado que en la creación, a paneles y CheckBoxes les das nombres que sólo difieren de otros sólo por su terminación (PnlUser1, PnlUser2,...) (CheckMail1, CheckMail2, ...). Además contenedor y contenido se corresponden en ese último número y que cada panel tiene contiene un CheckBox, se puede efectuar la eliminación mediante un método enviando como argumento sólo el número:

Código Delphi [-]
procedure TForm1.FreePanel(const Nro: Integer);
var
  C1: TComponent;
begin
  C1 := FindComponent('PnlUser' + IntToStr(Nro));
  if Assigned(C1) then
  begin
    if TCheckBox(FindComponent('CheckMail' + IntToStr(Nro))).Checked then
      C1.Free;
  end;
end;

Saludos