Interconexion de bloques

[astwin]

Hola, ya me he puesto a fondo con TsimpleGraph. Voy poco a poco comprendiendo como funciona.

El problema que tengo es que el linkado entre objetos se realiza mediante lineas que parten desde el centro del objeto, no pudiendose definir un punto fijo del objeto para linkarlo a otros.

Mi solucion ha sido crear cada bloque como un rectangulo, y las entradas y salidas tambien como rectangulos mas pequeños. El problema ahora lo tngo a la hora de mover el bloque grande, que no se como hacer que se puedan mover a la vez los pequeños (ademas el bloque grande esta alineado a la cuadricula y los pequeños no). Haber si alguien puede echarme un cable.

Código Delphi [-]
type
  // Rectangulo que servirá como entrada
  TGraphIn=class(TRectangularNode)
    public
      procedure init();
  end;
  // Rectangulo que servirá como salida
  TGraphOut=class(TRectangularNode)
      procedure init();
  end;
  // Rectangulo que será el cuerpo del bloque
  TGraphBlock=class(TRectangularNode)
    public
      nIn,nOut: integer ; //numero de entradas y de salidas
      vIn: array of TGraphNode;
      vOut: array of TGraphNode;
      IOHeigth: Integer;
      //GraphIORadious: integer; // Altura de las entradas y salidas
      InSelected:integer;
      OutSelected:integer;
      procedure init();
      //function QueryHitTest(const Pt: TPoint): DWORD; override;
      //procedure Draw(Canvas: TCanvas); override;
      //procedure MouseDown(Button: TMouseButton; Shift: TShiftState; const Pt: TPoint);override;
   end;

Type
  TGraphLine=class(TGraphLink)

  end;

const
  // ForEachObject Actions
  FEO_DesactiveIO             = 00;


implementation
uses
  unit1,unit2;





procedure TGraphBlock.init();
var
  I: Integer;
  inc: Integer;
  bound:Trect;
  pt: Tpoint;
begin
  // Opciones del nodo;
  self.NodeOptions:=[gnoMovable,gnoShowBackGround];
  // Imagen del nodo;
  self.Background.LoadFromFile('./images/sos.jpg');
  // Numero de entradas / salidas
    self.Nin:=3;   self.NOut:=4;
  // Creamos las entradas / salidas graficas
  self.IOHeigth:=8;
  setlength(vIn,nIn);
  setlength(vOut,nOut);
    // Entradas
    inc:=trunc((self.height-NIn*IOHeigth)/(Nin+1)); // Espacio entre entradas
    for I := 0 to nIn - 1 do
    begin
      pt.X:=left; pt.y:= Top+(i+1)*inc+i*IOHeigth;
      bound:= Rect(pt, Point(pt.X+IOHeigth, pt.Y+IOHeigth));
      form2.simpleGraph1.SnapToGrid:=False;
      vIn[i]:=form2.simpleGraph1.InsertNode(bound,TGraphIn);
      form2.simpleGraph1.SnapToGrid:=True;
      TGraphIn(vIn[i]).init;
    end;
    // Entradas
    inc:=trunc((self.height-NOut*IOHeigth)/(NOut+1)); // Espacio entre entradas
    for I := 0 to nOut - 1 do
    begin
      pt.X:=left+width-IOHeigth; pt.y:= Top+(i+1)*inc+i*IOHeigth;
      bound:= Rect(pt, Point(pt.X+IOHeigth, pt.Y+IOHeigth));
      form2.simpleGraph1.SnapToGrid:=False;
      vOut[i]:=form2.simpleGraph1.InsertNode(bound,TGraphIn);
      form2.simpleGraph1.SnapToGrid:=True;
      TGraphIn(vOut[i]).init;
    end;

  self.InSelected:=-1;
  self.OutSelected:=-1;
end;

procedure TGraphIn.init;
begin
  NodeOptions:=[gnoShowBackGround];
end;

procedure TGraphOut.init;
begin
  NodeOptions:=[gnoShowBackGround];
end;

[Neftali [Germán.Estévez]]

Empezado por astwin

Mi solucion ha sido crear cada bloque como un rectangulo, y las entradas y salidas tambien como rectangulos mas pequeños. El problema ahora lo tngo a la hora de mover el bloque grande, que no se como hacer que se puedan mover a la vez los pequeños (ademas el bloque grande esta alineado a la cuadricula y los pequeños no). Haber si alguien puede echarme un cable.

Me parece una buena solución. Si fuera mi caso posiblemente hubiera optado por la misma, ya que los puntos de entrada debes comportarse como elementos individuales, aunque en que los contenga sea el bloque externo.

Para el tema de movimiento, lo que hago yo, es detectar el movimiento del bloque exterior y "mover al mismo tiempo los bloques interiores". En tu caso, tú sabes en qué posición está cada entrada/salida, por lo tanto cuando mueves el bloque exterior lo único que debes hacer el aplicar ese mismo desplazamiento a los bloques interiores.

[astwin]

el problema es que no comprendo muy bien desde que funcion puedo sobreescribir del bloque 'grande' para que las entradas y salidas sigan el movimiento. mousemove, begindrag,... vamos, que no me aclaro muy bien como hacerlo. Haber si puedes orientarme.

[Neftali [Germán.Estévez]]

Para que te hagas una idea de cómo lo hago yo...

Código Delphi [-]
procedure TLeyendaNode.DrawBody(Canvas: TCanvas);
var
  i:Integer;
  obj:TGraphNode;
  _MinWidth:Integer;
begin
  inherited;

  // controlar el estado
  if (Self.State = osDestroying) then begin
    Exit;
  end;

  //- Owner.BeginUpdate;
  // proteccion
  try

    // AutoDimensionar
    if (FAutoSizeHeight) then begin
      Self.Height := DEFAULT_HEIGHT_TITLE +
                  (FTextNodes.Count * DEFAULT_HEIGHT_ELEMENT) +
                  (DEFAULT_HEIGHT_ELEMENT DIV 2);
      // Objeto en sí
      Self.Width := Max(Self.Width, DEFAULT_HEIGHT_ELEMENT);
    end;

    _MinWidth := 0;


    // Recolocar
    for i := 0 to (FTextNodes.Count - 1) do begin
      // Cuadro de color
      obj := TGraphNode(FColorNodes.Objects[i]);
      obj.OwnerNode := Self;
      obj.Left := Self.Left + LEFT_SPACE;
      obj.Top := Self.Top + DEFAULT_HEIGHT_TITLE + (DEFAULT_HEIGHT_ELEMENT * i);
      obj.Width := DEFAULT_HEIGHT_ELEMENT;
      obj.Height := DEFAULT_HEIGHT_ELEMENT - 1;
      obj.Brush.Color := StrToInt(FColorNodes.Strings[i]);
      obj.Pen.Color := clGray;
      obj.CanSelect := False;

      // Texto
      obj := TGraphNode(FTextNodes.Objects[i]);
      obj.Left := Self.Left + LEFT_SPACE + DEFAULT_HEIGHT_ELEMENT + LEFT_SPACE;
      obj.Top := Self.Top + DEFAULT_HEIGHT_TITLE + (DEFAULT_HEIGHT_ELEMENT * i);
      obj.Width := Self.Width - LEFT_SPACE - DEFAULT_HEIGHT_ELEMENT - LEFT_SPACE -
                   (SOMBRA_WIDTH * 2);
      obj.Height := DEFAULT_HEIGHT_ELEMENT;
      obj.Alignment := taLeftJustify    ;
      obj.Text := FTextNodes.Strings[i];

      _MinWidth := Max(_MinWidth, Canvas.TextWidth(obj.Text) + (LEFT_SPACE * 2));

      obj.Pen.Style := psClear;
      obj.CanSelect := False;
    end;

    // No asignado?
    if not Assigned(FTitleNode) then begin
      // Crear el título
      FTitleNode := Owner.InsertNode(nil, TEtiquetaNode{TRectangularNode});
      FTitleNode.OwnerNode := Self;
      FTitleNode.Visible := Self.Visible;
      FTitleNode.Top := Top;
      FTitleNode.Left := Left;
      FTitleNode.Height := DEFAULT_HEIGHT_ELEMENT - (SOMBRA_WIDTH * 2);
      FTitleNode.Width := Width;
      FTitleNode.CanSelect := False;
      FTitleNode.BringToFront;

      FTitleNode.Selected := False;
      FTitleNode.CanSelect := False;
      FTitleNode.Font.Style := FTitleNode.Font.Style + [fsBold];
    end;

    // Titulo
    FTitleNode.Top := Top + 1;
    FTitleNode.Left := Left + (DEFAULT_HEIGHT_ELEMENT div 2);
    FTitleNode.Width := Width - SOMBRA_WIDTH - DEFAULT_HEIGHT_ELEMENT;
    FTitleNode.Text := FTitle;
    FTitleNode.Font.Color := clBlack;

    _MinWidth := Max(_MinWidth, Canvas.TextWidth(FTitleNode.Text) +
                 (DEFAULT_HEIGHT_ELEMENT * 2));


    // AutoDimensionar
    if (FAutoSizeWidth) then begin
      // Objeto en sí
      Self.Width := Max(_MinWidth, DEFAULT_HEIGHT_ELEMENT);
    end;

  finally
    //- Owner.EndUpdate;
  end;
end;

Es un objeto que correspomde a un cuadro de leyenda.



Como ves es un objeto al que se le pasan un número de elementos (Texto + Color); Al mover la leyenda se posicionan de nuevo los elementos interiores.

[astwin]

Muchisimas gracias neftali, gracias a tu ayuda ya lo he conseguido hacer. Te tas ganando unas cuantas cervecillas . Muchas gracias. Espero no ser muy pesao.

[astwin]

Hola,
gracias al componente TsimpleGraph tengo el trabajo muy adelantado. Ya consigo linkar bloques con lineas, que estas conexiones de forma gráfica se traduzcan en una serie de estructuras y clases con las que realizar diversas tareas, etc.. Muchas gracias Neftali por sugerirmelo. Ahora estoy liado con el tema de copiar/cortar/pegar.

No me aclaro muy bien con el funcionamiento de esta funcionalidad en simplegraph.

Como ya postee anteriormente, para realizar el bloque cree una clase que hereda de Trectangularnode. Las entradas y salidas las cree mediante otra clase que hereda de Trectangularnode y se encuentran en una lista definida dentro de la clase de bloque. Decir además, que le he añadido en la variable 'data' referencias hacia otras clases, que no tienen nada que ver con la parte grafica.

Ahora para copiar y pegar un bloque no tengo ni idea de como proceder.

Código Delphi [-]
procedure TMainForm.EditCopyUpdate(Sender: TObject);
begin
  EditCopy.Enabled :=(SimpleGraph.SelectedObjects.Count > 0);
end;

procedure TMainForm.EditCopyExecute(Sender: TObject);
begin
  SimpleGraph.CopyToClipboard(True);
end;

procedure TMainForm.EditPasteUpdate(Sender: TObject);
begin
  EditPaste.Enabled := not IsReadonly and Clipboard.HasFormat(CF_SIMPLEGRAPH);
end;

procedure TMainForm.EditPasteExecute(Sender: TObject);
begin
  SimpleGraph.PasteFromClipboard;
end;

Este es el codigo de copiar y pegar que he observado en la demo del simpleGraph. Pero cuando selecciono un bloque grafico, lo copio y lo pego, al pegarlo me da error. Alguien puede orientarme un poco, si debo sobreescribir alguna funcion en mi clase de bloque para que se copie bien al portatapeles o que debo hacer o mirar.

Un saludo.

[Neftali [Germán.Estévez]]

Empezado por astwin

Este es el codigo de copiar y pegar que he observado en la demo del simpleGraph. Pero cuando selecciono un bloque grafico, lo copio y lo pego, al pegarlo me da error. Alguien puede orientarme un poco, si debo sobreescribir alguna funcion en mi clase de bloque para que se copie bien al portatapeles o que debo hacer o mirar.

Supongo que SimpleGraph implementa esos métodos, así como un formato nuevo del Clipboard. Al hacer el pegar debe crear los nuevos objetos.
¿Sabes en qué punto está fallando?
¿Lo has "debuggado" paso a paso?

La verdad es que esta funcionalidad no la he utilizado nunca.