El operador as

[[David]]

Hola

El operador as lo hago para hacer un cast objecto as clase

por ejemplo

Código SQL [-]

var
 F : TForm;
begin
   F := FProveedores; // FProveedores es un TForm de otra unidad
   // para llamar a una función del formulario de proveedores
   (F as TFProveedores).MiProcedure;
end;

vale, esto parece claro, pero lo que quiero saber es muy sencillo. Es lo mismo poner (F as TFProveedores).MiProcedure que poner TFProveedores(F).MiProcedure.

Es sólo eso, saber si los dos tipos de cast son equivalentes en todos los casos y sólo son dos formas de escribir lo mismo.

Un saludo

[[seoane]]

Cuando hace un typecast tienes que estar seguro de que los dos tipos son compatibles, en en caso del operado "as" es el mismo el que se encarga de hacer esa comprobación.

Es decir:

Código Delphi [-]
(F as TFProveedores).MiProcedure;

Equivale a esto:

Código Delphi [-]
if F is TFProveedores then
  TFProveedore(F).MiProcedure
else
  // Si no lo es se genera una excepcion

Como ves hacen lo mismo, pero "as" primero hace una comprobación.

[dec]

Hola,

Y yo que pensaba que tenía que ver con el tipo de error, o sea, excepción, que era generada en un caso uno de los "sistemas" y no por el otro... No voy a ponerme a rebatir al maestro Seoane, pero, ¿de qué sirve esta "condición"? Lo pregunto sin ánimo de molestar, sino, sinceramente, a ver si alguien puede sacarme del "dilema".

Código Delphi [-]
(Objecto as TEsteObjeto).Propiedad = 'Cadena';
// Sigue el resto del código aquí

¿De qué sirve la condición, si, pase lo que pase, se avanzará hasta la línea siguiente? ¿Acaso debería atraparse la posible excepción? ¿No sería mejor usar el operador "is"? ¿Me estaré volviendo loco?

Actualización: Acabo de comprobar que, usando el operador "as", se obtiene una excepción "EInvalidCast", mientras que, usando "el tipo" directamente, se obtiene una violación de acceso.

[[seoane]]

Empezado por dec

¿De qué sirve la condición, si, pase lo que pase, se avanzará hasta la línea siguiente?

¿Estas seguro de que se sigue en la linea siguiente?

Me explico, si tenemos esto:

Código Delphi [-]
(Objecto as TEsteObjeto).Propiedad = 'Cadena';

y "Objeto" no es de la clase TEsteObjeto (o una descendiente), se genera una excepción y la siguiente linea de código a esta no se ejecuta (como ocurre con todas las excepciones). ¿no es así?

[dec]

Hola,

Pues sí... así es... pero, yo no llamaría a eso una "condición", entendiendo como condición algo como esto:

Código Delphi [-]
if Condicion then
begin
  // La condición se cumple
end
else
begin
  // La condición no se cumple
end;

No sé. Es que, tal como yo entendí lo que dijiste (mejor dicho, acaso podría entenderse, por lo que dijiste) que el mismo "as" hará que el "asunto" se ejecute si se cumple la "condición", pero, es que no parece que sea así: se levanta una excepción, la condición "no la evita". Pero, puede que esté desbarrando, ¿eh?

Si lo pienso un poco más, puede que lleves toda (no parte de) la razón, porque la "condición" impide que se siga adelante, y, por tanto, se obtenga una violación de acceso, como ocurre en el otro caso, mas, ¿no es ya la "EAccessViolation" un tipo de excepción? Lo dicho, algo se me escapa en este asunto. Acaso es mejor una que otra excepción... lo ignoro ahora mismo. Una cosa está clara: son distintas excepciones.

[jachguate]

Empezado por dec

como ocurre en el otro caso, mas, ¿no es ya la "EAccessViolation" un tipo de excepción? Lo dicho, algo se me escapa en este asunto. Acaso es mejor una que otra excepción... lo ignoro ahora mismo. Una cosa está clara: son distintas excepciones.

Aplicando directamente el molde, no siempre obtendrás un EAccessViolation. Podrías simplemente sobreescribir la memoria, y luego el programa tronaría sin saber por que.

No tengo delphi a mano, pero se me ocurre que podes comprobarlo de manera sencilla (por favor, corregí vos por mi los errores de sintaxis que pudiera haber:

Código Delphi [-]
type
  TClase1 = class
  private
    FNumero: Integer;
  public
    property Numero: Integer read FNumero write FNumero;
  end;

  TClase2 = class
  private
    FLineas: TStringList;
    procedure SetLineas(const Value: TStringList);
  public
    constructor Create;
    property Lineas: TStringList read FLineas write SetLineas;
  end;

implementation
  
constructor TClase2.Create;
begin
  FLineas := TStringList.Create;
end;

procedure TClase2.SetLineas(const Value: TStringList);
begin
  if Assigned(Value) then
    FLineas.Assign(Value)
  else
    FLineas.Clear;
end;

Código Delphi [-]
procedure TForm1.MezclarTodo;
var
  Instancia1: TClase1;
  Instancia2: TClase2;
begin
  Instancia1 := TClase1.Create;
  Instancia2 := TClase2.Create;
  Instancia1.Numero := 1500;
  Instancia2.Lineas.Add('Prueba');
  //Hasta aquí todo bien.
  //La línea siguiente, debiera ejecutarse sin problemas 
  TClase1(Instancia2).Numero := 50;
  //La excepción, como ves, se dará en la siguiente línea
  Instancia2.Lineas.Add('Esto truena!');
end;

Espero que funcione como yo lo espero , si no, ya veremos cuando tenga un delphi a mano.

Hasta luego.

[dec]

Hola,

Creo que funciona tal como esperas Juan Antonio. Sin embargo, sigue sin quedarme claro todo este asunto. No creo que "la gracia" esté en que algo así no compile, directamente:

Código Delphi [-]
(Instancia2 as TClase1).Numero := 50;

En esto me debe pasar como en tantas cosas, que, como no las conozco, ignoro su posible utilidad...

[jachguate]

Algo así compilaría... la ventaja es que estas seguro de obtener una excepción en caso de no corresponder la clase.

Por ejemplo:

Código Delphi [-]
begin
  try
    (Sender as TButton).Caption := 'Pulsado';
  except
    on EInvalidTypecast
      Label1.Caption := 'Lo siento, en este momento solo puede pulsar botones';
  end;

Hasta luego.

[dec]

Hola,

Eso digo. Pero por el tema de tener una excepción más oportuna, es decir, que esto otro:

Código Delphi [-]
begin
  try
    TButton(Sender).Caption := 'Pulsado';
  except
    on EAccessViolation do
      Label1.Caption := 'Lo siento, en este momento solo puede pulsar botones';
  end;

Podría ser problemático, porque el "EAccessViolation" podría venir de otro lado, no del "cast" en cuestión. ¿No?

Aún así me sigue sin entrar lo de la "condición" de que hablaba Seoane. ¿Dónde está la condición? En ambos casos se produce una excepción, salvo que son distintas excepciones. ¿No? Pero, si uno quiere una condición tiene que recurrir al operador "is", ¿o me equivoco?

[adfa]

Empezado por seoane

Cuando hace un typecast tienes que estar seguro de que los dos tipos son compatibles, en en caso del operado "as" es el mismo el que se encarga de hacer esa comprobación.

Es decir:

Código Delphi [-]
(F as TFProveedores).MiProcedure;

Equivale a esto:

Código Delphi [-]
if F is TFProveedores then
  TFProveedore(F).MiProcedure
else
  // Si no lo es se genera una excepcion

Como ves hacen lo mismo, pero "as" primero hace una comprobación.

Por lo que yo se (y es poquito) me parece que no es asi.
El (objeto as TClaseCualquiera).procedimiento es lo mismo que hacer TClaseCualquiera(objeto).procedimiento.

El as no control que el objeto que se le pase sea de la clase adecuada, antes hay que preguntar con el "is".
El código del botón1 da error en ejecución, el 2 no.

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  type animal =class
  end;
  type perro=class(animal)
      procedure ladrar();
  end;
  type gato=class(animal)
  end;
var
  Form1: TForm1;

implementation

{$R *.dfm}


procedure perro.ladrar;
begin
  showmessage('guau');
end;
procedure TForm1.Button1Click(Sender: TObject);
var
  bicho : animal;
begin
  bicho := gato.Create;
   (bicho as perro).ladrar;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  bicho : animal;
begin
  bicho := gato.Create;
   if bicho is perro then (bicho as perro).ladrar;
end;

end.

Saludos

[jachguate]

Empezado por dec

Hola,

Eso digo. Pero por el tema de tener una excepción más oportuna, es decir, que esto otro:

Código Delphi [-]
begin
  try
    TButton(Sender).Caption := 'Pulsado';
  except
    on EAccessViolation do
      Label1.Caption := 'Lo siento, en este momento solo puede pulsar botones';
  end;

Podría ser problemático, porque el "EAccessViolation" podría venir de otro lado, no del "cast" en cuestión. ¿No?

No solo eso, dec. Es probable que no haya EAccessViolation, como ya he demostrado en el ejemplo anterior (que vos has dicho que funcionaba como yo quería.

Empezado por dec

Aún así me sigue sin entrar lo de la "condición" de que hablaba Seoane. ¿Dónde está la condición?

Quizás he leido el hilo demasiado rápido... pero no veo a seoane mencionando ninguna condición... ¿donde lo ha hecho?

Hasta luego.

[dec]

Hola,

Empezado por Jachguate

No solo eso, dec. Es probable que no haya EAccessViolation, como ya he demostrado en el ejemplo anterior (que vos has dicho que funcionaba como yo quería.

No, no... en el ejemplo se produce una excepción "EAccessViolation".

Empezado por Jachguate

Quizás he leido el hilo demasiado rápido... pero no veo a seoane mencionando ninguna condición... ¿donde lo ha hecho?

Bueno. Aquí está el primer mensaje de Seoane en este hilo. Mi intervención se debió por ese mensaje. Pero, todo venía porque ya alguna vez en estos foros se trató de este tema de la diferencia entre el "as" o el "cast directo" y, si no recuerdo mal, se llegó a la conclusión (si es que se llegó a alguna conclusión) de que la diferencia radicaba en los distintos errores que se generarían, las diferentes excepciones.

[jachguate]

Empezado por dec

No, no... en el ejemplo se produce una excepción "EAccessViolation".

La idea es hacer que se produzca un EAccessViolation, pero no en la línea donde se hace el cast, sino en la siguiente. ¿Podes comprobarlo?

Si se quitase esa línea, no habría EAccessViolation, al menos no en ese punto, sino en cualquier otro que tratase de usar la propiedad Lineas del componente creado.... como dije, es algo que he hecho rápidamente y sin delphi, pero la idea es esa.

Empezado por dec

se llegó a la conclusión de que la diferencia radicaba en los distintos errores que se generarían, las diferentes excepciones.

Definitivamente esa es una conclusión errada. El cast directo no necesariamente producirá una excepción, y si se produce, no necesariamente será un EAccessViolation, aunque es la mas probable. Si el ejemplo hecho no funciona aún, veré de arreglarlo para que se demuestre.

Hasta luego.

[dec]

Hola,

Sí; el ejemplo que preparaste funciona tal como esperas. Es decir, que la violación de acceso no se produce en el "cast", sino el la siguiente instrucción, que, de no existir, evitaría dicha violación de acceso, por el momento...

Yo también estoy de acuerdo en que la conclusión de que el asunto estribaba en la diferencia de excepciones no era del todo correcto, o no se elaboró en su momento de la misma forma que se ha hecho en este hilo, gracias, en buena medida, a tu ejemplo.

[jachguate]

Empezado por dec

gracias, en buena medida, a tu ejemplo.

Me alegra que te sea de utilidad... y mas me alegra que cumpliese su cometido sin haberlo podido probar yo antes... veo que mi comprobador interno de sintaxis va mejorando...

hasta luego.

[[Al González]]

¡Hola a todos!

Vaya lío con esto del operador As. Primero que nada, va mi sugerencia de utilizar el término molde de tipo para referirse a "type cast".

Como ya lo aclaró Antonio, el molde de tipo con el operador As, presenta dos verificaciones de seguridad; una de compilación y otra en tiempo de ejecución. Al compilar se verifica que el tipo de dato usado y el tipo de dato declarado del objeto sean clases con relación jerárquica lineal (padre-hijo, abuelo-nieto, misma clase, etc., pero no tío-sobrino, primo-primo, etc.). En tiempo de ejecución, se realiza una verificación de polimorfismo: que el objeto sea de la clase indicada, de una clase derivada de ella o un puntero nulo (Nil).

Mientras que un molde de tipo clásico (yo los conocía desde Turbo Pascal), al estilo "Clase (Objeto)", no impide que el programa compile y se ejecute la sentencia donde aparezca tal expresión. Pero eso sí, el resultado puede ser impredecible si no estamos completamente seguros de lo que estamos moldeando.

Me permito añadir aquí una humilde traducción al español de lo que dice la ayuda de Delphi sobre el operador As:

El operador as efectúa moldes de tipo verificados. La expresión

Objeto as Clase

devuelve una referencia al mismo objeto que Objeto, pero con el tipo dado por Clase. En tiempo de ejecución, Objeto debe ser una instancia de la clase denotada por Clase o de una de sus descendientes, o bien Nil; de otra forma se eleva una excepción. Si el tipo declarado de Objeto no está relacionado a Clase —es decir, si los tipos son distintos y uno no es ancestro del otro—, ocurre un error de compilación.

(Saludo as TAbrazo).Ejecutar;

Al González.

[Casimiro Notevi]

Empezado por Al González

¡Hola a todos!

Vaya lío con esto del operador As. Primero que nada, va mi sugerencia de utilizar el término molde de tipo para referirse a "type cast".

Como ya lo aclaró Antonio, el molde de tipo con el operador As, presenta dos verificaciones de seguridad; una de compilación y otra en tiempo de ejecución. Al compilar se verifica que el tipo de dato usado y el tipo de dato declarado del objeto sean clases con relación jerárquica lineal (padre-hijo, abuelo-nieto, misma clase, etc., pero no tío-sobrino, primo-primo, etc.). En tiempo de ejecución, se realiza una verificación de polimorfismo: que el objeto sea de la clase indicada, de una clase derivada de ella o un puntero nulo (Nil).

Mientras que un molde de tipo clásico (yo los conocía desde Turbo Pascal), al estilo "Clase (Objeto)", no impide que el programa compile y se ejecute la sentencia donde aparezca tal expresión. Pero eso sí, el resultado puede ser impredecible si no estamos completamente seguros de lo que estamos moldeando.

Me permito añadir aquí una humilde traducción al español de lo que dice la ayuda de Delphi sobre el operador As:
(Saludo as TAbrazo).Ejecutar;
Al González.

Totalmente claro, yo creo que es difícil explicarlo mejor

[adfa]

Empezado por Al González

¡Hola a todos!

Vaya lío con esto del operador As. Primero que nada, va mi sugerencia de utilizar el término molde de tipo para referirse a "type cast".

Como ya lo aclaró Antonio, el molde de tipo con el operador As, presenta dos verificaciones de seguridad; una de compilación y otra en tiempo de ejecución. Al compilar se verifica que el tipo de dato usado y el tipo de dato declarado del objeto sean clases con relación jerárquica lineal (padre-hijo, abuelo-nieto, misma clase, etc., pero no tío-sobrino, primo-primo, etc.). En tiempo de ejecución, se realiza una verificación de polimorfismo: que el objeto sea de la clase indicada, de una clase derivada de ella o un puntero nulo (Nil).

Mientras que un molde de tipo clásico (yo los conocía desde Turbo Pascal), al estilo "Clase (Objeto)", no impide que el programa compile y se ejecute la sentencia donde aparezca tal expresión. Pero eso sí, el resultado puede ser impredecible si no estamos completamente seguros de lo que estamos moldeando.

Me permito añadir aquí una humilde traducción al español de lo que dice la ayuda de Delphi sobre el operador As:



(Saludo as TAbrazo).Ejecutar;

Al González.

Ta decía yo que sabia poquito del tema. Brillante lo tuyo.
Saludos