Comprimir un archivo( que quede .zip), desde Builder sin mostrar Winzip

[dec]

Hola,

Empezado por Grefu

Código Delphi [-]
 abZipper1.filename:='C:\\yo.zip';  <---- aki me peta

Piensa que en este Hilo se está hablando de los componentes que te interesan, pero bajo C++ Builder, empero, parece que tú estás queriéndolos utilizar bajo Delphi: la instrucción anterior te falla (aunque no lo he comprobado), probablemente, por la doble barra invertida que separa la unidad del nombre del archivo "Zip". En C++ Builder esto tiene que ser así, en Delphi basta con una sola barra invertida, en todo caso bajo el sistema operativo Windows: con los distintos sabores de Unix sería al contrario: la barra sería una "normal", tal que esta "/".

Si me permites un consejo (ya estamos, dando consejos, precisamente, los que no hacemos casos de ellos), por decirlo de alguna manera, cuando algo "te falle" indica en qué, concretamente. Por ejemplo, si te aparece una excepción, o cualquier otro error, indica el tipo de esta y el mensaje de este, todo para que resulte en lo posible más sencillo echarte una mano, evidentemente. ¿Sigues precisando del ejemplo? Mira que hay quien está dispuesto a llevarlo a cabo, pues que con estos componentes comprimir y descomprimir archivos (fuera de que ofrecen más que eso, simplemente) no es complicado y no costaría mucho llevarlo a cabo, así, a bote pronto.

[dec]

Hola,

Al cabo me he decidido con un ejemplo que consigue más o menos lo que precisas, recuerda que los componentes utilizados son bastante más potentes que lo que se muestra aquí, quiere decirse que pueden dar mucho más de sí.

Código Delphi [-]
 uses
   // Delphi 7
   Dialogs, ExtDlgs, SysUtils,
 
   // Turbo Power Abbrevia 3.05
   AbZipKit, AbArcTyp, AbZipTyp;
 
 // TODO : Renombrar este procedimiento 
 //
 procedure ComprimirImagenesDentroArchivoZip;
 resourcestring
   rsExtensioZip = 'zip';
   rsFiltrDlgZip = 'Archivos Zip (*.zip)|*.zip';
   rsTitleDlgZip = '¿Dónde quieres guardar el archivo Zip?';
   rsTitleDlgImg = 'Elige las imágenes que quieres comprimir';
 var
   i: integer;
   zip: TAbZipKit;
   dlgZip: TSaveDialog;
   dlgImg: TOpenPictureDialog;
 begin
   zip := TAbZipKit.Create(nil);
   dlgZip := TSaveDialog.Create(nil);
   dlgImg := TOpenPictureDialog.Create(nil);
   try
     dlgZip.Title := rsTitleDlgZip;
     dlgImg.Title := rsTitleDlgImg;
     dlgZip.Filter := rsFiltrDlgZip;
     dlgZip.DefaultExt := rsExtensioZip;
     dlgZip.Options := dlgZip.Options + [ofOverwritePrompt];
     dlgImg.Options := dlgImg.Options + [ofAllowMultiSelect];
     if dlgImg.Execute then
     begin
       if dlgZip.Execute then
       begin
         zip.DeflationOption := doMaximum;
         zip.OpenArchive(dlgZip.FileName);
         zip.FileName := dlgZip.FileName;
         zip.StoreOptions := [soStripDrive, soStripPath, soFreshen];
         for i := 0 to dlgImg.Files.Count-1 do
         begin
           zip.AddFiles(dlgImg.Files[i], faAnyFile);
         end;
         zip.Save;
         zip.CloseArchive;
       end;
     end;
   finally
     zip.Free;
     dlgZip.Free;
     dlgImg.Free;
   end;
 end;
 
 // Ejemplo de llamada al procedimiento
 //
 procedure TfrmPrincipal.Button1Click(Sender: TObject);
 begin
   ComprimirImagenesDentroArchivoZip;
 end;

[meosre]

Yo utilizo estos componentes y me funcionan perfectamente, yo genero un zip al cual le cambio el tipo de extension para que se genere un archivo que solo abre mi aplicacion, resulta que ahora necesito ademas de comprimir unos archivos, comprimir una carpeta que necesito y que por dentro contiene mas carpetas cada una con informacion interna, me pueden ayudar para saber como hago esto, ya que yo lo que hago es agregar archivos con la funcion que trae el componente y no se como comprimir todo un directorio.

Gracias

[dec]

Hola,

Lo siguiente es Delphi, pero, creo que se entenderá bien:

Código Delphi [-]
 uses
   AbArcTyp, AbZipKit;
 
 procedure TForm1.Button1Click(Sender: TObject);
 var
   AbZipKit: TAbZipKit;
 begin
   AbZipKit := TAbZipKit.Create(Self);
   try
     AbZipKit.FileName := 'C:\Archivo.zip';
     AbZipKit.StoreOptions := [soRecurse];
     AbZipKit.AddFiles('C:\Archivos de programa\Inno Setup 5\*.*', faAnyFile);
     AbZipKit.CloseArchive;
     AbZipKit.Save;
   finally
     AbZipKit.Free;
   end;
 end;