Fibplus y Delphi 10.2

[MicrodeltaAmpos]

Hola a todos

Tengo escrita una aplicación desarrollada con Delphi 2006 que accede a una base de datos Firebird 2.1.5 utilizando los componentes Fibplus 6.4.1.
Hace varios años que esta aplicación está cumpliendo estupendamente con su cometido.

Ahora bien, me han pedido compilar esta aplicación con Delphi 10.2.3 Community Edition y los componentes Fibplus 7.632.3171 Release descargados
de internet. Al ejecutar la aplicación y dar de alta o modificar registros de la BD aparece incansablemente el mensaje de error 'Access violation...'.
Ejecutando la aplicación en modo de depuración me doy cuenta que estos errores tienen su origen en el código fuente de los componentes Fibplus.

Alguien puede decirme si la versión Fibplus 7.632.3171 es compatible con Delphi 10.2.3 ? O dicho de otra forma, existe alguna versión Fibplus
compatible con Delphi 10.2.3, o hay que olvidarse de Fibplus y utilizar FireDAC ?

Gracias.

[Casimiro Notevi]

Mira los enlaces de abajo del todo, a ver si te sirven.

[MicrodeltaAmpos]

He seguido los enlaces que me has pasado...hasta llegar a la web https://github.com/madorin/fibplus.
Ese grupo de voluntarios que se ha propuesto mantener vivos a los Fibplus está realizando una gran labor sobretodo por la gran dificultad que representa tener que adaptar código fuente escrito por otros.
Por lo que entiendo estas versiones de Fibplus no son del todo seguras ya que siguen apareciendo mensajes de error en las aplicaciones que las usan. El compañero que me pasó la versión Fibplus que tengo instalada con Delphi 10.2 me comenta que los bajo de esta web con el distintivo D25.
Por ahora no veo seguro migrar a esta versión de FibPlus la aplicación que te comenté.

Seguiré buscando información...
Gracias por los enlaces.

[manelb]

Saludos a todos…
Primero que nada, comentar que no soy un experto programador, ni mi ocupación directa sea esta, pero voy a intentar aportar mi granito de arena para ayudar a solucionar este problema.
Por lo tanto, ruego comprensión si la terminología empleada no es la más adecuada y sobre todo por la falta de rigurosidad técnica en mi exposición.

También es cierto que me ha sorprendido la poca participación en este hilo, bien porque realmente seamos pocos los usuarios de FIBs, o pocos de nosotros lo estemos intentando con las nuevas versiones de Delphi.

En referencia al problema, parece ser que realmente son dos, pero que se producen o están relacionados directamente con el evento onvalidate de TField.
Incluso el origen del problema podría ser el mismo, aunque no hemos podido llegar a esta conclusión.

Me han iluminado, entre otros, unos hilos del foro de Al González hablando sobre SetData, Validate, GetData y sobre los tipos de parámetros de algunos procedimientos que han cambiado de Pointer a TValueBuffer en las últimas versiones de Delphi.
También largas explicaciones de Casimiro sobre Unicode, que sigue costándome entender.

Como creo que me voy a extender un poco, mejor pongo cada uno de los dos problemas en mensajes separados.

[manelb]

El primero de ellos es un error que está registrado en la propia página de descarga de los componentes en github y que adjunta un pequeño ejemplo con base de datos incluida
https://github.com/madorin/fibplus/issues/30

El error consiste en un extraño y aleatorio “Access Violation”.
Se produce, bien al validar el campo, bien al hacer post del registro o bien al salir de la ventana.

Parece ser, por las pruebas que hemos realizado, que sucede cuando en el evento
onvalidate se utiliza el acceso al valor del campo validado usando la sentencia Sender.AsString.

En las pruebas realizadas hemos apreciado que si utilizamos Sender. AsAnsiString en lugar de Sender.AsString ya no se produce el error y de momento este apartado lo damos por solucionado.
Quiero creer que no vamos a tener ningún problema con Unicode siempre que no utilicemos otros idiomas.
Los expertos en Unicode me podríais confirmar este punto??

[manelb]

El segundo problema es que en el mismo evento onvalidate, los campos de tipo integer i smallint siempre devuelven 0 cuando se accede a su valor para proceder a su validación.
El siguiente evento

Código Delphi [-]
procedure TForm1.Validate(Sender: TField);
begin
  ListBoxSalida.Items.Add('Validate: '+sender.FieldName+': '+sender.AsString);
end;

conectado a campos de diferentes tipos e introduciendo siempre el valor ‘100’, devolvería el siguiente resultado:

Validate: SMALLINT: 0
Validate: INTEGER: 0
Validate: BIGINTEGER: 100
Validate: FLOAT: 100
Validate: NUMERIC: 100
Validate: CHAR_5: 100
Validate: VARCHAR_10: 100

Sobra decir que si utilizamos Firedac el resultado es el correcto, por lo que para investigar hemos tratado de comparar el comportamiento de los dos sistemas.

Parece ser que el problema se origina en el siguiente procedimiento de la unidad Data.DB debido a que la variable FValidating siempre es False cuando procede de FibPlus

Código Delphi [-]
function TIntegerField.GetValue(var Value: Longint): Boolean;
Begin
  if (FIOBuffer <> nil) and not FValidating then
    TDBBitConverter.UnsafeFrom(0, FIOBuffer);
  Result := GetData(FIOBuffer);
  if Result then
    case DataType of
      ftShortint:
        Value := TDBBitConverter.UnsafeInto(FIOBuffer);
      ftByte:
        Value := TDBBitConverter.UnsafeInto(FIOBuffer);
      ftSmallint:
        Value := TDBBitConverter.UnsafeInto(FIOBuffer);
      ftWord:
        Value := TDBBitConverter.UnsafeInto(FIOBuffer);
      ftLongWord:
        Value := TDBBitConverter.UnsafeInto(FIOBuffer);
      Else
        Value := TDBBitConverter.UnsafeInto(FIOBuffer);
      end;
end;

Investigando a quien corresponde la responsabilidad de mantener el valor de la variable FValidating nos encontramos con que en Firedac, se ejecuta el siguiente código(uno u otro en función del parámetro Buffer)

Código Delphi [-]
procedure TField.Validate(Buffer: TValueBuffer);
var
  prevBuffer: TValueBuffer;
begin
  if Assigned(OnValidate) then
  begin
    { Use the already assigned FValueBuffer if set }
    if FValueBuffer = nil then
      FValueBuffer := Buffer;
    FValueBuffer := Copy(FValueBuffer);
    prevBuffer := Copy(Buffer);
    FValidating := True;
    try
      OnValidate(Self);
    finally
      FValidating := False;
      Move(prevBuffer[0], Buffer[0], Length(Buffer));
    end;
  end;
end;

{$IFNDEF NEXTGEN}
procedure TField.Validate(Buffer: Pointer);
begin
  if Assigned(OnValidate) then
  begin
    { Use the already assigned FValueBufferPtr if set }
    if FValueBufferPtr = nil then
      FValueBufferPtr := Buffer;
    FValidating := True;
    try
      OnValidate(Self);
    finally
      FValidating := False;
    end;
  end;
end;
{$ENDIF !NEXTGEN}

Mientras que en los Fibs el trabajo equivalente lo realiza el siguiente procedimiento de la unidad FIBDataset, que no tiene en cuenta la variable FValidating, ya que utiliza un sistema diferente para controlar el estado de validación del campo

Código Delphi [-]
procedure TFIBCustomDataSet.DoFieldValidate(Field:TField;Buffer:Pointer);
begin
  if Assigned(Field.OnValidate) then
  begin
   Include(FRunState,drsInFieldValidate);
   Try
    FValidatingFieldBuffer:=Buffer;
    FValidatedField:=Field;
    FValidatedRec:= ActiveRecord;
    Field.OnValidate(Field);
   Finally
     Exclude(FRunState,drsInFieldValidate);
     FValidatingFieldBuffer:=nil;
   end;
  end;
end;

Llegados a este punto desearía conocer algunas opiniones y si os parece acertado o no el razonamiento que hemos hecho.

Soluciones???

Nosotros proponemos una pequeña modificación en TFIBCustomDataSet.DoFieldValidate de los fibs, introduciendo 3 linieas de código en el inicio del evento para que quede tal que así:

Código Delphi [-]
procedure TFIBCustomDataSet.DoFieldValidate(Field:TField;Buffer:Pointer);
begin
  if field is TIntegerField then  //lineas añadidas
    Field.Validate(Buffer)          // para solucionar problema onvalidate
  else                                             //en campos de tipo integer y smallint

  if Assigned(Field.OnValidate) then
  begin
   Include(FRunState,drsInFieldValidate);
   Try
    FValidatingFieldBuffer:=Buffer;
    FValidatedField:=Field;
    FValidatedRec:= ActiveRecord;
    Field.OnValidate(Field);
   Finally
     Exclude(FRunState,drsInFieldValidate);
     FValidatingFieldBuffer:=nil;
   end;
  end;
end;

De esta forma, el tratamiento de los campos integer lo delegamos al mismo procedimiento que usan los Firedac, y el resto de tipos de campos que no presentan error se siguen tratando igual que hasta ahora.
Que os parece??

Gracias por aguantar el rollo ….
Saludos a todos

[Zento]

Empezado por manelb

El error consiste en un extraño y aleatorio “Access Violation”.
Se produce, bien al validar el campo, bien al hacer post del registro o bien al salir de la ventana.

He actualizado de XE2 a 10.3 y estoy empezando a tener problemas con FIBPlus. Salta un access violation cada vez en un punto distinto del código fuente al trabajar con strings, pero tanto con AsString como con AsAnsiString así que por aquí voy más perdido. ¿Seguís trabajando con estos componentes? ¿Con la versión que hay en GitHub?