Existe la funcion EVAL en Delphi

darkone2k3 · #1 31-10-2003

Salu2 amigos foristas, esto sería de mucha ayuda.

Hay alguna funcion o procedimiento en dephi para poder evaluar expresiones desde cadenas de caracteres ingresadas por el usuario.
algo asi como la funcion EVAL de Javascript

Gracias y salu2 desde Chile.

roman · #2 31-10-2003

Cita:

darkone2k3 comentó:
Hay alguna funcion o procedimiento en dephi para poder evaluar expresiones desde cadenas de caracteres ingresadas por el usuario.

No. Porque Delphi es un lenguaje compilado y no interpretado como JavaScript.

Pero si nos quieres comentar el uso que quisieras darle a tal función quizá podamos ayudarte a lograr el objetivo utilizando otras técnicas.

// Saludos

darkone2k3 · #3 01-11-2003

Gracias por responder roman.

Mira, lo que pasa que tengo el siguiente codigo en jscrip:

Código:

function ratio(x_old,str1,str2){
  var xvalue=x_old
  var f=""
  var fdash=""
          for (var i=0;i<str1.length;i++)
       {
         var temp =str1.substring(i,i+1);
         if (temp=='z' || temp=='Z')temp=xvalue
         f+=temp}
  
     for (var i=0;i<str2.length;i++)
        {
         var temp =str2.substring(i,i+1);
         if (temp=='z' || temp=='Z')temp=xvalue
         fdash+=temp}
    
   var term = eval(f)/eval(fdash); 
   return term 
  }

Como te darás cuenta, en la linea que he resaltado de color azul, va la funcion eval, que es la que quiero pasar a Delpih 6.

Espero que te quede un poco más claro para que me puedas ayudar.
De ante manos, muchas gracias y salu2 desde Chile.

roman · #4 01-11-2003

Me cuesta trabajo entender el código ya que no sé en qué consisten los parámetros.

¿Podrías explicarme cual es el objetivo de la función y algún ejemplo?

// Saludos

darkone2k3 · #5 01-11-2003

Hola roman, lo que pasa es que ese codigo es parte de un programa que calcula raices a traves del metodo de Newton Raphson, y éste está hecho en jscript.

Te pongo el enlace de la página donde está el código:
http://www.fim.utp.ac.pa/Laboratorio...um/newton.html

Si no es mucha la molestia, para que la revises.

En todo caso, conoces alguna página donde pueda descargar o encontrar alguna codificacion para poder realizar el método de Newton Raphon, en delphi.

Gracias y salu2 desde Chile.

roman · #6 01-11-2003

En resumen, se trata de un método (parte de) para hallar las raíces de una función.

Aquí el problema consta de dos partes:

Evaluación de una expresión matemática
Implementación del algoritmo

El algoritmo en sí es independiente de la evaluación, se trata sólo de un algoritmo matemático de manera que su implementación en Delphi o cualquier otro lenguaje sólo requeriría de un buen entendimiento del algoritmo.

La parte de evaluación es necesaria para que el usuario de la aplicación pueda escribir la función que desee. Pero entonces el programa debe poder analizar la expresión (dada como una cadena de caracteres) para poder evaluarla. Por ejemplo, si la expresión es

Z^2

el programa debe de alguna forma descomponer la expresión en tokens:

z - variable
^ - operador
2 - constante

sustituir cada aparición de la variable por el valor numérico proporcionado y aplicar el operador:

Código:

if Operador = '^' then
  Resultado := Power(Valor, Potencia)
else if Operador = ...
...

Este no es un problema tan sencillo y ciertamente se facilita en los lenguajes interpretados. Sin embargo sí puede hacerse y en la web encontrarás seguramente varios evaluadores de expresiones.

Yo realmente desconozco el tema pero quizá te sirva algo de esta página:

http://www.efg2.com/Lab/Library/Delp...ns/Parsers.htm

// Saludos

darkone2k3 · #7 01-11-2003

Gracias roman por responder, voy a investigar lo que me dices.
Salu2 desde Chile.

rarratia · #8 27-09-2013

Cita:

Empezado por darkone2k3

Gracias roman por responder, voy a investigar lo que me dices.
Salu2 desde Chile.

Estimado, la función Eval para delphi es fácil, aquí va:

Código Delphi [-]function Eval(const expression : string) : extended;
var
  pos : Integer;
  ch : char;
  function GetChar : char;
  begin
    if pos < Length (expression) then
    begin
      Inc (pos);
      ch := expression [pos]
    end
    else ch := #0;
    result := ch
  end;
  function GetNonWhitespace : char;
  begin
    repeat
      GetChar
    until not (ch in [' ', #9]);
    result := ch
  end;
  function CalcAddition : extended; forward;
  function CalcNumber : extended;
  var
    s : string;
    gotPoint : boolean;
  begin
    gotPoint := False;
    while ch in ['0'..'9'] do
    begin
      s := s + ch;
      if (GetChar = '.') and not gotPoint then
      begin
        s := s + ch;
        GetChar;
        gotPoint := True
      end
    end;
    result := StrToFloat (s)
  end;
  function CalcExpressionInBrackets : double;
  begin
    result := CalcAddition;
    if ch = ')' then
      GetChar
    else
      raise Exception.Create ('Missing '')'' in expression')
  end;
  function CalcTerm : extended;
  begin
    case ch of
      '0'..'9' : result := CalcNumber;
      '(' : result := CalcExpressionInBrackets;
      else raise Exception.Create ('Syntax error in expression')
    end
  end;
  function CalcSignedTerm : extended;
  begin
    case GetNonWhitespace of
      '+' : result := CalcSignedTerm;
      '-' : result := -CalcSignedTerm;
      else result := CalcTerm
    end
  end;
  function CalcPower : extended;
  begin
    result := CalcSignedTerm;
    while ch = '^' do
      result := exp (ln (result) * CalcSignedTerm)
  end;
  function CalcMultiplication : extended;
  begin
    result := CalcPower;
    while ch in ['*', '/'] do
      case ch of
        '*' : result := result * CalcPower;
        '/' : result := result / CalcPower
      end
  end;
  function CalcAddition : extended;
  begin
    result := CalcMultiplication;
    while ch in ['+', '-'] do
      case ch of
        '+' : result := result + CalcMultiplication;
        '-' : result := result - CalcMultiplication
      end
  end;
begin
  pos := 0;
  result := CalcAddition
end;

mamcx · #9 27-09-2013

Otra manera es incluir python, javascript, lua u otro lenguaje de script.

Por ejemplo, con python:

http://www.atug.com/andypatterns/pythonDelphiTalk.htm

Lo he usado antes y funciona bien.

Con lua:

http://blog.spreendigital.de/2009/09...r-delphi-2010/

http://luapascal.luaforge.net/

Casimiro Notevi · #10 27-09-2013

Cita:

Empezado por mamcx

Otra manera es incluir python, javascript, lua u otro lenguaje de script.
Por ejemplo, con python:
http://www.atug.com/andypatterns/pythonDelphiTalk.htm
Lo he usado antes y funciona bien.
Con lua:
http://blog.spreendigital.de/2009/09...r-delphi-2010/
http://luapascal.luaforge.net/

¿Y eso qué tiene que ver con delphi?

dec · #11 27-09-2013

Hola,

Cita:

Empezado por Casimiro Notevi

¿Y eso qué tiene que ver con delphi?

Si lo que se quiere es evaluar expresiones, este tipo de "lenguajes de scripts" resultan útiles. El componente ArtFormula, por ejemplo, permite evaluar expresiones bastante complejas, además de proporcionar también cierto lenguaje de script similar a Pascal.

Casimiro Notevi · #12 27-09-2013

Sí, pero en el foro de club delphi, alguien pregunta por un eval en delphi, lo lógico no es contestar que use python, javascript, lua u otro lenguaje de script.

dec · #13 27-09-2013

Hola,

Cita:

Empezado por Casimiro Notevi

Sí, pero en el foro de club delphi, alguien pregunta por un eval en delphi, lo lógico no es contestar que use python, javascript, lua u otro lenguaje de script.

Lo que pasa es que estos "lenguajes de script" suelen incluir un "evaluador de expresiones" puesto que ellos mismos necesitan de uno. Es el caso de ArtFormula, que, no sólo ofrece un lenguaje de script, pero, además un evaluador de expresiones que puede usarse por separado y que incluso se recomienda, puesto que es cinco veces más rápido que usarlo en conjunto con el lenguaje de script que incluye el propio ArtFormula. Yo creo que el compañero iba por ahí Casimiro: de hecho ArtFormula es un componente para Delphi escrito en el propio Delphi.

mamcx · #14 27-09-2013

Esas opciones son las mejores si se quiere tener un abanico mas completo de funcionalidad de scripting en la app, pero un evaluador matematico es suficiente si es algo muy simple.

A proposito, recorde que hay una opcion en pascal:

http://www.remobjects.com/ps.aspx

[nlsgarcia] · #15 27-09-2013

Club Delphi,

Otra opción para evaluar expresiones en Delphi

Revisen este código :

Código Delphi [-]unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, CalcExpress, Math;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Expr1: TEdit;
    Expr2: TEdit;
    Vars: TMemo;
    Values: TMemo;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    ResultExpr1: TLabel;
    ResultExpr2: TLabel;
    CalcExpress1: TCalcExpress;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
   ResultExpr1.Caption := EmptyStr;
   ResultExpr2.Caption := EmptyStr;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin

   if Expr1.Text <> EmptyStr then
   begin
      try
         CalcExpress1.Formula := Expr1.Text;
         ResultExpr1.Caption := 'Result: ' + FloatToStr(RoundTo(CalcExpress1.calc([]),-6));
      except
         ResultExpr1.Caption := EmptyStr;
      end;
   end;

end;

procedure TForm1.Button2Click(Sender: TObject);
var
   args : Array of Extended;
   i : Integer;

begin

   if (Vars.Lines.Count = Values.Lines.Count) and (Expr2.Text <> EmptyStr) then
   begin

      try

         CalcExpress1.Formula := Expr2.Text;

         CalcExpress1.Variables:= Vars.Lines;

         SetLength(args,Values.Lines.Count);

         for i := 0 to Values.Lines.Count - 1 do
            args[i] := StrToFloat(Values.Lines[i]);

         ResultExpr2.Caption := 'Result: ' + FloatToStr(RoundTo(CalcExpress1.calc(args),-6));

      except

         ResultExpr2.Caption := EmptyStr;

      end;

   end
   else
      MessageDlg('Error en Expresión, Variables o Valores',mtError,[mbOK],0);

end;

end.

El código anterior realiza una evaluación de expresiones por medio del componente TCalcExpress (Freeware), como se puede ver en la siguiente imagen:

Consulten este link:

Cita:

CalcExpress : http://www.aidaim.com/products/free_...s/intr_spc.php

Espero sea útil

Nelson.