Problema con cambiar el nombre de Equipo

[Delphi01]

Hola ,

para cambiar el nombre de PC he utilizado lo siguiente :

Código Delphi [-]
function SetComputerName(AComputerName: string): Boolean;
var
  ComputerName: array[0..MAX_COMPUTERNAME_LENGTH + 1] of Char;
  Size: Cardinal;
begin
  StrPCopy(ComputerName, AComputerName);
  Result := Windows.SetComputerName(ComputerName);
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  if SetComputerName('NewComputerName') then
    ShowMessage('Computer Name Reset Setting will be used at next startup.')
  else 
    ShowMessage('Computer Name Not Reset');
end;

pero no funcionó y me da este error :

Slack overflow

estoy utilizando delphi xe8 y parec que no acepta Windows.SetComputerName y tuve que quitar Windows
y escribir la así

Código Delphi [-]
  Result :=SetComputerName(ComputerName);

Necesito saber porqué no funcinó, o si hay otro código mejor .

Muchas gracias.

[rocksoft]

Hola Delphi01,

eres Administrador de la computadora, el programa que ejecutas tiene derechos de admin?

Prueba a ejecutar tu aplicacion como admin.

[Neftali [Germán.Estévez]]

Otra opción (siempre muy socorrida) es recurrir a WMI.

La clase Win32_ComputerSystem, nos permite obtener esa información del equipo.
https://msdn.microsoft.com/en-us/lib...(v=vs.85).aspx

Y además entre los métodos que posee hay uno llamado Rename:
https://msdn.microsoft.com/en-us/lib...(v=vs.85).aspx

Utilizando un código como este puedes obtener el npombre actual del equipo:

Código Delphi [-]
var
  sWbemLocator  : OLEVariant;
  sWMIService   : OLEVariant;
  sWbemObjectSet: OLEVariant;
  sWbemObject   : OLEVariant;
  oEnum         : IEnumvariant;
  iValue        : LongWord;
begin;

 try
    CoInitialize(nil);
    try
      sWbemLocator  := CreateOleObject('WbemScripting.SWbemLocator');
      sWMIService   := sWbemLocator.ConnectServer('', 'root\CIMV2', '', '');
      sWbemObjectSet:= sWMIService.ExecQuery('SELECT * FROM Win32_ComputerSystem','WQL');
      oEnum         := IUnknown(sWbemObjectSet._NewEnum) as IEnumVariant;
      if oEnum.Next(1, sWbemObject, iValue) = 0 then
        Edit1.Text := sWbemObject.Properties_.Item('Name').Value;
    finally
      CoUninitialize;
    end;
 except
    on E:Exception do
        ShowMessage('Error al obtener el valor; ' + E.ClassName + '-' + E.Message);
 end;

Y usando uno como este puedes cambiar el actual nombre, por uno nuevo:

Código Delphi [-]
var
  sWbemLocator:ISWbemLocator;
  sWMIService:ISWbemServices;
  FWbemObject:ISWbemObject;
  Parametros:ISWbemObject;
  res:ISWbemObject;
  param:OleVariant;
  rValue:integer;
begin
  try
    CoInitialize(nil);
    try
      sWbemLocator := CoSWbemLocator.Create;
      sWMIService := sWbemLocator.ConnectServer('localhost', 'root\CIMV2', '', '', '', '', 0, nil);
      FWbemObject := sWMIService.Get('Win32_ComputerSystem.Name="'+ Edit1.Text + '"',0,nil);
      Parametros := FWbemObject.Methods_.Item('Rename',0).InParameters.SpawnInstance_(0);
      // Asignar valores
      param := Edit2.Text;
      Parametros.Properties_.Item('Name', 0).Set_Value(param);
      param :='XXX';
      Parametros.Properties_.Item('Password', 0).Set_Value(param);
      param :='XXX';
      Parametros.Properties_.Item('UserName', 0).Set_Value(param);

      res := sWMIService.ExecMethod('Win32_ComputerSystem.Name="'+ Edit1.Text + '"', 'Rename', Parametros, 0, nil);
      rValue := res.Properties_.Item('ReturnValue',0).Get_Value;

      if (rValue = 0) then begin
        ShowMessage('Correcto');
      end
      else begin
        ShowMessage('Se ha producido un error; Resultado: ' + IntToStr(rValue));
      end;
    except
      on E:EOleException do
          Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
      on E:Exception do
          Writeln(E.Classname, ':', E.Message);
    end;
  finally
    CoUninitialize;
  end;

Pon un formulario con un par de edits y añade ese código:



Una vez que lo cambies, puedes ver el resultado en la ventana de sistema:



Debes añadir al uses:

Código Delphi [-]
uses
  Diagnostics,
  ActiveX,
  ComObj,
  WbemScripting_TLB

El ejemplo completo lo he subido al ftp.

[Delphi01]

Muchas gracias Neftalieres muy amable te agradezco mucho tu explicación tan detallada, me funcionó lo de SetComputerName pero tenia que poner Windows en uses , algo que no lo capto muy bien todavía ,
para llamar la :

procedure TfrmMain.btnCambiarNombrePCClick(Sender: TObject);
begin
If SetComputerName(edit1.Text) Then
begin
If MessageDlg('Computer name succesfully set.' + #13#10#13#10 + 'Would you like to restart to apply changes?',mtConfirmation,[mbYes,mbNo],0) = mrYes Then
begin
WindowsExit(EWX_REBOOT or EWX_FORCE);
end;
end
Else
begin
ShowMessage('Computer name change failed.');
end;
end;

Una pregunta amigo que és la diferencia entre SetComputerName y SetComputerNameEx?