mandar resultado SQL a Excel??

[roman]

Más o menos así:

Código Delphi [-]
uses ComObj;

...

var
  Excel: OleVariant;
  Libro: OleVariant;
  Hoja: OleVariant;

begin
  // Creas una instancia de Excel
  Excel := CreateOleObject('Excel.Application');

  // Agregas un libro con una sólo hoja
  Excel.SheetsInNewWorkbook := 1;
  Libro := Excel.Workbooks.Add;

  // Hoja activa
  Hoja := Libro.ActiveSheet;

  // Accedes a las celdas con la propiedad Cells que es un arreglo
  // bidimensional (fila, columna) basado en 1.
  Hoja.Cells[1, 1] := 'Hola mundo';

  // Muestras la instancia de Excel
  Excel.Visible := true;
end;

Así pues, recorriendo los resultados de tu consulta puedes ir llenando las celdas de una hoja de Excel.

// Saludos

[mjjj]

gracias roman funciona a la perfeccion.

otra consulta... con este mismo metodo, estoi tratando de ingresar una formula a cierta celda en particular, como sigue:

Código Delphi [-]
inicio:=2;
fin:=5;
excel.Cells[fila,I].Value:= '=SUMA(C'+inttostr(inicio)+':C'+inttostr(fin);

El problema es que cuando me voy a la planilla, la formula esta escrita en la celda, pero no la reconoce como formula, debo hacerle un clic a la celda y luego a edit para editar la formula... ahi recien la reconoce como tal.

Porque podra ser esto?

Otra cosa... le puedo asignar formato a cierta celda en particular con este mismo metodo?

Gracias... saludos

[roman]

Las fórmulas debes ponerlas en inglés, o sea, en lugar de SUMA pon SUM.

// Saludos

[mjjj]

gracia nuevamente roman

la ultima pregunta... con este mismo metodo OLe, puedo carle formato a cierta celda en particular, por ejemplo, negrita, tipo moneda, etc??

gracias

[roman]

Por ejemplo

Código Delphi [-]
Hoja.Range['A5:A5'].Font.Bold := true;

donde Hoja es como en mi ejemplo.

// Saludos

[mjjj]

muchas gracias roman... funciono perfecto.

me puedes dar una lista de las propiedades que puedo modificar:

por ejemplo:

centrado, justificado izq, justificado derecha, color de las letras, color del fondo, bordes (completo, izq, der), tamaño y nombre de letra...

espero no ser de tanto molestia.... muchas gracias

saludos

[roman]

Realmente es imposible dar una lista porque hay multitud de objetos, colecciones, métodos, propiedades y valores. El ejemplo que te pongo ahora sólo abarcará una ínfima parte:

Código Delphi [-]
var
  Excel: OleVariant;
  Libro: OleVariant;
  Hoja: OleVariant;

begin
  Excel := CreateOleObject('Excel.Application');

  Excel.SheetsInNewWorkbook := 1;
  Libro := Excel.Workbooks.Add;
  Hoja := Libro.ActiveSheet;

  Hoja.Cells[1, 1] := 'Hola mundo';

  // Fuente de la celda
  Hoja.Cells[1, 1].Font.Name := 'Comic Sans MS';
  Hoja.Cells[1, 1].Font.Size := 18;
  Hoja.Cells[1, 1].Font.Color := RGB($ff, $ff, $ff);
  Hoja.Cells[5, 1].Font.Bold := true;

  // Alineación
  Hoja.Cells[1, 1].HorizontalAlignment := xlCenter;
  Hoja.Cells[1, 1].VerticalAlignment := xlTop;

  // Relleno
  Hoja.Cells[1, 1].Interior.Color := RGB($00, $80, $c0);
  Hoja.Cells[1, 1].Interior.Pattern := xlSolid;

  // Altura de la fila
  Hoja.Range['A1'].RowHeight := 49.5;

  // Combinar celdas
  Hoja.Range['A1:G1'].Merge;

  // Borde
  Hoja.Range['A1:G1'].Borders.LineStyle := xlContinuous;

  Excel.Visible := true;
end;

La mejor fuente de información, sin duda y a pesar será la Referencia de Microsoft Excel Visual Basic que se incluye en la ayuda de Excel. Pero sabe que no siempre es fácil dilucidar cómo se aplican las propiedades y métodos. Muchas veces ayuda grabar una macro de Excel haciendo lo que deseamos y examinando el código de la macro en el editor de Visual Basic de Excel. Por ejemplo, para preparar el ejemplo, no atinaba de sólo ver la ayuda, a ver como se ponía el relleno; entonces hice una macro y me di cuenta que se trataba de la propiedad Interior. Aún así, los macros no siempre se traducen fácilmente. En ocasiones lo que aparentemente se llama con paréntesis, en delphi se llama con corchetes.

Como tip general, te comento que de lo más importante que hay es el conjunto Range, que puede ser una celda, una fila, una columna o conjuntos de ellas.

Otra cosa es que para que delphi te acepte constantes como xlCenter, xlSolid y xlContinuous, debes incluir el archivo con las definiciones de excel, puede ser Excel97 o Excel2000 según la versión que tengas o desees.

// Saludos