Inicializando componentes de un form

[[movorack]]

Como el formulario ya lo tienes creado y lo que haces es mostrarlo nuevamente, limpiando los controles.

Podrías manipular los eventos Show y ShowModal y así establecer los valores iniciales antes de mostrar el formulario.

Ejemplo:

Aplicación con 2 formularios, Form1 y Form2, ambos creados al inicio del programa.

Form1 llama al Form2

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
begin
  Form2.Show;
end;

En Form2, el evento Show limpia el texto de los Edit antes de cambiar el valor a la propiedad "Visible"

Código Delphi [-]
type
  TForm2 = class(TForm)
    Edit1: TEdit;  
    Edit2: TEdit;

    //El FormShow sigue funcionando normal, ejecutando el código al mostrarse
    procedure FormShow(Sender: TObject); 
  private  
    procedure ResetControls;
    { Private declarations }
  public
    procedure Show; reintroduce;
    function ShowModal: Integer; override;
    { Public declarations }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

{ TForm2 }

procedure TForm2.FormShow(Sender: TObject);
begin
  Edit1.SetFocus;
end;

procedure TForm2.ResetControls;
  var
    i: integer;
begin
  for i := 0 to Self.ControlCount - 1 do
  begin
    if Self.Controls[i] is TEdit then
      TEdit(Self.Controls[i]).Text := '';
  end;
end;

procedure TForm2.Show;
begin
  ResetControls;

  inherited Show;
end;

function TForm2.ShowModal: Integer;
begin
  ResetControls;

  Result := inherited ShowModal;
end;

end.

[Dexter182]

Hola movorack!

¡Muchísimas gracias por tu detalladísima respuesta!.
Lo estuve probando y el problema no quiere irse.
Estuve pensando que quizás lo mejor sea también crear estos formularios dinámicamente, ya que los que creo de esa manera no tienen este problema.
Saludos!

[Dexter182]

Bueno, sigo haciendo pruebas...

- Volví a probar el código que propuso movorack y no noto mejoras. Lo más triste es que no entiendo el porqué, ya que el código propuesto tiene toda la lógica del mundo.
- Probé de crear los formularios "a demanda" y si bien resuelvo el problema actual, se presenta otro: los formularios tardan más en abrirse, lo cuál también es lógico.

Si estoy siendo demasiado "puntilloso", por favor me lo dicen.

Difícil la vida del programador amateur...

[[kuan-yiu]]

En el código propuesto por [movorack] haz un 'hide' al principio de 'ResetControls'. Así te aseguras de que el formulario no está visible durante ese proceso.

[[movorack]]

Es algo extraño que los usuarios sigan viendo como limpias los controles, ya que, en el ejemplo que te he dado, eso se hace antes de cambiar el estado de la propiedad visible y por lo tanto el formulario está aún oculto. ¿Podrías compartirnos como lo implementaste en tu formulario?.

[Dexter182]

Muchas gracias a ambos por responder.


Les dejo el código del formulario en el que lo estoy implementando (le quité el código de los procedimientos que consideré poco relevantes para que no quede tan largo):

Código Delphi [-]
unit Tarjetas;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls, Spin, IniFiles, XPStyleActnCtrls,
  ActnList, ActnMan, ToolWin, ActnCtrls, StdStyleActnCtrls, Buttons, StrUtils,
  Tipos, System.Actions, PngSpeedButton, System.UITypes;

type
  TForm_Tarjetas = class(TForm)
    ActionManager: TActionManager;
    ActionToolBar: TActionToolBar;
    actAceptar: TAction;
    actCancelar: TAction;
    actCredito: TAction;
    actCtaCte: TAction;
    actDebito: TAction;
    actEfectivo: TAction;
    btnAceptar: TPngSpeedButton;
    btnCancelar: TPngSpeedButton;
    cbCredito: TComboBox;
    cbCtaCte: TComboBox;
    cbDebito: TComboBox;
    eCuotas: TEdit;
    eInteres: TEdit;
    eTotal: TEdit;
    lCuotas: TLabel;
    lInteres: TLabel;
    lTotal: TLabel;
    Panel: TPanel;
    seCuotas: TSpinEdit;
    procedure actAceptarExecute(Sender: TObject);
    procedure actCancelarExecute(Sender: TObject);
    procedure actCreditoExecute(Sender: TObject);
    procedure actCtaCteExecute(Sender: TObject);
    procedure actDebitoExecute(Sender: TObject);
    procedure actEfectivoExecute(Sender: TObject);
    procedure cbCreditoChange(Sender: TObject);
    procedure eInteresExit(Sender: TObject);
    procedure eInteresKeyPress(Sender: TObject; var Key: Char);
    procedure eInteresKeyUp(Sender: TObject; var Key: Word;  Shift: TShiftState);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure FormKeyDown(Sender: TObject; var Key: Word; Shift: TShiftState);
    procedure FormKeyPress(Sender: TObject; var Key: Char);
    procedure FormShow(Sender: TObject);
    procedure seCuotasChange(Sender: TObject);
    procedure seCuotasKeyPress(Sender: TObject; var Key: Char);
  private
    { Private declarations }
    Archivo_Tarjetas : TIniFile;
    Venta : TDatosPago;
    procedure Actualizar_Total(Interes_Personalizado: Boolean);
    procedure ResetControls;
  public
    { Public declarations }
    property DatosPago:TDatosPago read Venta write Venta;
    procedure Show; reintroduce;
    function ShowModal: Integer; override;
  end;

var
  Form_Tarjetas: TForm_Tarjetas;

implementation

{$R *.dfm}

uses
  Principal, Varios;

procedure TForm_Tarjetas.actEfectivoExecute(Sender: TObject);
//Al presionar el botón de "Efectivo"
begin
  cbDebito.Visible  := FALSE;
  cbCredito.Visible := FALSE;
  cbCtaCte.Visible  := FALSE;
  lCuotas.Visible   := FALSE;
  seCuotas.Visible  := FALSE;
  eCuotas.Visible   := FALSE;
  lInteres.Visible  := FALSE;
  eInteres.Visible  := FALSE;

  eTotal.Text := Venta.Total;
end;

procedure TForm_Tarjetas.actDebitoExecute(Sender: TObject);
//Al presionar el botón de "Tarjeta de Débito"
begin
  cbDebito.Visible  := TRUE;
  cbCredito.Visible := FALSE;
  cbCtaCte.Visible  := FALSE;
  lCuotas.Visible   := FALSE;
  seCuotas.Visible  := FALSE;
  eCuotas.Visible   := FALSE;
  lInteres.Visible  := FALSE;
  eInteres.Visible  := FALSE;
//  cbDebito.SetFocus;

  eTotal.Text := Venta.Total;
end;

procedure TForm_Tarjetas.actCreditoExecute(Sender: TObject);
//Al presionar el botón de "Tarjeta de Crédito"
begin
  cbDebito.Visible  := FALSE;
  cbCredito.Visible := TRUE;
  cbCtaCte.Visible  := FALSE;
  lCuotas.Visible   := TRUE;
  seCuotas.Visible  := TRUE;
  eCuotas.Visible   := TRUE;
  lInteres.Visible  := TRUE;
  eInteres.Visible  := TRUE;

  seCuotas.Text  := IntToStr(Venta.Cuotas);
//  cbCredito.SetFocus;

  Actualizar_Total(FALSE);
end;

procedure TForm_Tarjetas.actCtaCteExecute(Sender: TObject);
//Al presionar el botón de "Cuenta Corriente"
begin
  cbCtaCte.Visible  := TRUE;
  cbDebito.Visible  := FALSE;
  cbCredito.Visible := FALSE;
  lCuotas.Visible   := FALSE;
  seCuotas.Visible  := FALSE;
  eCuotas.Visible   := FALSE;
  lInteres.Visible  := FALSE;
  eInteres.Visible  := FALSE;
//  cbCtaCte.SetFocus;

  eTotal.Text := Venta.Total;
end;

procedure TForm_Tarjetas.FormClose(Sender: TObject; var Action: TCloseAction);
//Libera la memoria ocupada por el archivo INI
begin
  Archivo_Tarjetas.Free;
end;

procedure TForm_Tarjetas.ResetControls;
begin
  Hide;

  //Abre el archivo Tarjetas.ini y completa el ComboBox con los nombres de las tarjetas
  Archivo_Tarjetas := TIniFile.Create (RutaAplicacion+'Datos\Tarjetas\Tarjetas.ini');

  ActualizarCombo(cbDebito, TARJETA, '2');
  ActualizarCombo(cbCredito, TARJETA, '3');
  ActualizarComboClientes(cbCtaCte);
  cbDebito.ItemIndex  := 0;
  cbCredito.ItemIndex := 0;
  seCuotas.Alignment  := taRightJustify;

  Case Venta.FormaPago of
    Contado :
      actEfectivo.Execute;

    Credito :
      begin
        If Venta.Tarjeta <> '' then
          cbCredito.ItemIndex := cbCredito.Items.IndexOf(Venta.Tarjeta);
        actCredito.Execute;
      end;

    Debito :
      begin
        If Venta.Tarjeta <> '' then
          cbDebito.ItemIndex := cbDebito.Items.IndexOf(Venta.Tarjeta);
        actDebito.Execute;
      end;

    CtaCte :
      begin
        If Venta.Cliente <> '' then
          cbCtaCte.ItemIndex := cbCtaCte.Items.IndexOf(Venta.Cliente);
        actCtaCte.Execute;
      end;
  end; {case}
end;

procedure TForm_Tarjetas.Show;
begin
  ResetControls;

  inherited Show;
end;

function TForm_Tarjetas.ShowModal: Integer;
begin
  ResetControls;

  Result := inherited ShowModal;
end;

end.

No lo mencioné, pero el defecto no lo alcanzo a percibir en mi PC (o al menos no se nota tanto)
Yo creo que es porque es una máquina más nueva que en la PC dónde se usa el programa.

Saludos y gracias!!!

[[movorack]]

Como en tu formulario tienes un ActionManager, solo para descartar que este esté afectando el comportamiento del formulario. ¿Podrias modificar el ResetControls para que en lugar de llamar la acción llame el procedimiento?

Me explico, que en lugar de ejecutar actCtaCte.execute, llame a actCtaCteExecute(actCtaCte)

[Dexter182]

Gracias por responder!

Empezado por movorack

Me explico, que en lugar de ejecutar actCtaCte.execute, llame a actCtaCteExecute(actCtaCte)

Estuve probando esto y tampoco resultó.

Para descartar, también probé de compilar como Release en vez de Debug con idem resultado.

Y también probé esto: https://stackoverflow.com/questions/...ot-of-controls

Tampoco resultó...

¿Será alguna configuración de la PC dónde está instalado?.

Saludos y mil gracias por su tiempo!!!