Override evento

[[Lepe]]

¿Qué código necesitas ejecutar al cerrar el form?

Igual no deberías hacerlo en ese momento.
Quizás haya un momento mejor de hacerlo.
Quizás se le deba proporcionar un evento al usuario del componente... con esto quiero decir que estas intentando modificar el comportamiento de algo que no es tuyo, y por tanto, quizás no sea buena idea hacerlo.

Cuando declaras una variable reservando memoria.... ¿el form se encarga de liberarlo? No, eres tú en el Onclose de la ventana el encargado de hacer un .Free del mismo.

La solución más rápida es proporcionar un método al usuario de tu componente que pueda ser llamado al cerrar el form o cuando al usuario se le antoje.

Saludos

[buildero_d]

Que tal lepe, gracias por contestar.

Bien, el código que se ejecuta al cerrar el form es una rutina en particular que he creado y que aplica para uno o varios forms. Si yo como desarrollador se que un formulario en particular necesita ejecutar dicho código... simplemente agrego mi componente y listo. Pondré un simple ejemplo.... imagina que encapsulé en un nuevo componente la famosa pregunta "¿Esta seguro que desea salir?", esta rutina la pude haber diseñado como una función que no pertenece a niguna clase y mandarla a ejecutar las veces que sea necesario en los forms que sean necesarios..... ahora yo voy un poco mas adelante... imagina que en lugar de tener que hacer la llamada de manera explicita lo hago de manera implicita a través del componente. Con solo agregarlo bastaria para que cada vez que se intente cerrar el form la rutina que envia el mensaje se ejecuta. En pocas palabras escribir menos y solo dedicarme a "ensamblar".

Asi que si por algún motivo necesito ademas de la pregunta de cierre del form, agregar otras lineas de código (que solo aplica en un caso en particular) y esas lineas las agrego en el evento OnCloseQuery del form ... solo se ejecuta la rutina del componente y no ambas.

Seguire investigando, a ver que puedo encontrar... y si hay mas ideas, pues serán bien recibidas.

Saludos!

[roman]

Antes de asignar tu propio evento CloseQuery guarda el que pudiera tener el formulario para poder llamarlo en su momento. Te pongo un ejemplo, está en delphi pero imagino que no tendrás problemas para pasarlo a C++:

Código Delphi [-]
{
  Componente para manejar el evento CloseQuery del formulario
  donde se inserte.
}
unit CloseQuery;

interface

uses
  Windows, SysUtils, Classes, Forms;

type
  TCloseQueryComponent = class(TComponent)
  private
    FForm: TForm; // formulario contenedor
    FOldCloseQuery: TCloseQueryEvent; // evento propio del formulario

  protected
    procedure ValidateContainer(AComponent: TComponent); override;
    procedure Loaded; override;
    procedure CloseQuery(Sender: TObject; var CanClose: Boolean); virtual;

  public
    constructor Create(AOwner: TComponent); override;
  end;

procedure Register;

implementation

{
  Registrar la componente
}
procedure Register;
begin
  RegisterComponents('buildero_d', [TCloseQueryComponent]);
end;

{ TCloseQueryComponent }

{
  Constructor de la componente

  Aquí sólo asignamos la referencia al formulario
}
constructor TCloseQueryComponent.Create(AOwner: TComponent);
begin
  inherited;

  if AOwner is TForm then
    FForm := TForm(AOwner);
end;

{
  Valida el contenedor

  Aquí nos aseguramos que estamos insertando la componente
  en un formulario y no, por ejemplo, en un DataModule.
}
procedure TCloseQueryComponent.ValidateContainer(AComponent: TComponent);
begin
  inherited;

  if not (AComponent is TForm) then
    raise Exception.Create('Este componente sólo puede insertarse en un formulario');
end;

{
  La VCL llama al método Loaded cuando ha terminado de leer el dfm
  del formulario. Entonces podemos estar seguros de que ya se dispone
  del evento CloseQuery asignado en el diseño. Esto no podría asegurarse
  en el constructor.
}
procedure TCloseQueryComponent.Loaded;
begin
  inherited;

  if Assigned(FForm) then
  begin
    FOldCloseQuery := FForm.OnCloseQuery;
    FForm.OnCloseQuery := CloseQuery;
  end;
end;

{
 Nuestro evento CloseQuery
}
procedure TCloseQueryComponent.CloseQuery(Sender: TObject; var CanClose: Boolean);
const
  Flags = MB_YESNO or MB_ICONWARNING;

begin
  if Assigned(FForm) then
  begin
    if Application.MessageBox('¿Desea cerrar esta ventana?', 'Confirmar', Flags) = ID_YES then
    begin
      CanClose := true;

      {
         Si el usuario accede a cerrar el formulario, probamos si había un
         evento asignado drante el diseño y, de ser así, lo invocamos.
      }
      if Assigned(FOldCloseQuery) then
        FOldCloseQuery(FForm, CanClose);
    end
    else
      CanClose := false;
  end;
end;

end.

// Saludos