Salto de pagina RichEdit
 

Hola a todos.
Mi progrunta es referente a un RichEdit. Queria saber la forma de hacer un salto de pagina por codgio.

Muchas gracias.

Carsoft

Hola,

Buscando en Google topé con varios sitios en los que se dice que no es posible insertar, de una manera sencilla, "page breaks" en los componentes "TRichEdit". En los resultados de la búsqueda en Google pueden verse otras páginas Web que tratan sobre el tema. Yo me quedo con esta página Web, en donde además se tratan no pocas cuestiones relativas al componente "TRichEdit". Ahí mismo se propone (en inglés) alguna que otra solución para lo que te ocupa, pero, ninguna es sencilla y se trata más o menos de chapucear un poco. Échale un vistazo a ver qué te parece a ti. ;)

No pense que era tan complicado, pensaba que era algun metodo o alguna propiedad que no conocia. voy a fijarme en la web a ver que puedo encontrar. Muchas gracias.

CARsoft (Quilmes - Bs. As. - Argentina) ;)

El RxRichEdit de la biblioteca RX imprime correctamente el salto de página.

// Saludos

como usarlos saltos de pagina RxRichEdit
 

Hola!...yo estoy tratando de usar saltos de pagina desde codigo, me podrias explicdar como usarlos en RxRichEdit?... ya los he descargado e instalado. pero no se como indicar sonde quiero un salto de linea desde el codigo.

de antemano muchas gracias!;)

He estado estos dos días tratando de encontrar una repuesta y resultó ser más difícil de lo que pensaba :D

Hace tres años respondí lo que respondí porque, en efecto, el RxRichEdit es capaz de imprimir los saltos de página -que corresponden a la instrucción \page de RTF. Comprobar esto es muy sencillo. Basta, por ejemplo, abrir MS Word, insertar ahí un salto de página, copiarlo y pegarlo en un RxRichEdit. Si esto mismo lo hacen en un RichEdit normal, el salto de página no se imprime.

Pero una cosa es saber que el RxRichEdit es capaz de imprimir saltos de página y otra muy distinta es insertar dichos saltos.

En principio, la solución es fácil:

Código Delphi [-]
var
  Paragraph: TParaFormat2;

begin
  FillChar(Paragraph, SizeOf(Paragraph), 0);
  Paragraph.cbSize := SizeOf(Paragraph);
  Paragraph.dwMask := PFM_PAGEBREAKBEFORE;
  Paragraph.dwReserved := PFE_PAGEBREAKBEFORE;
  RichEdit1.Perform(EM_SETPARAFORMAT, 0, LParam(@Paragraph));
end;

Al menos así lo indica la documentación.

Pero, al parecer no tiene ningún efecto. Al menos a mi no me funciona y en varios lugares he visto mencionado que el control RichEdit nativo hace caso omiso de esta modalidad del PARAFORMAT2.

Sin embargo, el RichEdit admite una forma de insertar texto o código RTF mediante el mensaje EM_STREAMIN. Este mensaje proporciona una función callback que es la encargada de proveer de datos al control. Ya hay por aquí en el club un código que usa este mensaje, pero cuando lo probé algo no me funcionó o posiblemente no lo utilicé correctamente. El caso es que finalmente me hice de un par de funciones para solucionar esto, que traté de simplificar lo más posible.

Código Delphi [-]
// Función de retrollamada (Al González dixit)
function ReadFromStream(
  dwCookie: Longint; pbBuff: PByte;
  cb: Longint; var pcb: Longint): Longint; stdcall;
begin
  Result := 0;
  pcb := TStream(dwCookie).Read(pbBuff^, cb);
end;

procedure InsertRtf(RichEdit: TRxRichEdit; Text: String);
var
  EditStream: TEditStream;
  Stream: TStringStream;

begin
  Stream := TStringStream.Create(Text);

  try
    EditStream.dwCookie := Integer(Stream);
    EditStream.dwError := 0;
    EditStream.pfnCallback := ReadFromStream;

    RichEdit.Perform(EM_STREAMIN, SF_RTF or SFF_SELECTION, LParam(@EditStream));
  finally
    Stream.Free;
  end;
end;

Deben incluirse las unidades RichEdit y RxRichEd. La función a usar es InsertRtf, que, en principio, serviría para insertar cualquier código RTF. Para el caso de un salto de página, sería así:

Código Delphi [-]
InsertRtf(RxRichEdit1, '{\rtf1 \page}');

Con esto se tendrá el buscado salto de página en el punto donde se localice el cursor.

// Saludos

Eres Grande!
 

Tenia mas de dos semanas "peleando" con esa situacion, y no pude resolverla... INFINITAS GRACIAS ROMAN ;).

Por si cabe la duda de para que quiero hacer eso:

Utilizo el RxRichEdit para imprimir un recibo de ventas en una impresora termica (como lo ha sugerido Neftalí en Este Hilo). Pero necesito imprimir dos tickets por cada venta (uno para el cliente y un comprobante que conserva la tienda), para tal efecto relleno los dos RxRichEdit con la informacion necesaria, y mando a imprimir ambos tickets. hasta ahi funciona bien, el problema surgia cuando mandaba a impresion simultaneamente desde dos equipos en red, en vez de salir P.Ej.

• Ticket Maquina1, Comprobante Maquina 1 ---> Ticket Maquina2, Comprobante Maquina 2.

Se mezclaban las impresiones:

• Ticket Maquina1, Ticket Maquina2 ---> Comprobante Maquina 2, Comprobante Maquina 1.

Una posible solucion era poner todos los datos en un solo RxRichEdit y enviar una sola impresion, para los dos tickets, pero no podia enviar la cuchilla para cortar entre los dos tickets.

Con tu respuesta ha quedado solucionado mi problema y espero que sirva a laguin mas con un problema similar....

OTRA VEZ GRACIAS!!!

A toro pasado
 

Ahora veo que es más fácil (y quizá lo sea más, no lo sé). Basta con esto para insertar el salto de página:

Código Delphi [-]
var
    Stream: TStream;

begin
    Stream := TStringStream.Create('{\rtf1\page}');
    try
        RxRichEdit1.StreamMode := RxRichEdit1.StreamMode + [smSelection];
        RxRichEdit1.Lines.LoadFromStream(Stream);
    finally
        Stream.Free;
    end;
end;

// Saludos