Procedimientos para separar cadenas
 

Hola a todos y saludos

me preguntaba si hay alguna función que me pueda indicar cúantas partes tiene una cadena de texto y otra para obtener cada una de estas partes. Me explico, la cadena "Uno,Dos,Tres" tiene tres partes, la primera es "Uno", la segunda "Dos" y la tercera "Tres".

De hecho ya me hice un par de funciones para la ocasión, pero me da la impresión de que tiene que existir algo en Delphi que ya lo haga.

Y si no lo hay, bueno, pues me tocará mostraros mi código.

Gracias

Hola para lo que buscas, no recuerdo nada que exista en Delphi, siempre me he visto funciones creadas por terceros, un ejemplo en concreto en Trucomania es este

Échale un vistazo a ver si te sirve o no si prefieres usar la tuya porque te va bien ;)

Saludos

La verdad, la mía es bastante más sencilla, aunque lo más seguro sea debido a que solo se puede usar como separador un carácter.

Gracias

Bueno, Cuando necesito hacer algo asi utilizo el Pos o recorro la cadena con un ciclo.

Saludos

Y antes:

Estamos esperando... :rolleyes:

// Saludos

Yo para estas cosas utilizo un TStringList. :D Aunque parece que esa es mi solución para todo ...

A mi también se me ocurre eso pero no deja de tener sus inconvenientes:

1. Hay que construir el objeto y luego destruirlo y encima hacer esto último dentro de un bloque try-finally.

2. No funciona bien si las partes tienen espacios:

Hola,soy pepe perez perea

Lo toma como si fuesen cinco partes.

Por ello me interesa ver cuál es el código de ixMike.

// Saludos

:( ¿no te interesa ver el mio?.

Código Delphi [-]
function Token(Sub: string; var S: string): string;
begin
  Result:= '';
  while Length(S)>0 do
  begin
    if AnsiSameText(Copy(S, 1, Length(Sub)), Sub) then
    begin
      Delete(S, 1, Length(Sub));
      break;
    end;
    Result:= Result + Copy(S,1,1);
    Delete(S,1,1);
  end;
end;


// Un ejemplo de uso
var
  S: string;
begin
  S:= 'uno[sep]dos[sep]tres';
  while Length(S)>0 do
    ShowMessage(token('[sep]',S));
end;

No se si te acuerdas de Pico, el micro servidor web que postee por aquí hace unos meses, pues cuando estuve creando a su hermano mayor tuve que crear muchas funciones parecidas para manejar cadenas porque me había empeñado en no usar la unit classes para así hacerlo mas pequeño. Pero eso ya es otra historia, y ya no te cuento cuando intente trasladarlo todo a C ... Que forma de complicarse la vida por diversión :D

Ja, ja. Bueno, tú no lo habías ofrecido y además mencionaste StringLists, ¿o no eres el mismo seoane de hace tres mensajes? :D

Pero lo veo muy bien, muy compactito. Lo único malo es que está tan bien que ahora hay aún menos posibilidades de que ixMike nos muestre su código. :D

// Saludos

Trasteando como mi Turbo he visto que el objeto TStrings cuenta con la propiedad StrictDelimiter. Cuando esta propiedad esta a TRUE solo se tiene en cuenta el carácter delimitador, ignorando los espacios y demás. Ignoro si existe en versiones anteriores de delphi, en la 7 no la tenia. Parece que los de Borland recapacitaron y acabaron con la sin razón de meter siempre en el mismo saco el carácter delimitador y cualquier otro entre el #1 y el #32.

Código Delphi [-]
var
  i: integer;
begin
  with TStringList.Create do
  try
    Delimiter:= ',';
    // Aqui esta 
    StrictDelimiter:= TRUE;
    DelimitedText:= 'Hola,soy pepe perez perea';
    for i:= 0 to Count - 1 do
    begin
      ShowMessage(Strings[i]);
    end;
  finally
    Free;
  end;
end;

¡Ah! Pues hasta que se les prendió el foco :)

Ahora que, eso sí, nada como el amigable php:

Salida:

// Saludos

:confused: !!!!vaya qué despiste!!!

Pues ahora mismo no lo llevo encima (no tengo internet en casa). Quizás mañana a esta hora...

Muchas gracias a todos, por las sugerencias y códigos.

Edito: En mi código no busco una cadena dentro de otra (buscar una SubString en una String), sino que en una string busco la parte 2, o 3, ó 4, ó 1000. Sería algo así:

Código Delphi [-]

s:=ObtienePalabra(';','Uno;dos;tres',2);
//s ahora vale "dos"

Para saber cuántas palabras hay (las palabras pueden ser nulas, como "uno;dos;;cuatro") simplemente cuento cúantos separadores hay (en el ejemplo, ";")

Holas, esta aqui ixMike conmigo y dice que aqui teneis el codigo:

Código Delphi [-]
Function ContarPalabras(Texto: String; Separador: Char): Integer;
var i: Integer;
begin
Result:=0;
If Length(Texto)=0 then Exit else
 for i:=1 to Length(Texto) do if Texto[i]=Separador then Inc(Result);
Inc(Result);
end;
 
Function ObtienePalabra(Texto: String; Separador: Char; Indice: Integer): String;
var
  c, n, p: Integer;
  Resto: String;
begin
If Pos(Separador,Texto)=0 then Result:=Texto else
  begin
  c:=1;
  for n:=1 to Length(Texto)do
   if Texto[n]=Separador then
     begin
     if Indice=1 then
       begin
       Result:=Copy(Texto,1,n-1);
       Exit;
       end;
     Inc(c);
     p:=n+1;
     Resto:=Copy(Texto,p,Length(Texto)-p+1);
     If c=Indice then
       begin
       If Pos(Separador,Resto)>0 then
        Result:=Copy(Texto,p,Pos(Separador,Resto)-1)else Result:=Resto;
       Exit;
       end;
     end;
  end;
end;

y dice: "que aproveche !!"

Saludos !!

Para Delphi 7 que no cuenta con la propiedad StrictDelimiter

El truco está en reemplazar el espacio por un carácter que se esté seguro que no se va a usar y luego hacer el proceso inverso.

Código Delphi [-]
Var
   SubFrase: TStringList;
begin
     SubFrase:= TStringList.Create;

     SubFrase.Text:= 'hola, soy pepe perez perea, no tengo pereza, por eso uso delphi';
     SubFrase.Delimiter:= ',';
     SubFrase.DelimitedText:=  StringReplace(SubFrase.Text, ' ', '·', [rfReplaceAll]);

     ShowMessage(StringReplace(SubFrase.Strings[0], '·', ' ', [rfReplaceAll]));
     ShowMessage(StringReplace(SubFrase.Strings[1], '·', ' ', [rfReplaceAll]));
     ShowMessage(StringReplace(SubFrase.Strings[2], '·', ' ', [rfReplaceAll]));
     ShowMessage(StringReplace(SubFrase.Strings[3], '·', ' ', [rfReplaceAll]));
     
     FreeAndNil(SubFrase);
end;

Para enriquecer el tema, hoy ya se puede usar el método implícito Split (realmente contenido en el ayudante TStringHelper):
http://docwiki.embarcadero.com/Libra...ngHelper.Split

Un abrazo por separado.

Al González. :)