mostrar una imagen en un DBGrid

[adebonis]

Hola.

¿Alguien sabe cómo mostrar una imagen (.bmp) en un DBGrid según el valor True/False de un campo?

Uso Delphi 5.

Gracias.
Adolfo Bonis
Barcelona

[luisgutierrezb]

pues puedes hacer un campo calculado y asignarle el bmp segun la opcion y ya solo necesitarias un dbgrid que muestre imagenes, el de los JEDI lo hace, entre otros

[roman]

Te pongo un ejemplo usando un DBGrid normal. Este es el evento OnDrawColumnCell del DBGrid:

Código Delphi [-]
procedure TForm1.DBGrid1DrawColumnCell(
  Sender: TObject; const Rect: TRect; DataCol: Integer;
  Column: TColumn; State: TGridDrawState);
var
  Bmp: TBitmap;
  L, T: Integer;

begin
  // Si es la columna donde deseas poner la imagen...
  if DataCol = 4 then
  begin
    // Seleccionas la imagen a usar según el valor del campo
    if Table1.FieldByName('campo').AsBoolean then
      Bmp := BitmapSi
    else
      Bmp := BitmapNo;

    // Calculas las coordenadas para que la imagen quede centrada en la celda
    L := Rect.Left + (Rect.Right - Rect.Left - Bmp.Width) div 2;
    T := Rect.Top + (Rect.Bottom - Rect.Top - Bmp.Height) div 2;

    // Dibujas la imagen
    DBGrid1.Canvas.Draw(L, T, Bmp);
  end
  else
    DBGrid1.DefaultDrawColumnCell(Rect, DataCol, Column, State);
end;

Aquí, BitmapSi y BitmapNo serían dos TBitmap creados al inicio con las imágenes que quieras:

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
begin
  BitmapSi := TBitmap.Create;
  BitmapSi.LoadFromFile('SI.bmp');

  BitmapNo := TBitmap.Create;
  BitmapNo.LoadFromFile('NO.bmp');
end;

y destruidos al final

Código Delphi [-]
procedure TForm1.FormDestroy(Sender: TObject);
begin
  BitmapSi.Free;
  BitmapNo.Free;
end;

// Saludos

[adebonis]

Hola roman.

Va perfecto, pero lo que me pasa es que la imagen se me muestra por encima del texto /True o False.

¿Sabes si hay un sistema para que no se me vea el texto por debajo de la imagen?

Gracias

Adolfo Bonis
Barcelona.

[roman]

Si pusiste el código tal cual, creo entonces que lo que faltaría es poner la propiedad DefaultDrawing del DGrid en false.

// Saludos

[roman]

Ya he comprobado que eso es lo que faltaba.

Por cierto, la columna sobre la que dibujas no necesariamente debe corresponder a la de un campo. Me explico: si usas el editor de columnas del DBGrid, puedes agregar columnas que no estén asociadas a ningún campo y dibujar sobre ella. De hecho eso fue lo que hice antes y por ello no me había percatado de la sobrescritura. Pero el caso es que haciendo esto puedes preservar el campo original true/false, además de la nueva columna.

// Saludos

[adebonis]

Hola.

Cierto, me faltaba poner DefaultDrawing en false.

Ya sé que soy puntilloso, pero ahora el color de fondo de la fila no me aparece en la columna donde he dibujado la imagen.

Gracias otra vez.
Adolfo Bonis
Barcelona

[roman]

Está bien que seas puntilloso. Si te refieres al color de la selección, prueba poniendo esta modificación al principio del evento:

Código Delphi [-]
  // Si es la columna donde deseas poner la imagen...
  if DataCol = 4 then
  begin
    // Si la celda está seleccionada, escoger el color de selección del sistema
    if gdSelected in State then
      DBGrid1.Canvas.Brush.Color := clHighlight;

    // Dibujar el fondo
    DBGrid1.Canvas.FillRect(Rect);

    // Seleccionas la imagen a usar según el valor del campo
    if Table1.FieldByName('campo').AsBoolean then
      Bmp := BitmapSi
    else
      Bmp := BitmapNo;

    // Calculas las coordenadas para que la imagen quede centrada en la celda
    L := Rect.Left + (Rect.Right - Rect.Left - Bmp.Width) div 2;
    T := Rect.Top + (Rect.Bottom - Rect.Top - Bmp.Height) div 2;

    // Dibujas la imagen
    DBGrid1.Canvas.Draw(L, T, Bmp);
  end
  else
    DBGrid1.DefaultDrawColumnCell(Rect, DataCol, Column, State);

// Saludos