Guardar y recuperar imagen en bd

[Lizette]

Hola compañeros, trato de guardar una imagen en mi bd pero lo que hago es guardarla como string, escribiendola en un flujo Stream, de alli para recuperarla leo el campo y lo escribo en un flujo stream y de allí cargo la imagen. El problema esk no me muestra ninguna imagen , alguien me pudiera orientar, o bien sugerir otra forma de hacerlo.

Código Delphi [-]
//Para guardar la imagen
foto := TStringStream.Create('');
   Image3.Picture.Graphic.SaveToStream(foto);

   ADOtblCte.FieldByName('FotoC').AsString:=foto.DataString;

Código Delphi [-]
//Para mostrar la imagen
var
imagen:TStringStream;
cargar:TBitMap;
begin
 imagen := TStringStream.Create('');
 ADOTable1.Open;
 imagen.WriteString(ADOTable1.FieldValues['FotoC']);
 cargar:=TBitMap.Create;
 cargar.LoadFromStream(imagen);
 image1.Picture.Graphic:=cargar;
 ADOTable1.Close;
end;

Saludos y gracias

[rgstuamigo]

Disculpa mi ignorancia ,pero dices que la imagen lo guardas como string? ¿como es eso? Talves te estas refiriendo a solo guardar la ruta de la imagen?
Y aparte de eso ¿Que servidor de base de datos usas(MySQL,MS SQL Server,Oracle,Firebird,etc)?¿Y que tipo de dato es la columna de tu tabla que guarda la imagen (Char,Varchar,Blob,etc)?.

Saludos...

[Lizette]

Uff, perdón, se me olvido comentar que el motor de bd que utilizo es MySql, y el campo es varchar.

Ese código lo saqué de un post de la web del programador, que supuestamente guarda la imagen como texto, pero ya vi q nomás no funciona jeje. Saludos

[Alzheimer]

pk no usas un kampo de tipo Graphic *son para esto* y te ahorras todo eso de konvertir en string una imagen k parece k no funciona????

[calogero]

Hola en casos como ese lo que yo hago es solo guardar la ruta en la base de datos y la imagen la guardo en una carpeta en el disco duro asi solo leo la ruta en la base de datos y la imagen la tomo de la carpeta del disco duro, tal vez no sea la mejor forma pero me ha funcionado yo desarrollo aplicaciones web en php y esa es la manera en la que guardo imágenes.

saludos..

[rgstuamigo]

Empezado por calogero

Hola en casos como ese lo que yo hago es solo guardar la ruta en la base de datos y la imagen la guardo en una carpeta en el disco duro asi solo leo la ruta en la base de datos y la imagen la tomo de la carpeta del disco duro, tal vez no sea la mejor forma pero me ha funcionado yo desarrollo aplicaciones web en php y esa es la manera en la que guardo imágenes.

saludos..

Es verdad es una buena solucion, personalmente tambien he implementado algo asi, pero tiene un inconveniente que si la aplicacion es multiusuario y se encuentra en diferentes Maquinas, pues no se va poder ver las imagenes en todas y peor aun si la aplicacion se conecta desde una red Wan.
Por otro lado tambien si se guarda muchas imagenes directamente en las tablas del servidor, puede provocar lentitud o sobrecarga en la red.
Asi que en todo caso hay que ver la forma mas adecuada posible de implementarlo y eso depende de la aplicacion, y de quien lo esta implementado.
Saludos...

[roman]

Lizette,

No sé si pueda guardarse una imagen en un campo de tipo VarChar, en todo caso, no me parece el más indicado. Sería mejor que optaras por un campo BLOB (LongBlob, MediumBlob, TinyBlob, etc., dependiendo del tamaño de tus imágenes).

Te pongo aquí unas rutinas para guardar y mostrar imágens en una base MySQL usando un ADOTable:

Código Delphi [-]
// Guardar una imagen
var
    Stream: TStringStream;

begin
    Stream := TStringStream.Create('');

    try
        Image1.Picture.Graphic.SaveToStream(Stream);

        AdoTable1.Append;
        AdoTable1.FieldByName('titulo').AsString := 'Mi primera foto';
        AdoTable1.FieldByName('foto').AsString := Stream.DataString;
        AdoTable1.Post;
    finally
        Stream.Free;
    end;
end;

// Mostrar la imagen
var
    Stream: TStringStream;
    Bitmap: TBitmap;

begin
    Bitmap := nil;
    Stream := nil;

    try
        Bitmap := TBitmap.Create;
        Stream := TStringStream.Create(AdoTable1.FieldByName('foto').AsString);

        Bitmap.LoadFromStream(Stream);
        Image1.Picture.Assign(Bitmap);
    finally
        Bitmap.Free;
        Stream.Free;
    end;
end;

Las rutinas equivalentes usando un AdoQuery

Código Delphi [-]
// Guardar una imagen
var
    Stream: TStringStream;

begin
    Stream := TStringStream.Create('');
    try
        Image1.Picture.Graphic.SaveToStream(Stream);

        AdoQuery1.SQL.Text := 'insert into fotos (titulo, foto) values(:titulo, :foto)';
        AdoQuery1.Parameters.ParamByName('titulo').Value := 'Mi primera foto';
        AdoQuery1.Parameters.ParamByName('foto').Value := Stream.DataString;
        AdoQuery1.ExecSQL;
    finally
        Stream.Free;
    end;
end;

// Mostrar la imagen
var
    Stream: TStringStream;
    Bitmap: TBitmap;

begin
    Bitmap := nil;
    Stream := nil;

    try
        Bitmap := TBitmap.Create;

        AdoQuery1.SQL.Text := 'select titulo, foto from fotos where id = :id';
        AdoQuery1.Parameters.ParamByName('id').Value := 8;
        AdoQuery1.Open;

        Stream := TStringStream.Create(AdoQuery1.FieldByName('foto').AsString);

        Bitmap.LoadFromStream(Stream);
        Image1.Picture.Assign(Bitmap);
    finally
        Bitmap.Free;
        Stream.Free;
    end;
end;

Veo más conveniente usar un AdoQuery, sobre todo para obtener la imagen desde la base de datos; porque usar un AdoTable implicaría, como dice rgstuamigo, demasiado tráfico. Lo normal sería, mostrar una lista de registros y que el usuario escoja de cual quiere ver la imagen, y sólo entonces descargas la foto.

// Saludos