Se borra lo dibujado en el canvas, como evitarlo?

[[Gunman]]

Hola, he dibujado un circulo en el Canvas de mi form de la siguiente manera:
Form1.Cavas.Ellipse(0,0,400,400);
El problema es que al passar otra ventana por encima me borra lo dibujado, como lo puedo solucionar?

[[seoane]]

Tienes 2 soluciones, utilizar un conponente TImage para hacer tus dibujos, o en el evento OnPaint del formulario redibujar lo que se ha borrado.

El evento OnPaint se produce cuando el formulario necesita ser redibujado. Aqui puedes poner la instruccion:

Código Delphi [-]
procedure TForm1.FormPaint(Sender: TObject);
begin
  Form1.Canvas.Ellipse(0,0,400,400);
end;

Esto solo es util cuando la operacion de dibujo no es muy compleja, pero cuando hay que dibujar varios elementos puede ser util utilizar la propiedad Canvas.Cliprect que nos devueleve las coordenadas de la porcion del formulario que necesita ser redibujada, evitando asi tener que repetir todo el dibujo:

Código Delphi [-]
procedure TForm1.FormPaint(Sender: TObject);
var
  R: TRect;
begin
  if IntersectRect(R, Canvas.ClipRect, Rect(0,0,400,400)) then
    Canvas.Ellipse(0,0,400,400);
end;

[delphi.com.ar]

Si dibujas sobre una ventana, te tienes que preocupar por redibujar cada vez que esta ventana lo requiera, por ejemplo sobreescribiendo el mensaje WM_PAINT:

Código Delphi [-]
type
  TForm1 = class(TForm)
  private
    procedure WMPaint(var Message: TWMPaint); message WM_PAINT;
  public
  end;

...

implementation

procedure TForm1.WMPaint(var Message: TWMPaint);
begin
  Canvas.Rectangle(Rect(10, 10, 100, 100));
end;

Saludos!

[[seoane]]

Solo comentar, si me lo permites, que se podria anadir al codigo anterior un inherited:

Código Delphi [-]
procedure TForm1.WMPaint(var Message: TWMPaint);
begin
  inherited;
  Canvas.Rectangle(Rect(10, 10, 100, 100));  
end;

De todas formas el evento Onpaint del formulario cumple la misma funcion, sin necesidad de andar interceptando los mensajes. Pero es cuestion de gustos

[lpmlpm]

lo pongo solo por si se da el caso de que te sirva...

cuando yo tengo necesidad de pintar sobre un canvas y necesito que exista cierta persistencia de lo que se dibuja, o bien como dicen es muy complejo el dibujo que se ha de hacer, utilizo la librería G32 que es mucho más rápida y eficiente que el canvas tradicional y funciona de la misma manera... la gran ventaja que tiene el usar el canvas de estos componentes es que te olvidas de problemas como este que mencionas y aparte ganas velocidad de pintado y tienes a tu dispocición muchas nuevas funciones que te pueden ahorrar mucho trabajo.

Saludos

[delphi.com.ar]

Empezado por seoane

De todas formas el evento Onpaint del formulario cumple la misma funcion, sin necesidad de andar interceptando los mensajes. Pero es cuestion de gustos

Totalmente!.. es mas, sugiero el OnPaint para compatibilidad entre plataformas... Solo di un ejemplo abierto de lo que me acordaba de memoria

[[Gunman]]

Sólo hay un problemilla... No es que dibuje un círculo, bueno si. El problema es que dibujo 2147483640 puntos. los tengo que redibujar todos? Cuando hay 100 puntos vale, pero cuando vamos por unos cuantos millones de puntos... Además, los puntos caen en una posición aleatória... Qué me aconsejáis?

[[Gunman]]

Bueno, os voy a proporcionar más información, que eso nunca viene mal para resolver un problema. Pensé que no seria necesaria, pero quizás paso algo por alto y no quiero perder tiempo...
Bueno, he hecho un programa para aproximarte al valor del número PI. Básicamente se basa en la probabilidad. Si tenemos un cuadrado de lado dos y inscribimos una circumferencia en el, el área del cuadrado será 4 (2^2) y la del círculo PI (PI·1^2). Entonces, si hacemos un punto al azar en el cuadrado, la probabilidad de que caiga en el círculo es de PI/4. Bueno, podéis buscar en el google "método montecarlo".
Entonces, cada vez que se elige al azar las coordenadas del punto que se va a pintar, como no, lo pinta (esto no es necesario, pero queda chulo) y ahí está el problema, que al pintar los puntos y pasar una ventana por encima me borra los puntos!
No puedo repintar cada vez, porque en alguna ocasión deberia repintar 9999999 puntos y en la siguiente esos más uno, y así sucesivamente.
En vez de hacerlo en el canvas del form he probado con un PaintBox y tengo el mismo problema. Con un TImage no me pinta el punto cada vez. No se que hacer...
Bueno, pongo el código del programa (sólo lo que nos interesa):

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var
  Point: TPoint;
  I, Counter, Max: Integer;
begin
  Form1.Canvas.Ellipse(0,0,400,400);
  Counter := 0;
  Max := StrToInt(FloatToStr(JvSpinEdit1.Value));
  for I := 1 to Max do
  begin
    Randomize;
    Point.X := Random(400);
    Randomize;
    Point.Y := Random(400);
    if CheckPoint(PointToModPoint(Point)) = True then
    begin
      Counter := Counter+1;
      Form1.Canvas.Pixels[Point.X, Point.Y] := clRed;
    end
    else
      Form1.Canvas.Pixels[Point.X, Point.Y] := clBlue;
    Label2.Caption := Format('Tirs: %d || Encerts: %d', [I, Counter]);
    Label2.Repaint;
  end;
  ShowMessage(FloatToStr((Counter/Max)*4));
end;

[delphi.com.ar]

Empezado por [Gunman]

Sólo hay un problemilla... No es que dibuje un círculo, bueno si. El problema es que dibujo 2147483640 puntos. los tengo que redibujar todos? Cuando hay 100 puntos vale, pero cuando vamos por unos cuantos millones de puntos... Además, los puntos caen en una posición aleatória... Qué me aconsejáis?

Entonces es conveniente que lo dibujes sobre un mapa de bits, que mantenga la información. En pocas palabras podrías pegar un TImage que abarque la superficien que necesites y pintar sobre el canvas de algún formato gráfico.

Saludos!

[[seoane]]

Si el problema con el TImage es que no se actualiza, utiliza el metodo repaint igual que haces con el label.

[[Gunman]]

Muchas gracias, juraría que había probado lo de Repaint con el TImage, quizás me confundí y escribí Image1.Refresh en vez de Image1.Repaint. De todos modos, muchas gracias por vuestro interés!

[[seoane]]

Estuve jugando un poco con el codigo que dejaste y solo queria comentarte un par de cositas.

No utilices el randomize dos veces en cada ciclo, porque los numeros no saldran tan aleatorios como cabria esperar, lo mejor es llamar a randomize una sola vez. Ya lo dice la ayuda de delphi:

Do not combine the call to Randomize in a loop with calls to the Random function

Por ultimo, para acelerar un poco la cosa, podrias hacer dos loop uno dentro del otro, en el de dentro colocarias puntos y en el de fuera actualizarias el TImage, visualmente apenas notaras la diferencia pero sera mucho menos trabajo para la aplicacion.

Aqui te dejo el codigo tal como yo lo veo:

Código Delphi [-]
const
  radio = 200;
  Vueltas = 1000;
  PuntosPorVuelta = 100;
var
  x,y: Integer;
  i, j, k: Integer;
begin
  Randomize;
  k:= 0;
  Image1.Picture.Assign(nil);
  Image1.Width:= 2*radio;
  Image1.Height:= 2*radio;
  Image1.Canvas.Ellipse(0,0,2*radio,2*radio);
  for j:= 1 to Vueltas do
  begin
    for i := 1 to PuntosPorVuelta do
    begin
      x := Random(2*radio);
      y := Random(2*radio);
      if  (sqr(x-radio)+sqr(y-radio))< sqr(radio) then
      begin
        inc(k);
        Image1.Canvas.Pixels[x, y]:= clRed;
      end
      else
        Image1.Canvas.Pixels[x, y]:= clBlue;
      Label2.Caption := Format('Tirs: %d || Encerts: %d', [i*j, k]);
    end;
    Label2.Repaint;
    Image1.Repaint;
  end;
  ShowMessage(FloatToStr((k/(Vueltas*PuntosPorVuelta))*4));
end;

Lo dicho, solo es una opinion, no te molestes porque retoque un poco tu codigo

[Neftali [Germán.Estévez]]

Una sugerencia; Yo sacaría el Randomize fuera del For y pondría sólo 1.
EDITO: Acabo de leer que ya lo han comtenado.

[[Gunman]]

Muchas gracias, no habia leído estos mensajes y si los hubiese leído me podrian haber evitado tiempo y otro hilo que abrí ayer.
Muchas gracias y perdón!

[Diavlo]

Por casualidad pase por este hilo y es lo q andaba buscando, solo unas dos cositas mas.
Primero: como cambio el color del fondo del TImage, dibujo unas lineas o cualquier cosa y me sale con fondo blanco.
Segundo: Como se borra todo lo q he dibujado, lo q estoy haciendo es el metodo grafico para problemas de programacion lineal, hasta ahora mi programa grafica solo rectas, pero cuando quiero graficar otras rectas las rectas anteriores sigeun ahi y yo quiero borrarlas.

[Neftali [Germán.Estévez]]

El color de fondo deberías poder cambiarlo con:

Código Delphi [-]
...  Canvas.Brush.>Color := clRed;

[Diavlo]

Probe con el siguiente codigo:

Código Delphi [-]
  Image1.Canvas.Brush.Color := clBlack;

Y el fondo sigue siendo blanco, no puedo cambiarle el color de fondo al TIamge.

[[seoane]]

Cambiar el color de fondo solo afecta a las operaciones de dibujo posteriores al cambio. Me explico, si cambias el color a negro luego tienes que borrar todo el canvas para que este se cubra de negro:

Código Delphi [-]
  Image1.Canvas.Brush.Color := clBlack;
  Image1.Canvas.FillRect(Image1.Canvas.ClipRect);

[pattyka]

disculpen... tengo una duda ... si ya hice un dibujo en paintbox ¿ Cómo hago para borrarla o limpiar el paint box?... gracias...

[Diavlo]

Para borrar lo dibujado en un PaintBox simplemente ponle:

Código Delphi [-]
 
PanintBox1.Repaint;