Calcular tiempo restante y mostrar en porcentaje

[alquimista]

Muy buenas...

Estoy usando variables tipo TdateTime, para medir tiempo de adquisicion de datos.

Uso durTotal para duración total de datos
Luego comparo con la fecha y hora actual. hago la resta
if (Now()>=DurTotal) then termino captura.

Cuando muestro tiempo restante (durTotal -now) si la duracción total supera en unas 12 horas o un dia me la muestra mal.

Y como puedo hacer que se muestre en porcentaje (como son valores (tdatetime) con muchos decimales no se como hacerlo) para usar una progressbar

Un saludo...

[afxe]

No sé que versión de delphi tienes, pero si es superior a la 6 échale un vistazo a la libreria DateUtils, creo que tiene lo que buscas.

Saludos.

[[newtron]]

Hola.

No lo comentas en tu mensaje pero imagino que estarás usando FloatToStr(now) para trabajar con las fechas en modo numérico, esto te da un número con 10 decimales que si lo multiplicas por 10000000000 te da un número entero con lo que podrás trabajar.

Espero que te sirva.

Saludos

[ecfisa]

Cuando muestro tiempo restante (durTotal -now) si la duracción total supera en unas 12 horas o un dia me la muestra mal.

Hola.

Para mostrar más de 24 horas sin que te un resultado erróneo:

Código Delphi [-]
uses DateUtils;
function MostrarHoras(const Ini,Fin: TDateTime): string;
var
  h,m,s: Word;
begin
  h:= 0;
  if DaysBetween(Ini,Fin) > 0 then
    h:= DaysBetween(Ini, Fin) * 24;
  h:= h + HourOf(Ini - Fin);
  m:= MinuteOf(Ini - Fin);
  s:= SecondOf(Ini - Fin);
  Result:= Format('%3d hr %3d min %3d seg',[h,m,s]);
end;

Ejemplo de llamada:

Código Delphi [-]
var
  d1,d2: TDateTime;
begin
  d1:= StrToDateTime('29/4/2011 09:03:01');
  d2:= StrToDateTime('04/5/2011 10:15:12');
  ShowMessage(MostrarHoras(d1,d2)); // resultado: 121 hr 12 min 11 seg
end;

Y en cuanto a obtener los valores para usar en un ProgressBar, newtron ya te ha dado la solución.

Saludos.

[alquimista]

Muchas gracias....

Voy a probar... Si... Me salian numeros flotantes

Estoy usando SpinEdits indicando Dias, Horas y minutos, para calcular la duración total

Código Delphi [-]
     DurTotal:=(SEDay.Value*3600*60+SEHour.Value*3600+SEMin.Value*60)*1000;

// esto lo uso para pasar a Time
       DurTotal:=Durtotal/ MSecsPerSec / SecsPerDay;

Hay alguna forma de manejarlo mejor. Esto me funciona pero me parece complicado.

Ya os comentare lo del porcentaje...

[alquimista]

No me funciona....
No se que estoy haciendo mal..

uso directamente fechas en Tdatetime. perdon!!!!! DurTotal es Extended;
No uso los dias en string directamente...
Uso dias, horas, minutos en Spinedits y los convierto a mano en tdatetime con la formula anterior. A lo mejor no lo hago bien??? Lo curioso es que me funciona bien al comparar.
Comienzo la captura InicioCap=hora actual) le añado la DurTotal(la que paso con los SpinEdits) y comparo Now>=DurTotal (esto dentro de un timer)

Código Delphi [-]
InicioCap:=Now();
 DurTotal:=InicioCap+DurTotal;
 ....      if (Now()>=DurTotal) then acabar

[[duilioisola]]

Lo mejor es que utilices las funciones que te da Delphi, siempre que puedas.
Si cambias de version de Delphi, es más seguro que puedas compilar sin problemas. También si quieres pasar el código a FreePascal / Lazarus por ejemplo.
Puede que cambie la representación interna de un TDateTime (parte entera días, parte decimal horas) a otra diferente. Si utilizas funciones, solo deberás reemplazar o reprogramar la función, si es que la nueva versión no lo ha hecho ya.

Mira estas dos de la Unit DateUtils:

Código Delphi [-]
function EncodeTime(Hour, Min, Sec, MSec: Word): TDateTime;
function EncodeDateTime(const AYear, AMonth, ADay, AHour, AMinute, ASecond, AMilliSecond: Word):TDateTime;

Deberás tirar los datos de los SpinEdit dentro de los parámetros correspondientes de la función y obtendrás un TDateTime.

[alquimista]

Estaba pensando en rediseñar y usar las funciones de delphi..

Uso Delphi 2007 por lo que no tendre problemas...
Lo que pasa que hay tantas funciones que tiene para fechas que no sabia por donde empezar...

[ecfisa]

Hola alquimista.

Usar las funciones de Delphi, como ya te lo comentó duilioisola, es más simple y seguro.

Pero veo que en este cálculo tenés un error:

Código Delphi [-]
DurTotal:=(SEDay.Value*3600*60+SEHour.Value*3600+SEMin.Value*60)*1000;

No es: SEDay.Value * 3600 * 60, ya que el día tiene 24 horas y no 60. Lo que correspondería es: SEDay.Value * 24 * 3600.

Seguramente sea eso lo que te genere el error.

Saludos.

[alquimista]

He modificado el error de las 24 horas.. y he puesto 1 dia y 1 minuto y al pasar el minuto me muestra que quedan las 24 horas restantes. Parece que esto va bien...
aunque antes ya habia desactivado el spinedit de los dias... y lo del porcentaje no me iba bien...


EStoy probando lo del encodedatetime...
Vamos estoy reescribiendo con otras variables para ir comparando los valores antiguos y los nuevos...

[alquimista]

Bueno...
vale...
Me falta lo del porcentaje para una barra de progreso....
¿Que hago ahora?.. paso el str a numero otra vez y lo multiplico por 10000000000 ?? No me queda muy claro...

Ya he trabajado con las funciones de delphi y he rehecho las rutinas
Lo he solucionado de esta forma..

Por si a alguien le sirve....

Código Delphi [-]

function MostrarRestante(const Ini,Fin: TDateTime): string;
var
  d,h,m,s: Word;
begin
  d:=0;
  if DaysBetween(Ini,Fin) > 0 then
    d:= DaysBetween(Ini, Fin);
  h:= HourOf(Ini - Fin);
  m:= MinuteOf(Ini - Fin);
  s:= SecondOf(Ini - Fin);
  Result:= Format('%2d dia(s) %.02d:%.02d:%.02d',[d,h,m,s]);
end;
.......
var AinicioCap, AFinCap:Tdatetime;
.......
        AInicioCap:=Now;
        AfinCap:=IncDay(AinicioCap, trunc(SEDay.Value)); // Sumo dias a la fecha actual
        AfinCap:=IncHour(AfinCap, trunc(SEHour.Value)); //Sumo horas
        AfinCap:=IncMinute(AfinCap, trunc(SEMin.Value)); //Sumo minutos

        Edit1.Text:=Datetimetostr(AfinCap);

.......

        Edit2.Text:=Mostrarrestante(Now,AfinCap);
..... 
        str:=Floattostr(AFinCap);   // ej.- 46789,2345677883

......
        if Now>=AfinCap then termina

Si me podeis poner algún ejemplo de lo del porcentaje..

Gracias por la ayuda...

[ecfisa]

Hola.

Poné en un form un TTimer un TProgressBar y un TLabel y probá si este código hace más o menos lo que buscas:

Código Delphi [-]
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, ComCtrls;

type
  TForm1 = class(TForm)
    Timer1: TTimer;
    ProgressBar1: TProgressBar;
    Label1: TLabel;
    procedure Timer1Timer(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    FLapsoIni: Int64;
    FDTIni: TDateTime;
  public
  end;

var
  Form1: TForm1;

implementation {$R *.dfm}

uses DateUtils;

function ObtenerLapso(const Ini,Fin: TDateTime): Int64;
var
  h,m,s: Word;
begin
  h:= 0;
  if DaysBetween(Ini,Fin) > 0 then
    h:= DaysBetween(Ini, Fin) * 24;
  h:= h + HourOf(Ini - Fin);
  m:= MinuteOf(Ini - Fin);
  s:= SecondOf(Ini - Fin);
  Result:= h*3600+m*60+s;
end;

procedure TForm1.FormShow(Sender: TObject);
begin
{ Aca tendrías que asignar a FDTIni los valores de los SpinEdits,
  para simplificar el ejemplo lo asigno directamente sumando 2 minutos }
  FDTIni:= IncMinute(Now, 2); //  sumo 2 minutos
  FLapsoIni:= ObtenerLapso(Now, FDTIni); // Obtener lapso inicial
  Timer1.Enabled:= False;
  Timer1.Interval:= 1000;
  ProgressBar1.Max:= FLapsoIni;
  ProgressBar1.Step:= 1;
  Timer1.Enabled:= True;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
var
  LapsoAct: Int64;
begin
  LapsoAct:= ObtenerLapso(Now, FDTIni); // Obtener estado actual
  ProgressBar1.StepIt;
  Label1.Caption:= Format('%3.0f %%',[100-LapsoAct/FLapsoIni*100]);
  if  LapsoAct <= 0 then
  begin
    Timer1.Enabled:= False;
    MessageBeep(MB_ICONEXCLAMATION);
  end;
end;

end.

Como verás las pruebas las hice con minutos, si usaba días u horas estaría más seguro, pero la respuesta hubiera llegado un poco tarde...

Saludos.

[[duilioisola]]

Regla de tres simple:

Tiempo_Inicial = Hora de Comienzo
Tiempo_Final = Hora de Finalizacion
Total_Tiempo = Tiempo_Final - Tiempo_Inicial
Tiempo_Transcurrido = Now - Tiempo_Inicial

Total_Tiempo -------- 100%
Tiempo_Transcurrido --- x%

x = (Tiempo_Transcurrido x 100%) / Total_Tiempo

[alquimista]

El problema es que al ver el pedazo de numero que me daba no sabia como manejarlo.
La idea de obtenerlo en minutos reduce el numero y simplifica..

Gracias, a probar y ya os comento..

Un saludo a todos

[alquimista]

Gracias ecfisa, tu solución me ha funcionado al 100% de progreso.

Lo mejor de todo es que las modificaciones que me habeis comentado me han hecho comprender mejor lo de las fechas y es mas !!! lo he entendido!!!


Un saludo a todos. Sois los mejores.