Codigo Hexadecimal

[LoPiTaL]

Diría que eso es porque te pasas del tamaño del archivo al leerlo de 4 en 4 bytes (el tamaño del archivo no es múltiplo de 4, por lo que en la últia lectura falla). Lee en lugar de 4 en 4, de 1 en 1 y así no fallará.

Un saludo,
LoPiTaL

[kdemia]

perfecto funciono perfectamente... muchas gracias LoPiTal te lo agradezco. sos un groso

[elmago00]

amigos, intente esto, pero la verdad no va siempre da read error. y lo cambie a 1, pero nada;

Código Delphi [-]
var
  LStream: TMemoryStream;
  miVar: longWord;
  miStr: string;
  todasMisStrings: TStringList;
  I: integer;
begin

  if not OpenDialog1.Execute then Exit;  //Supongo que od es un Diálogo para seleccionar un archivo....

  LStream:=TMemoryStream.Create;
  todasMisStrings:=TStringList.Create;
  try
    LStream.LoadFromFile(OpenDialog1.FileName);
    LStream.Seek(0,soBeginning);
    miStr:='';  //Inicializamos la str....
    I:=0;
    while (I < LStream.Size - 1) do
      LStream.ReadBuffer(miVar, sizeOf(longWord));
      miStr:=miStr+IntToHex(miVar,8);  //8 es el nº de caracrteres hexadecimales que deseas para la conversión - 4 bytes= 8 caracteres hex.
      miStr:=miStr+' ';  //Añadimos el espacio que deseabas
      if (I mod 32)=0 then begin  //Cada 32 bytes, añadimos una nueva línea
        todasMisStrings.Add(miStr);
        miStr:='';  //Volvemos a empezar para la siguiente línea.
      end;
      inc(I,1);  //Incrementamos en 4 el valor de I


  finally

     LStream.Free;
     todasMisStrings.Free;
  end;

intente este metodo, pues lo que quiero es leer el archivo en hexadecimal y luego modificar un cadena de ese archivo.

[ecfisa]

Hola elmago00.

Acabo de probar el código de LoPiTaL y funciona perfectamente, sólo faltaba un begín del while (omisiones que suelen pasar cuando publicamos algún código).

La prueba:

Código Delphi [-]
{
 Agregué el parámetro "od" por que ConvertBinFileToTxtFile no es método del Form,
 y el parámetro "Destino" para darle mas versatilidad al procedimiento  
}
procedure ConvertBinFileToTxtFile(od: TOpenDialog; const Destino: TFileName);
var
  LStream: TMemoryStream;
  miVar: longWord;
  miStr: string;
  todasMisStrings: TStringList;
  I: integer;
begin
  if not od.Execute then Exit;

  LStream:= TMemoryStream.Create;
  todasMisStrings:=TStringList.Create;
  try
    LStream.LoadFromFile(od.FileName); //Supongo que od es un Diálogo para seleccionar un archivo....
    LStream.Seek(0,soBeginning);
    miStr:='';
    I:=0;
    while (I < LStream.Size-1) do
    begin
      LStream.ReadBuffer(miVar, sizeOf(longWord));
      //8 es el nº de caracrteres hexadecimales que deseas para la conversión - 4 bytes= 8 caracteres hex.
      miStr:=miStr+IntToHex(miVar,8);  
      miStr:=miStr+' ';  //Añadimos el espacio que deseabas
      if (I mod 32) = 0 then //Cada 32 bytes, añadimos una nueva línea
      begin
        todasMisStrings.Add(miStr);
        miStr:='';  //Volvemos a empezar para la siguiente línea.
      end;
      inc(I,4);  //Incrementamos en 4 el valor de I
    end;
    todasMisStrings.SaveToFile(Destino);
  finally
     LStream.Free;
     todasMisStrings.Free;
  end;
end;

{ Llamada de ejemplo }
procedure TForm1.Button1Click(Sender: TObject);
begin
  ConvertBinFileToTxtFile(OpenDialog1, 'C:\miArchivoDestino.txt');
end;

Saludos

[elmago00]

gracias ecfisa, por ayudarme, funciona bien pero mi intecion es que el archivo se vea asi.
esto.jpg

no se si en la imagen se ve bien, pero necesito la dirección seguido del hexadecimal.
pues lo que necesito es ubicar una dirección del hexaceimal y modificara.

sera posible esto? perdonen si molesto demasiado.

saludos

[ecfisa]

Hola elmago00.

No alcanzo a distinguir bién la imágen pero te hice un ejemplo de visor hexadecimal:

Código Delphi [-]
implementation 
 
procedure DumpFile(aFileName:TFileName; SG: TStringGrid; const BPF: Word);
var
  c, i, r: integer;
  ascii: string;
  aux: Byte;
begin
  with TMemoryStream.Create do
  try
    LoadFromFile(aFileName);
    // configurar StringGrid
    SG.Options:= SG.Options - [goVertLine] - [goHorzLine];
    SG.Font.Name:= 'Courrier';
    SG.Font.Size:= 10;
    SG.ColWidths[0]:= 80;
    SG.Cells[0,0]:= 'Offset(h)';
    SG.ColCount:= BPF+2;
    SG.ColWidths[SG.ColCount-1]:= SG.Canvas.TextWidth('X') * BPF;
    SG.Cells[SG.ColCount-1,0]:= 'ASCII';
    for i:= 0 to BPF-1 do
    begin
      SG.ColWidths[i+1]:= 30;
      SG.Cells[i+1,0]:= IntToHex(i,2);
    end;
    SG.RowCount:= Size div BPF;
    // cargar en StringGrid
    Seek(0, soBeginning);
    c:= 0;
    r:= SG.FixedRows;
    while c < Size do
    begin
      SG.Cells[0, r]:= Format('%s',[IntToHex(c, 8)]);
      ascii:= EmptyStr;
      i:= 0;
      while (i < BPF)and(i+c < Size) do
      begin
        Read(aux, SizeOf(Byte));
        SG.Cells[i+1,r]:= IntToHex(aux,2);
        if aux = 0 then aux := 46;
        ascii:= ascii + Chr(aux);
        Inc(i);
      end;
      SG.Cells[SG.ColCount-1,r]:= Format('%s',[ascii]);
      Inc(c, BPF);
      Inc(r);
    end;
  finally
    Free;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  ComboBox1.Items.CommaText:= '8,10,16,24,32,48,64,128,255';
  ComboBox1.ItemIndex:= 2;
end;

procedure TForm1.btnFileClick(Sender: TObject);
begin
  with OpenDialog1 do
  begin
    Filter:= '*.*';
    if Execute then
    begin
      Caption:= FileName;
      DumpFile(FileName, StringGrid1,
        StrToInt(ComboBox1.Items[ComboBox1.ItemIndex]) );
    end;
  end;
end;

salida:


Mas si tu inquietud es a fines prácticos, ya existen excelentes editores hexadecimal freeware como: HxD - Freeware Hex Editor and Disk Editor.

Saludos

[elmago00]

esto es justamente lo que buscaba pero en lugar de verlo en stringGrid era guardarlo en .txt
pero de aquí sacare como hacerlo, muchas gracias ecfisa