Errror al copiar memo.

[tarco35]

Hola, estoy copiando un campo memo de una tabla a otra de la siguiente forma:

Código Delphi [-]
// en su sitio correspondiente estan definidas las variables
  var
  Stream1: TBlobStream;
  Stream2: TStream;

//ya en el codigo de programa

  Stream1 := TBlobStream.Create(FormTraspasoDatos.TablaPacientesOhmedynMEMO1, bmRead);
  try
    ModuloDatos.TablaPacientes.Edit;
    Stream2 := ModuloDatos.TablaPacientes.CreateBlobStream(ModuloDatos.TablaPacientes.FieldByName('MOTIVO'),bmReadW  rite);
    try
      Stream2.CopyFrom(Stream1,Stream1.Size);
      ModuloDatos.TablaPacientes.Post;
      ModuloDatos.TablaPacientes.FlushBuffers;
    finally
      //Stream2.Free;
    end;
  finally
    Stream1.Free;
  end;

está copiado de la ayuda de delphi 6 y al ejecutar la linea Stream2.Free me lanza el error:
EDBEngineError: BLOLB NOT OPENED

Y supongo que necesito liberarlos porque tengo que meterlo en un bucle para copia el contenido del memo de una tabla a otra.
Gracias.

[ecfisa]

Hola tarco35.

Código Delphi [-]
procedure CopyBlobFields(SourceDataSet, TargetDataSet: TDataSet;
  const SourceFieldName, TargetFieldName: string);
var
  Stream: TStream;
begin
  Stream := TMemoryStream.Create;
  try
    TBlobField(SourceDataSet.FieldByName(SourceFieldName)).SaveToStream(Stream);
    Stream.Seek(0, soFromBeginning);
    TargetDataSet.Edit;
    TBlobField(TargetDataSet.FieldByName(TargetFieldName)).LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
end;

Ejemplo de uso:

Código Delphi [-]
begin
  CopyBlobFields(DataSet1, DataSet2, 'BLOB_FIELD', 'BLOB_FIELD');
  ...

Saludos

[tarco35]

Muchisimas gracias, funciona perfecto.... muy amable y gracias por tu tiempo.