Cambio al hacer foco con el mouse

c748a · #1 12-12-2003

Hola foro:
Estoy intentando que un Tlabel cambie su color al hacer foco con el mouse sobre el compomente y al perderlo que vuelva a su color anterior. En la ayuda hay un ejemplo pero no me da resultado. El método Focused pareciera que es el correcto pero no le encuentro la vuelta.

Osorio · #2 13-12-2003

Los eventos MouseEnter y MouseLeave, te envio un ejemplo.

procedure TForm1.Label1MouseEnter(Sender: TObject);
begin
TLabel(sender).Color:= clBlue;
end;

procedure TForm1.Label1MouseLeave(Sender: TObject);
begin
TLabel(sender).Color:= clBtnFace;
end;

Suerte...

Ruben_Cu · #3 14-12-2003

Cita:

c748a comentó:
El método Focused pareciera que es el correcto pero no le encuentro la vuelta.

Es que el método Focused no lo tiene el control TLabel, a sea que no es posible usarlo en este caso (al menos hasta delphi 6).
Aunque no recuerdo bien creo que algunos eventos del ratón no están disponibles en versiones anteriores a la 6.
Además si solo se trata de una etiqueta no es necesario el uso del typecast, puede ser de manera directa: label1.color
Espero que mis comentarios aclaren algo.
Saludos

madriles · #4 14-12-2003

hola
prueba con esto, a ver si es lo que quieres

procedure TForm1.Label1MouseDown(Sender: TObject; Button: TMouseButton;
Shift: TShiftState; X, Y: Integer);
begin
TLabel(sender).Color:= clBlue;
end;

procedure TForm1.Label1MouseUp(Sender: TObject; Button: TMouseButton;
Shift: TShiftState; X, Y: Integer);
begin
TLabel(sender).Color:= clBtnFace;
end;

marcoszorrilla · #5 14-12-2003

Lo que apunta madriles, no funcionará porque para ello se debe de pulsar el botón del ratón y soltarlo y según creo la pregunta versa sobre el cambio de color de una etiqueta al pasar sobre ella con el ratón, el código que propongo no me gusta del todo, pero es que el Tlabel, no dispone de eventos para cuando se abandona su superficie con el ratón:

En resumen es una simpleza con evento OnMouseMove del Tlabel aprovechamos para cambiar el color de la etiqueta y con el mismo evento del formulario hacemos lo contrario.

Código:

procedure TForm1.Label1MouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
label1.Font.Color:=ClBlue;
end;

procedure TForm1.FormMouseMove(Sender: TObject; Shift: TShiftState; X,
  Y: Integer);
begin
label1.font.color:=clRed;
end;

Un Saludo.

Ruben_Cu · #6 14-12-2003

Hola Marcos, por eso comentaba lo de los eventos disponibles para el TLabel porque en la versión 6 si existen los que refiere Osorio en su propuesta, clara si c748a tiene una versión anterior creo que esta obligado a usar tu solución.
Saludos

c748a · #7 15-12-2003

Gracias a todos por las contestaciones.
En algunas ocasiones la solución de Marcos Zorrilla me genera un problemita. Este es que si se pasa rápidamente del Tlabel a otro componente pareciera que no se genera el evento onmousemove del form. Esto no sucede muy a menudo pero quería destacarlo. Con respecto a los eventos mencionados no los tengo porque estoy utilizando una version bastante viejita: Delphi 3
Un saludo

sakuragi · #8 06-08-2005

hola que tal

yo tengo el mismo problema

pero lo quiero haser en un DBgrid y en un cxgrid

ya que estos componetes no tienes los mismos eventos que el lable

me gustaria saber como haserle para que al pasar el mouse por ensima de una fila este me la ponga de color diferente

ya eh buscado en el foro pero no e contrado nada de con dbgrid o cxgrid que al pasar el mouse por ensima ponga de otro color ya l quitarlo se regrese a su color anteriro pero por filas

de hante mano gracias

saludos

German · #9 06-08-2005

Cita:

Empezado por c748a

Gracias a todos por las contestaciones.
En algunas ocasiones la solución de Marcos Zorrilla me genera un problemita. Este es que si se pasa rápidamente del Tlabel a otro componente pareciera que no se genera el evento onmousemove del form. Esto no sucede muy a menudo pero quería destacarlo. Con respecto a los eventos mencionados no los tengo porque estoy utilizando una version bastante viejita: Delphi 3
Un saludo

Desconozco si las rxLib funcionan en Delphi 3, pero estas incluyen una trxLabel, descendiente de una tLabel, con dos eventos que son los que necesitas:

onMouseEnter -> Al entrar el raton
onMouseLeave -> Al salir el raton

Salu2.

madriles · #10 06-08-2005

por si puede servir, en trucomania teneis el truco 395 para crear evento OnMouseEnter OnMouseLeave de un componente, con un ejemplo en un TImage
espero que os sirva
un saludo

sakuragi · #11 06-08-2005

este es el ejemplo que dice "madriles"

Código Delphi [-] unit Image2;

 interface

 uses
   Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
   ExtCtrls;

 type
   TEntrarEvent=procedure(Sender:TObject) of object;
   TSalirEvent =procedure(Sender:TObject) of object;
   TImage2 = class(TImage)
   private
     { Private declarations }
     FOnEnter:TEntrarEvent;
     FOnExit :TSalirEvent;
     procedure CMMouseEnter(var msg:TMessage); message CM_MOUSEENTER;
     procedure CMMouseLeave(var msg: TMessage); message CM_MOUSELEAVE;
   protected
     { Protected declarations }
   public
     { Public declarations }
   published
     { Published declarations }
     property OnMouseEnter: TEntrarEvent read FOnEnter write FOnEnter;
     property OnMouseLeave: TSalirEvent read FOnExit write FOnExit;

   end;

 procedure Register;

 implementation

 procedure TImage2.CMMouseEnter(var msg:TMessage);
 begin
     inherited;
     {Cuando el raton entra...}
     If Assigned(FOnEnter) then FOnEnter(Self);
 end;

 procedure TImage2.CMMouseLeave(var msg: TMessage);
 begin
     inherited;
     {Cuando el raton sale}
     If Assigned(FOnExit) then FOnExit(self);
 end;

 procedure Register;
 begin
   RegisterComponents('TMania', [TImage2]);
 end;

 end.

saludos

sakuragi · #12 06-08-2005

bueno el codigo que puse anterior mente

no me sirvio para un DBGrid ni apra un cxGrid

ni si quiera entro al onMouseEnter ni leave

ni ha los procedures entro

saludos

German · #13 07-08-2005

Cita:

Empezado por sakuragi

bueno el codigo que puse anterior mente

no me sirvio para un DBGrid ni apra un cxGrid

ni si quiera entro al onMouseEnter ni leave

ni ha los procedures entro

saludos

El código anterior es para crear un componente tLabel con los eventos onMouseEnter y onMouseLeave. Si quieres, tambien puedes hacer lo mismo con un componente dbGrid, creando uno nuevo que incluya esos eventos:

Código Delphi [-]unit dbGrid2;
 
interface 
 
uses 
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls, DbGrids;
 
type 
  TEntrarEvent=procedure(Sender:TObject) of object;
  TSalirEvent =procedure(Sender:TObject) of object;
  tDbGrid2 = class(tDbGrid)
  private
    { Private declarations }
    FOnEnter:TEntrarEvent;
    FOnExit :TSalirEvent;
    procedure CMMouseEnter(var msg:TMessage); message CM_MOUSEENTER;
    procedure CMMouseLeave(var msg: TMessage); message CM_MOUSELEAVE;
  protected
    { Protected declarations }
  public
    { Public declarations }
  published
    { Published declarations }
    property OnMouseEnter: TEntrarEvent read FOnEnter write FOnEnter;
    property OnMouseLeave: TSalirEvent read FOnExit write FOnExit;
 
  end; 
 
procedure Register;
 
implementation 
 
procedure tDbGrid2.CMMouseEnter(var msg:TMessage);
begin 
    inherited;
    {Cuando el raton entra...}
    if Assigned(FOnEnter) then FOnEnter(Self);
end; 
 
procedure tDbGrid2.CMMouseLeave(var msg: TMessage);
begin 
    inherited;
    {Cuando el raton sale}
    if Assigned(FOnExit) then FOnExit(self);
end; 
 
procedure Register;
begin 
  RegisterComponents('Personal', [tDbGrid2]);
end; 
 
end.

Doy por hecho que sabes crear un nuevo componente con este código. Si no es así, ya diras.

Salu2.

sakuragi · #14 08-08-2005

German gracias por responder

pero de hecho ya havia hecho eso ya lo havi aintentado como me dices erpo si correo todo pero no pasa nada, por eso volvi a preguntar

declare todo asi como lo describes, pero simple mente no pasa nada la pasa el cursor por arriva del DBGrid, mejor dicho no entra a los procedures

Código Delphi [-] procedure tDbGrid2.CMMouseEnter(var msg:TMessage);
begin 
    inherited;
    {Cuando el raton entra...}
    if Assigned(FOnEnter) then FOnEnter(Self);
end; 
 
procedure tDbGrid2.CMMouseLeave(var msg: TMessage);
begin 
    inherited;
    {Cuando el raton sale}
    if Assigned(FOnExit) then FOnExit(self);
end;

le puse showmessage haver si entraba y el resultado fue negativo

ya lo has probado? o alguien?

de hante mano gracias

German · #15 08-08-2005

Yo añadí el nuevo componente (tdbGrid2) a Delphi 7 antes de poner el código en el foro, y funcionaba perfectamente.

Creo que tu error está a la hora de añadir el componente, pues haces referencia a los procedimientos del .pas PARA CREAR EL OBJETO, y no a los EVENTOS DEL OBJETO YA CREADO.

El código escrito es UNICAMENTE PARA CREAR EL OBJETO EN LA PALETA DE DELPHI. Una vez creado, tendras una nueva pestaña llamada "Personal", y dentro de ella el componente dbGrid2. Es ESE COMPONENTE el que debes utilizar, y que te permitirá controlar cuando entra y sale el raton.