Oscurecer y aclarecer pantalla

[turminator]

llevo buscando por el foro y distintas webs, como podria hacer para que la pantalla de mi programa se fuera oscureciendo lentamente y llegado un punto medio, volver a aclarecerse. No sé si es que tenia que buscar por algun nombre distinto o alguna otra cosa. pero no he encontrado nada al respeto.

Se agradeceran las ayudas.

Saludos y gracias de antemano.

[dec]

Hola,

En este Hilo se trató algo similar a lo que dices, cuando no lo mismo. A ver si puede servirte de algo.

[turminator]

Gracias por la info. Me lo he estado mirando todo y aunque trata el tema no me acaba de ir bien. Pero gracias. Lo que encontré es un componente que se llama Proeffectimage y tiene una opción que se llama Darkness y es justo lo que necesito.

Lo que me sucede es que queria usar el effecto Darkness sobre un archivo jpeg (en vez de bmp.). Y cuando sustituyo los '1.bmp' por '2.jpeg' me da el siguiente error: Unknown picture extension JPEG

Cual es la solución al problema? Espero puedan ayudarme

El codigo del ejemplo es:

Código Delphi [-]
unit Main;
interface
uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls, ProEffectImage, StdCtrls, ComCtrls;
type
  TForm1 = class(TForm)
    ProEffectImage: TProEffectImage;
    Bevel1: TBevel;
    EffectsList: TListBox;
    TrackBar: TTrackBar;
    Button_APPLY: TButton;
    AutoMatic: TCheckBox;
    procedure FormCreate(Sender: TObject);
    procedure EffectsListClick(Sender: TObject);
    procedure Button_APPLYClick(Sender: TObject);
    procedure TrackBarChange(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
var
  Form1: TForm1;
implementation
{$R *.DFM}
{ FORM CREATION }
//------------------------------------------------------------------------------
procedure TForm1.FormCreate(Sender: TObject);
begin
 ProEffectImage.Picture.LoadFromFile ('2.JPEG');
end;
//------------------------------------------------------------------------------
 
{ EFFECT LISTBOX ACTIONS }
//------------------------------------------------------------------------------
procedure TForm1.EffectsListClick(Sender: TObject);
begin
 {Start}
 ProEffectImage.Picture.LoadFromFile ('2.JPEG');
 Button_APPLY.Enabled := True;
 TrackBar.Enabled     := True;
 TrackBar.Position    := 1;
end;
//------------------------------------------------------------------------------
 
{ APPLY BUTTON ACTIONS }
//------------------------------------------------------------------------------
procedure TForm1.Button_APPLYClick(Sender: TObject);
Var i  : Integer; {For Loop}
begin
  Screen.Cursor := crHourGlass;
  ProEffectImage.Picture.LoadFromFile ('2.JPEG');
  Button_APPLY.Enabled := False;
  { E F F E C T S }
     Case EffectsList.ItemIndex of
           0: ProEffectImage.Effect_GaussianBlur   (TrackBar.Position);
           1: ProEffectImage.Effect_SplitBlur      (TrackBar.Position);
           2: ProEffectImage.Effect_AddColorNoise  (TrackBar.Position * 3);
           3: ProEffectImage.Effect_AddMonoNoise   (TrackBar.Position * 3);
           4: For i:=1 to TrackBar.Position do
              ProEffectImage.Effect_AntiAlias;
           5: ProEffectImage.Effect_Contrast       (TrackBar.Position * 3);
           6: ProEffectImage.Effect_FishEye        (TrackBar.Position div 10+1);
           7: ProEffectImage.Effect_Lightness      (TrackBar.Position * 2);
           8: ProEffectImage.Effect_Darkness       (TrackBar.Position * 2);
           9: ProEffectImage.Effect_Saturation     (255-((TrackBar.Position * 255) div 100));
          10: ProEffectImage.Effect_Mosaic         (TrackBar.Position div 2);
          11: ProEffectImage.Effect_Twist          (200-(TrackBar.Position * 2)+1);
          12: ProEffectImage.Effect_Splitlight     (TrackBar.Position div 20);
          13: ProEffectImage.Effect_Tile           (TrackBar.Position div 10);
          14: ProEffectImage.Effect_SpotLight      (TrackBar.Position ,
                                                    Rect (TrackBar.Position ,
                                                    TrackBar.Position ,
                                                    TrackBar.Position +TrackBar.Position*2,
                                                    TrackBar.Position +TrackBar.Position*2));
          15: ProEffectImage.Effect_Trace          (TrackBar.Position div 10);
          16: For i:=1 to TrackBar.Position do
              ProEffectImage.Effect_Emboss;
          17: ProEffectImage.Effect_Solorize       (255-((TrackBar.Position * 255) div 100));
          18: ProEffectImage.Effect_Posterize      (((TrackBar.Position * 255) div 100)+1);
          19: ProEffectImage.Effect_Grayscale;
          20: ProEffectImage.Effect_Invert;
     end;{Case}

  Screen.Cursor := crDefault;
end;
//------------------------------------------------------------------------------
 
procedure TForm1.TrackBarChange(Sender: TObject);
begin
 If Not Button_APPLY.Enabled then Button_APPLY.Enabled := True;
 if AutoMatic.Checked        then Button_APPLY.Click;
end;

end.

[Sick boy]

Sin tener ni idea del componente que quieres usar, se me ocurre que puedes probar a cambiar la extension del archivo de 2.jpeg a 2.jpg

Es por si es un problema de la extension, aunque no creo....

Sino, solo te queda convertir el jpeg a bmp antes de asignarlo a tu componente.

[turminator]

Lo que me comentas tampoco me va. Investigando más, he descubierto que el ejemplo enlaza a otro archivo: ProEffectImage.pas En este archivo sale el codigo que se usa para los distintos efectos que hace el ejemplo y allí está el efecto Darkness con su codigo. Supongo que el problema esta en las primeras lineas del codigo, porque todas las demás son para hacer cada efecto.

unit ProEffectImage;
interface
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
ExtCtrls,Math;
type
TProEffectImage = class(TImage)
private
{ Private declarations }
protected
{ Protected declarations }
public
{ Public declarations }
published
Procedure Effect_Invert;
Procedure Effect_AddColorNoise (Amount:Integer);
Procedure Effect_AddMonoNoise (Amount:Integer);
Procedure Effect_AntiAlias;
Procedure Effect_Contrast (Amount:Integer);
Procedure Effect_FishEye (Amount:Integer);
Procedure Effect_GrayScale;
Procedure Effect_Lightness (Amount:Integer);
Procedure Effect_Darkness (Amount:Integer);
Procedure Effect_Saturation (Amount:Integer);
Procedure Effect_SplitBlur (Amount:Integer);
Procedure Effect_GaussianBlur (Amount:Integer);
Procedure Effect_Mosaic (Size:Integer);
Procedure Effect_Twist (Amount:Integer);
procedure Effect_Splitlight (Amount:integer);
Procedure Effect_Tile (Amount: integer);
Procedure Effect_SpotLight (Amount: integer; Spot: TRect);
Procedure Effect_Trace (Amount: integer);
Procedure Effect_Emboss;
Procedure Effect_Solorize (Amount: integer);
Procedure Effect_Posterize (Amount: integer);

{ Published declarations }
end;
procedure Register;
implementation
{$R DATA.RES}
procedure Register;
begin
RegisterComponents('Samples', [TProEffectImage]);
end;

[...]

procedure Darkness(var src: tbitmap; Amount: integer);
var
p0bytearray;
r,g,b,x,y: Integer;
begin
src.pixelformat:=pf24bit;
for y:=0 to src.Height-1 do begin
p0:=src.scanline[y];
for x:=0 to src.Width-1 do
begin
r:=p0[x*3];
g:=p0[x*3+1];
b:=p0[x*3+2];
p0[x*3]:=IntToByte(r-((r)*Amount)div 255);
p0[x*3+1]:=IntToByte(g-((g)*Amount)div 255);
p0[x*3+2]:=IntToByte(b-((b)*Amount)div 255);
end;
end;
end;

[...]

//----------------------
//-------------------------
//----------------------

Procedure TProEffectImage.Effect_Darkness (Amount:Integer);
Var BB:TBitmap;
Begin
BB := TBitmap.Create;
BB.PixelFormat := pf24bit;
BB.Assign (Picture.Bitmap);
Darkness (BB,Amount);
Picture.Bitmap.Assign (BB);
BB.Free;
end;

Que deberia de cambiar para que me aceptara jpeg?

Gracias y siento ser tan pesado.

[Sick boy]

Primero, usar las etiquetas para codigo delphi. Si te fijas, el moderador ya te edito el primer mensaje.

Sino, solo te queda convertir el jpeg a bmp antes de asignarlo a tu componente.

Esto no te va?? por que??

El procedure Darkness(var src: tbitmap; Amount: integer); recibe un Tbitmap, asi que si le envias un bitmap funcionará sin problemas.

Que te acepte jpg me parece que va a ser imposible. Hay que trabajar un poco más, y convertir el jpg a bmp ANTES de asignarlo a tu componente.

Busca por el foro pasar de bmp a jpg, veras como encuentras lo que necesitas.

[turminator]

Okk. Siento lo de las etiquetas no sabia como se hacia.


Código Delphi [-]Prueba



Gracias por la información. Ahora veré como pasar de bmp a jpeg. gracias

[[seoane]]

Bien, lo que quieres es que una imagen contenida en un TImage, por ejemplo, se vaya oscureciendo. Eso es sencillo, aqui te dejo una funcion que oscurece la imagen de un TImage, el parametro brillo indica cuanto se debe de oscurecer la imagen: 256 para no oscurecer nada y 0 para el negro.

Código Delphi [-]
type
  Triple = array[1..3]of Byte;

// Realiza la operacion (b * x) / 256
function Multiplicar(b: Byte; x: Integer): byte;
begin
  x:= (x * b);
  x:= x shr 8;
  if x > 255 then Result:= 255
    else Result:= x;
end;

procedure OscurecerTImage(Imagen: TImage; Brillo: Integer);
var
  Bitmap: TBitmap;
  P: ^Triple;
  i, j: Integer;
begin
  // Si no es un bitmap, lo convertimos en un bitmap
  if not (Imagen.Picture.Graphic is TBitmap) then
  begin
    Bitmap:= TBitmap.Create;
    try
      Bitmap.Assign(Imagen.Picture.Graphic);
      Imagen.Picture.Assign(Bitmap);
    finally
      Bitmap.Free;
    end;
  end;
  Imagen.Picture.Bitmap.PixelFormat:= pf24bit;
  for j:= 0 to Imagen.Picture.Bitmap.Height - 1 do
  begin
    P:= Imagen.Picture.Bitmap.ScanLine[j];
    for i:= 0 to Imagen.Picture.Bitmap.Width - 1 do
    begin
      P^[1]:= Multiplicar(P^[1],Brillo);
      P^[2]:= Multiplicar(P^[2],Brillo);
      P^[3]:= Multiplicar(P^[3],Brillo);
      inc(P);
    end;
  end;
  Imagen.Refresh;
end;

Si te fijas al principio de la funcion compruebo si la imagen que tiene cargada el TImage es un Bitmap y si no lo es convierto la imagen, para poder trabajar con ella. Esto solo pasa la primera vez que se llama la funcion el resto de las veces ya es un bitmap

Ahora solo nos queda hacer la animacion para eso podemos usar por ejemplo un timer y oscurecer solo un poquito la animacion de cada vez, algo asi:

Código Delphi [-]
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  OscurecerTImage(Image1,250);
end;

Espero que te sirva, aunque si sigues queriendo utilizar ese componente que encontraste echale un vistazo a como paso un formato cualquiera a bitmap, es lo mismo para un JPEG.

[turminator]

Muchas gracias por la función que me pusistes. Ahora tendré k ver como integrar toda la función dentro de un proyecto nuevo y haber que tal me va.
Ahora empiezo a estudiar para la Selectividad así que supongo que hasta pasado el 25 de Junio no probaré de programar. De todos modos me da la sensación de que me va a ayudar.

Gracias seoane y Sick Boy y Dec.

PD: He encargado un libro de primeros pasos con Delphi.

[turminator]

Muchas gracias de nuevo Seoane de nuevo. Ahora ya he conseguido ver tu ejemplo y me va de MARAVILLA . Lo que he estado probando es de como puedo hacer ahora otro timer que permite aclarecer la imagen hasta su nivel normal. Es decir, primero se me oscurece hasta X y luego vuelve a aclarecerme a partir de X hasta su iluminación normal.

Saludos y muchas gracias.

[[seoane]]

En este truco explico como cambiar el color y el brillo de una imagen, la misma funcion nos sirve para aumentar y disminuir el brillo. Pero hay que tener en cuenta, que al aumentar el brillo en algunos puntos la imagen puede saturarse o al oscurecerse quedarse totalmente negra. Asi que si repetimos el proceso de oscurecer - aclarar varias veces la imagen puede terminar degradandose un poco. Podria resultarte mejor cargar el original en un bitmap y dibujarlo con distintos valores de brillo, pero ya depende de lo que quieras hacer tu.

[turminator]

Mi intención era oscurecer y aclarecerla una vez solamente. El truco que he probado tuyo, me sal el siguiente error cuando compilo: Expected ':'but'=' found.

Que he echo mal?

[[seoane]]

¿En que linea te da ese error? parece que falta un ';' en algun sitio. Se debio de perder al copiar y pegar

[turminator]

El error me lo da a esta linea 11:10

Triple = array[1..3]of Byte;

Pero no le veo nada raro.

Será que debo de meter algo primero al form?

Muchas gracias.

[[seoane]]

No deberia de dar ningun error. Lo estas colocando debajo de un Type ??? es decir, lo estas colocando asi:

Código Delphi [-]
type
  Triple = array[1..3]of Byte;

[turminator]

Si lo pongo así y todo el codigo restante debajo de implementation.

[[seoane]]

Me rindo, a mi me compila bien, tanto el ejemplo que te deje en este hilo, como el que esta en la seccion de trucos. Asi que no se donde puede estar el problema, revisa que copiaras todo tal cual debajo de implementation. Y si sigue sin compilarte, a lo mejor alguien acierta con lo que te esta pasando

[[kuan-yiu]]

Empezado por turminator

El error me lo da a esta linea 11:10

Triple = array[1..3]of Byte;

Pero no le veo nada raro.

Será que debo de meter algo primero al form?

Muchas gracias.

¿Que pone exactamente en la línea anterior?

[turminator]

Código Delphi [-]
unit Unit1;
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;
type
  TForm1 = class(TForm)
  Triple = array[1..3]of Byte;
  private
    { Private declarations }
  public
    { Public declarations }
  end;
var
  Form1: TForm1;
implementation
 // Realiza la operacion (b * x) / 256
function Multiplicar(b: Byte; x: Integer): byte;
begin
  x:= (x * b);
  x:= x shr 8;
  if x > 255 then Result:= 255
    else Result:= x;
end;
procedure OscurecerTImage(Imagen: TImage; Brillo: Integer);
var
  Bitmap: TBitmap;
  P: ^Triple;
  i, j: Integer;
begin
  // Si no es un bitmap, lo convertimos en un bitmap
  if not (Imagen.Picture.Graphic is TBitmap) then
  begin
    Bitmap:= TBitmap.Create;
    try
      Bitmap.Assign(Imagen.Picture.Graphic);
      Imagen.Picture.Assign(Bitmap);
    finally
      Bitmap.Free;
    end;
  end;
  Imagen.Picture.Bitmap.PixelFormat:= pf24bit;
  for j:= 0 to Imagen.Picture.Bitmap.Height - 1 do
  begin
    P:= Imagen.Picture.Bitmap.ScanLine[j];
    for i:= 0 to Imagen.Picture.Bitmap.Width - 1 do
    begin
      P^[1]:= Multiplicar(P^[1],Brillo);
      P^[2]:= Multiplicar(P^[2],Brillo);
      P^[3]:= Multiplicar(P^[3],Brillo);
      inc(P);
    end;
  end;
  Imagen.Refresh;
end;
{$R *.dfm}
end.

Eso es lo que he copiado. Cuando pongo el debugger me sale el mensage: Expected ':'but'=' found.

Tengo la version 7 de Delphi, por si influyese.

[[seoane]]

Ahora si:

Donde pones:

Código Delphi [-]
type
  TForm1 = class(TForm)
  Triple = array[1..3]of Byte;
  private

Deberias poner:

Código Delphi [-]
type
  Triple = array[1..3]of Byte;
  TForm1 = class(TForm)  
  private

Date cuenta de que private,public, etc ... forman parte de la declaracion de TForm1, no puedes declarar un tipo en el medio de la declaracion de una clase.