Automatizar la votación en un sistema de votaciones en línea

[imossa]

Efectivamente, entiendo tu aclaración de "legalidad"....
Bueno, sólo prentendo hacer... lo que tantas veces me han explicado: automatizar una tarea que ejecuto todos los dias.
Me imagino que para el registro de votos se tendrá encuenta la ip que envía el voto o similar para gestionar que no se pude votar más de una vez.... no se...
En cuanto al origen, bueno, el que pone el link en su página, me imagino que estará más preocupador por recoger votos que por saber si ha habido intervención humana en la recogida del voto. Son listas de popularidad nada más, con lo que cuantos más arriba aparezcas, más posibles usuarios se podrán conseguir.
Ya me contarás cuando si lo ves bien, o mal, y si se puede hacer algo.
Gracias.

[[seoane]]

Pues no me parece muy complicado, a simple vista el método de votación parece mas simple que el mecanismo de un chupete , habrá que ver como lo maneja internamente.

Supongo que ya has leído el hilo sobre Automatización web. Si lo has hecho y tienes claro como comunicarse con la pagina web lo demás no parece difícil.

Primero accederiamos a la pagina que contiene el boton y nos fijariamos en esta parte:

Código PHP:

<INPUT TYPE="HIDDEN" NAME="31" VALUE="60199"> 


Parece que "value" es un valor fijo, que seguramente identifica a quien se quiere votar, mientras que "name" tiene un valor variable. Pues bien solo tendríamos que obtener ese valor y simular un POST.

Como ya dije, a simple vista no parece que se implementen mas protecciones. Intentalo y nos cuentas ...

[dec]

Hola,

Yo me he quedado en "dónde" hacer el "POST", puesto que no he podido encontrar un "regvote.php válido"...

[[seoane]]

Empezado por dec

Yo me he quedado en "dónde" hacer el "POST", puesto que no he podido encontrar un "regvote.php válido"...

El truco amigo dec puede ser en el header referer de la petición, creo que este debe contener la dirección de la pagina donde se encuentra el botón.

[dec]

Hola,

Bueno. Yo he tratado de hacer un "post" al Script en cuestión... y obtengo el 404... Por otro lado he localizado un "regvote.php" otra URL de la misma Web (ahora no recuerdo el dominio), pero, sin resultados.... es decir, no funcionaba el "post", pero ya no sabe uno si porque no incluyó los parámetros adecuados, si porque no se trata del mismo "regvote.php"...

Empezado por Seoane

El truco amigo dec puede ser en el header referer de la petición, creo que este debe contener la dirección de la pagina donde se encuentra el botón.

Pues... chico, no sé, puede ser, sí. Por mi parte le dejo al compañero comprobarlo. ¡Yo ya le he votado hoy!

[[seoane]]

Esto es todo lo que voy a dedicar a este asunto, espero que te sirva. Yo no lo puedo comprobar porque ahora ya ni me deja entrar a la pagina de votación, me dice que ese servidor esta offline y que no puedo votar por el

Es una aplicación de consola.

Código Delphi [-]
program Voto;

{$APPTYPE CONSOLE}

uses
  Windows, SysUtils, WinInet, Classes;

function URLEncode(Str: string): string;
var
  i: integer;
begin
  Result:= '';
  for i:= 1 to Length(Str) do
    if Str[i] in ['A'..'Z','a'..'z','0'..'9','-','_','.'] then
      Result:= Result + Str[ i ]
    else
      Result:= Result + '%' + IntToHex(Ord(Str[ i ]),2);
end;

function SendRequest(Server, Uri: string; Port: Word; Params: TStringList;
  Response: TStream): Boolean;
var
  hNet: HINTERNET;
  hCon: HINTERNET;
  hReq: HINTERNET;
  Context: DWORD;
  Buffer: array[0..10240] of Char;
  BytesRead: DWORD;
  i: integer;
  Str: String;
  Success: Boolean;
begin
  Context:= 0;
  Result := FALSE;
  hNet := InternetOpen('Agente', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  if (hNet <> nil) then
  begin
    hCon:= InternetConnect(hNet,PChar(Server),Port,nil,nil,
      INTERNET_SERVICE_HTTP,0,Context);
    if (hCon <> nil) then
    begin
      if Params <> nil then
        hReq:= HttpOpenRequest(hCon,'POST',PChar(Uri),nil,nil,nil,
          INTERNET_FLAG_RELOAD,Context)
      else
        hReq:= HttpOpenRequest(hCon,'GET',PChar(Uri),nil,nil,nil,
          INTERNET_FLAG_RELOAD,Context);
      if (hReq <> nil) then
      begin
        if Params <> nil then
        begin
          Str:= Emptystr;
          for i:= 0 to Params.Count - 1 do
            Str:= Str + '&' + URLEncode(Params.Names[i]) + '=' +
              URLEncode(Params.ValueFromIndex[i]);
          Delete(Str,1,1);
          Success:= HttpSendRequest(hReq,
           'Content-Type: application/x-www-form-urlencoded',Cardinal(-1),
            PChar(Str),Length(Str));
        end else
          Success:= HttpSendRequest(hReq,nil,0,nil,0);
        if Success and (Response <> nil) then
        try
          while (InternetReadFile(hReq,@Buffer,sizeof(Buffer),BytesRead)) do
          begin
            if (BytesRead = 0) then
            begin
              Result := TRUE;
              break;
            end;
            Response.Write(Buffer,BytesRead);
          end;
        except end;
        InternetCloseHandle(hReq);
      end;
      InternetCloseHandle(hCon);
    end;
    InternetCloseHandle(hNet);
  end;
end;

procedure Votar;
var
  Campos: TStringlist;
  Respuesta: TStringStream;
  Str: String;
begin
  Campos:= TStringList.Create;
  Respuesta:= TStringStream.Create('');
  try
    if SendRequest('l2.hopzone.net','/vote.php?site=60199',80,nil,Respuesta) then
    begin
      if Pos('<INPUT TYPE="HIDDEN" NAME="',Respuesta.DataString) > 0 then
      begin
        Str:= Respuesta.DataString;
        Respuesta.Size:= 0;
        Delete(Str,1,Pos('<INPUT TYPE="HIDDEN" NAME="',Respuesta.DataString)+
          Length('<INPUT TYPE="HIDDEN" NAME="') - 1);
        Delete(Str,Pos('"',Str),MAXINT);
        Campos.Values[Str]:= '60199';
        Campos.Values['gogogo']:= 'VOTE FOR Insomnyo Server';
        if SendRequest('l2.hopzone.net','/regvote.php',80,nil,
          Respuesta) then
        begin
          // Aqui comprobariamos la respuesta, pero en principio el voto
          // se ha realizado
        end else Writeln('No puedo acceder al servidor');
      end else Writeln('No encuentro el campo oculto');
    end else Writeln('No puedo acceder al servidor');
  finally
    Campos.Free;
    Respuesta.Free;
  end;
end;

begin
  Votar;
end.

[imossa]

Bueno chicos, felicidades, creo que ha funcionado.
De verdad, gracias por vuestra ayuda.
Saludos.

Edito: el navegador no se abre jeje lo abría yo en otro punto. Ahora termino las pruebas....

[imossa]

Últimos comentarios tras las pruebas realizadas:
Todo parece correcto, se hace el get y el post (en el código que me pasásteis había un pequeño error, que al llamar la segunda vez a la función que hace el post, no iban los parámetros), y he guardado las respuestas en un post, y es curioso lo que pasa:
La página se carga bien, y se ejecuta el post, pero realmente, el voto no queda registrado.
Además, si ejecuto el form desde el firefox, la página resultante viene en inglés, pero si lo ejecuto con delphi, la página la devuelve en castellano ...

Seguiré haciendo alguna prueba más a ver si lo consigo.
Gracias por todo.

[imossa]

Efectivamente, esta idea me ha surgido de otra que me hizo leer esos hilos.
De hecho intenté con el código que vi, simular o lanzar el post, pasándole lo datos, pero, claro, el tema es que uno de los datos lo genera el programa.
Entonces, pensé en, hacer un get y recoger el fuente en un stream, revisarlo para extraer los datos hidden que me ofrecía y hacer un post con ellos, pero, tampoco funcionó....
No obstante y como ya tengo la mente limpia de lo otro que estaba haciendo, voy a repetir toda la jugada y te comento los resultados, ya que si me diriges a ese hilo es porque debe ser el camino más fácil para hacer lo que me propongo.
Gracias por el tiempo que le has dedicado.