Visor de Nibles

[GaaK]

Hola todos.

Mi pregunta es simple, tengo un editor en donde ingreso 'F' y quiero que me muestre cuatro cuadritos que representen su valor en binario: 1111

Se me ocurre manejarlo con Labels, colocar cuatro Labels de 5*5 con un color de fondo x. Sería factible este método para un ingreso como 'F124145FEDA'?

Gracias por las respuestas
- GaaK -

[[Lepe]]

Mira la función HexTobin en la ayuda.

Código Delphi [-]
function HextoBinEx(hexa:string):string;
var buffer: array of string;
     BuffSize:integer;
begin
BuffSize := length(hexa)*2;
setlength( buffer, BuffSize);
{$T-}
HexTobin(pansichar(lowercase(hexa)), @buffer, BuffSize);
{$T+}
Result := buffer;
end;

De memoria sería así, tendrá errores.

Saludos

[[seoane]]

A la siguiente función le pasas un string con un numero en hexadecimal y te devueleve un string con el número en binario. Luego tu solo tienes que ir comprobando en un bucle cada posición, para saber si es un uno o un cero y mostrarlo gráficamente como quieras.

Código Delphi [-]
function HexABin(Str: String): String;
var
  i,j: int64;
begin
  Result:= EmptyStr;
  j:= int64(1) shl 62;
  i:= StrToInt64('$' + Str);
  while j > 0 do
  begin
    if i >= j then
    begin
      Result:= Result + '1';
      i:= i - j;
    end else
      Result:= Result + '0';
    j:= j shr 1;
  end;
end;

// Por ejemplo
ShowMessage(HexABin('F124145FEDA'));

[GaaK]

Gracias por las respuestas.

Mi duda más que nada es el modo de visualización. Estuve revisando el BinaryClock y usa Labels para mostrar los valores, de modo que cada Label es un bit, se le cambia el color del fondo para indicarlo como 0 o como 1.
Esto es una buena opción, pero para mostrar un valor como FFFF (16 bits) serían 16 Labels y si la cifra incrementa imagínense la cantidad de Labels.

Hasta acá creo que ya tienen la idea verdad?...

Anduve revisando y encontré StringGrid y DrawGrid, ambos me pueden proporcionar una gran matriz de boxes (131*80 por ejemplo). Puedo configurar los boxes como 4*4 y hasta acá todo genial, pero no encuentro la forma de cambiar el color de fondo de cada box. Quizá con DrawGridOnDrawCell...ARow, ACol?

Otra opción y creo que sería lo mejor es mediante un Image. Con esto podría dibujar los boxes a mi antojo. Al parecer esto sería una tarea más ardua.

Recordaís que:
- Se tiene un Memo en donde ingreso el valor Hexa y al presionar un Botón se me origine el gráfico.
- El modo inverso sería también que del gráfico se me origine la cadena Hexa, esto me proporcionaría la opción de modificar el estado de algunos bits directamente desde el gráfico.

Cáspita, esto parece un editor gráfico...

- GaaK -

[[seoane]]

Vamos a probar con gráficos.

Lo primero es hacer una bonita función que nos dibuje los bits:

Código Delphi [-]
procedure PintarBits(Canvas: TCanvas; Numero: Cardinal);
var
  i,j: Cardinal;
begin
  j:= 0;
  i:= $80000000;
  while i > 0 do
  begin
    if Numero >= i then
    begin
      Numero:= Numero - i;
      Canvas.Brush.Color:= clYellow;
    end else
      Canvas.Brush.Color:= clSkyBlue;
    Canvas.Rectangle(j,0,j+10,10);
    i:= i shr 1;
    inc(j,10);
  end;
end;

Esta función nos dibuja una tira de 10 pixeles de alto y 320 de ancho, en el que cada bit se representa por un cuadrado, de color amarillo para los unos y azul para los ceros. Siendo el bit menos significativo el cuadrado de la derecha.

Ahora tenemos que decidir donde dibujar, podemos hacerlo sobre un TImage, un TPictureBox, un TBitmap o incluso sobre el propio formulario. Vamos a utilizar la opción del TPictureBox.

Colocamos en el formulario un TPictureBox de 320x10, y en su evento OnPaint colocamos los siguiente:

Código Delphi [-]
procedure TForm1.PaintBox1Paint(Sender: TObject);
begin
  PintarBits(PaintBox1.Canvas,Numero);
end;

Donde "Numero" es una variable global de tipo Cardinal que almacena el numero que queremos dibujar. Ahora bien, como le asignamos un valor, pues por ejemplo en el evento de un ratón colocamos lo siguiente:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
begin
  Numero:= $AAAAAAAA;
  PintarBits(PaintBox1.Canvas,Numero);
end;

En el código anterior le asignamos un valor fijo, te dejo a ti usar el valor de un TEdit por ejemplo. Pero ahora lo que seria interesante es poder modificar los bits pulsando con el ratón sobre ellos, pues nada en el evento OnMouseUp del TPictureBox colocamos esto:

Código Delphi [-]
procedure TForm1.PaintBox1MouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  i: Cardinal;
begin
  i:= x div 10;
  if i < 32 then
  begin
    i:= 1 shl (31 - i);
    Numero:= Numero xor i;
    PintarBits(PaintBox1.Canvas,Numero);
    // Aqui podriamos mostrar el numero en un TEdit, por ejemplo
  end;
end;

Bueno, creo que con esto llega por ahora ...

[GaaK]

Empezado por seoane

Vamos a probar con gráficos.

Lo primero es hacer una bonita función que nos dibuje los bits:

....Bueno, creo que con esto llega por ahora ...

Magnífico, esto es lo que quería y ya tengo la idea, thank you very much.

- GaaK -