Ejecutar Valor de una variable

[bbjb]

Hola a tod@s,

No se si lo que voy a plantear es un disparate como una catedral, pero bueno por probar.

Tengo recogida en una variable el nombre de un procedimiento y me gustaría saber si es posible ejecutar el valor de esa variable de manera que pasará a lanzarse el procedimiento en cuestión

Me he conseguido explicar?
Un saludo y muchas gracias.

[[Bicho]]

Hola,

a mi no se me ocurre que puedas hacerlo cogiendo el nombre del procedimiento y ejecutándolo. Sólo se me ocurre que hagas un "case" (en tu caso no valdría ya que en la variable guardas un string) o ir haciendo If's para los valores que pueda tomar esa variable y según el que tome ejecutar un procedimiento

Ej: con integer;

Código Delphi [-]
  case variable of
     1 : Buscar;
     2 : Guardar;
     3 : Borrar;
     4 : boton1OnClick(boton1);
  ...
  end;

Ej. con string

Código Delphi [-]
  if variable = 'GUARDAR' then Guardar
  else if variable = 'BUSCAR' then Buscar
    else if variable = 'BORRAR' ....

Espero te sirva o alguien encuentre mejor solución para lo que buscas.

Saludos

[dec]

Hola,

No sé si te refieres a algo así:

Código Delphi [-]
var
  FProcedimiento: procedure(s: string);

procedure UnProcedimiento(saludo: string);
begin
  ShowMessage(saludo);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  FProcedimiento := UnProcedimiento;
  FProcedimiento('¡Hola mundo!');
end;

[Neftali [Germán.Estévez]]

Si el procedimiento es published y pertenece a una clase puedes hacerlo utilizando RTTI.

Si es eso lo que te interesa dilo o haz una búsqueda en los foros y te aclaramos un poco más.

[[seoane]]

Ya puestos a hacer cosas "exoticas" ¿que os parece esto?

Código Delphi [-]
procedure Vamos1;
begin
  ShowMessage('Hola 1');
end;

procedure Vamos2;
begin
  ShowMessage('Hola 2');
end;

procedure TForm1.EjecutarPorNombre(Nombre: String);
var
  i: integer;
  p: Procedure;
begin
  i:= Lista.IndexOf(Nombre);
  if i <> -1 then
  begin
    p:= Pointer(Lista.Objects[i]);
    p;
  end else
    ShowMessage('No se encontro el procedimiento');
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  EjecutarPorNombre('Vamos1');
  EjecutarPorNombre('Vamos2');
  // Esta ultima nos dara error
  EjecutarPorNombre('Vamos3');
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Lista.Free;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Lista:= TStringList.Create;
  Lista.AddObject('Vamos1',TObject(@Vamos1));
  Lista.AddObject('Vamos2',TObject(@Vamos2));
end;

No es que tenga mucha utilidad, pero resulta curioso

[bbjb]

Antes de nada agradeceros el interés mostrado.

Os voy a detallar un poco más el programilla que tengo para situaros mejor.

Tengo dos procedimientos declarados en una unidad Unit1 cuya utilidad única y exclusiva es recoger todas la funciones y procedimientos que son susceptibles de ser utilizados desde distintos formularios, por lo tanto estos procedimientos son "públicos".

Por otro lado, y desde el formulario Form1 por ejem. tengo una variable que puede recoger el valor de uno de esos procedimientos, por ejem:

    s_cadena := 'procedimiento_inicio';

Lo que intento es poder utilizar el valor de esa variable para ejecutar el proced. que en cada momento contenga.

[Neftali [Germán.Estévez]]

Eso desestima RTTI; La opción de Seoane de una lista de apuntadores a funciones creo que puede ser la más útil si el número de funciones va a ir creciendo. Si van a ser siempre 2 utiliza un if/case.

[[seoane]]

Vamos a ver, podemos implementar el método que te comente antes en una unit, y solamente hacer publico el procedimiento EjecutarPorNombre. Algo así:

Código Delphi [-]
unit Procedimientos;

interface

procedure EjecutarPorNombre(Nombre: String);

implementation

uses Windows, Sysutils, Classes;

var
  Lista: TStringList;

// Aqui coloca los procedimientos
// *******************************
procedure Procedimiento1;
begin

end;

procedure Procedimiento2;
begin

end;

procedure Procedimiento3;
begin

end;
// *******************************

procedure EjecutarPorNombre(Nombre: String);
var
  i: integer;
  P: Procedure;
begin
  i:= Lista.IndexOf(Nombre);
  if i <> -1 then
  begin
    P:= Pointer(Lista.Objects[i]);
    P;
  end else
    raise Exception.Create('No se pudo encontrar el procedimiento');
end;

initialization
  Lista:= nil;
  Lista:= TStringList.Create;
  Lista.AddObject('Procedimiento1',TObject(@Procedimiento1));
  Lista.AddObject('Procedimiento2',TObject(@Procedimiento2));
  Lista.AddObject('Procedimiento3',TObject(@Procedimiento3));
finalization
  Lista.Free;

end.

Para llamar a un procedimiento, lo haríamos de la siguiente manera:

Código Delphi [-]
var
  s_cadena: string;
begin
  // El nombre diferencia entre mayusculas y minusculas
  s_cadena:= 'Procedimiento1';
  EjecutarPorNombre(s_cadena);
end;

Espero que te sirva

[bbjb]

Ok, gracias a ambos.

Voy a probar y ahora os comento.