Minimizar Form en ShowModal

[el_enigma1]

Como se puede minimizar un form que esta en ShowModal, bueno de hecho minimizar la aplicacion que esta mostrando un ventana en ShowModal.
De antemano gracias por la ayuda.

[Neftali [Germán.Estévez]]

Empezado por el_enigma1

Como se puede minimizar un form que esta en ShowModal, bueno de hecho minimizar la aplicacion que esta mostrando un ventana en ShowModal.

Añade a la parte privada de tu form modal la siguiente definición:

Código Delphi [-]
 procedure WMSyscommand(Var msg: TWmSysCommand); message WM_SYSCOMMAND;

y luego en la implementación de dicha procedure haces lo siguiente:

Código Delphi [-]
   case (msg.cmdtype and $FFF0) of
     SC_MINIMIZE:
     begin
       msg.result := 0;
       EnableWindow(Application.handle, true);
       Application.Minimize;
     end;
   else
     inherited;
   end;

con ésto debería funcionar...

[el_enigma1]

Gracias por la info

[roman]

Con el método de Neftalí se logra minimizar la aplicación al minimizar la ventana modal, pero, ¿qué tal minimizarla usando el botón de la barra de tareas? Este botón siempre se inhabilita al mostrar una ventana modal.

Pues viendo esta solución se me ocurrió entonces poner

EnableWindow(Application.handle, true);

en el evento OnShow de la ventana modal y ¡listo!, ahora el botón de la barra de tareas continúa funcionando y de hecho sin necesidad del WMSysCommand.

Así que me alegro de que hayan preguntado esto y de la respuesta de Neftalí que resuelve algo que siempre quise .

La pregunta ahora sería, ¿cómo lograr esto para cualquier ventana modal sin necesidad de programar el evento OnShow de cada ventana?

¿Se te ocurre algo Neftalí?

// Saludos

[unko!]

intenta tambien en el Inspector de Objetos, en la parte de hasta abajo en "Windows State" modificale a -----> wsMinimized si kieres ke se minimize en cuanto se le llame. slau2, espero ke sirva XD

[roman]

Hola,

Continuando lo que había planteado, he finalmente encontrado una respuesta definitiva dada por Peter Below en los foros de Borland. Básicamente se trata de habilitar la aplicación cada vez que alguien la deshabilite. La aplicación recibe el mensaje WM_ENABLE cuando se habilita o se inhabilita así que lo único que hay que hacer es interceptar este mensaje. Desafortunadamente el evento OnMessage de una componente ApplicationEvents no recibe este mensaje así que hay que usar otra técnica que es la que nos muestra Peter Below:

Código Delphi [-]
type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);

  private
    function AppHook(var Msg: TMessage): Boolean;
  end;

implementation

procedure TForm1.FormCreate(Sender: TObject);
begin
  Application.HookMainWindow(AppHook);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  Application.UnhookMainWindow(AppHook);
end;

function TForm1.AppHook(var Msg: TMessage): Boolean;
begin
  Result := false;
  if Msg.Msg = WM_ENABLE then
    if not TWMEnable(Msg).Enabled then
    begin
      EnableWindow(Application.Handle, true);
      Result := true;
    end;
end;

end.

// Saludos

[Neftali [Germán.Estévez]]

Empezado por roman

...así que hay que usar otra técnica que es la que nos muestra Peter Below:

Código Delphi [-]
 ...
    Application.HookMainWindow(AppHook);
 ...

Muy bueno, sí señor...

[Alexander]

Hola amigos del Foro.

Gracias por la información para minimizar un ShowModal. Me funcionó perfecto.

Mi consulta ahora es: Como puedo hacer para que al minimizar un reporte desarrollado en Report Builder, también minimice la aplicación.

Muchas gracias.

Alexander