Petición HTTP

[[newtron]]

Hola a tod@s.


Estoy intentando comunicarme con un "PinPad" (lector de tarjetas de crédito) y para eso me dicen que tengo que hacer una llamada con el siguiente formato:



El tema es que estoy un poco liado porque para esto imagino que tendría que usar un objeto HTTPClient insertando un JSONObject con el cuerpo del mensaje y tengo un par de problemas:


- No sé cómo crearlo teniendo en cuenta de que hay en medio una especie de array en el elemento "executeOptions".
- De todas formas he hecho una llamada de pruebas con un json que seguramente no valdrá, pero por si acaso, y el "PinPad" ni se inmuta y ya no sé si es que estoy haciendo algo mal o me estoy equivocando al poner ip o puerto o qué pasa.


El código que estoy usando es uno que he pillado de un ejemplo que puso nuestro compañero Keys y lo he tuneado:

Código Delphi [-]
procedure TForm2.Button2Click(Sender: TObject);var
  sAux,Enviar: String;
  LRequest: THTTPClient;

  LResponse: TStringStream;
  JSONData: TJSONObject;
  StringStream: TStringStream;
  valido : Boolean;
  vJSONArray: TJSONArray;
  JSONDataArray: TJSONObject;
begin

  LRequest := THTTPClient.Create;
  LResponse := TStringStream.Create;

  vJSONArray := TJSONArray.Create;
  JSONDataArray := TJSONObject.Create;
  JSONDataArray.AddPair('method','polling');
  vJSONArray.AddElement(JSONDataArray);

  //Objeto JSON para enviar los datos
  JSONData := TJSONObject.Create;
  JSONData.AddPair('pinpad', '*');
  JSONData.AddPair('opType','sale');
  JSONData.AddPair('cardNumberHashDomain','branch');
  JSONData.AddPair('createReceipt',TJSONFalse.Create);
  JSONData.AddPair('executeOptions', vJSONArray);
  JSONData.AddPair('language','es');
  JSONData.AddPair('requestedAmount',TJSONNumber.Create(200));
  JSONData.AddPair('requireConfirmation',TJSONFalse.Create);
  JSONData.AddPair('transactionReference','Operación N 256498');

  try

    Lrequest.ContentType := 'application/json';

    StringStream := TStringStream.Create(JSONData.ToString, TEncoding.UTF8);

    LRequest.Post('http://192.168.1.34:8887/transaction/start', StringStream , LResponse);

    JSONData := TJSONObject.ParseJSONValue(LResponse.DataString) as TJSONObject;

    if Assigned(JSONData) then begin

    end;

    JsonData.destroy;
    LResponse.Free;
    LRequest.Free;
    StringStream.Destroy;
  except
    JsonData.destroy;
    LResponse.Free;
    LRequest.Free;
    StringStream.Destroy;
  end;


end;

A ver si algún amable forero me pueda dar luz.


Gracias y un saludo.

[lucho6007]

Hola!
No se qué versión de Delphi usas, pero este ejemplo sirve para versiones viejitas y nuevas:
En el uses de la unidad agregás:

Código Delphi [-]
IdServerIOHandler, IdSSL, IdSSLOpenSSL, IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient, IdHTTP, McJson,

McJSon es una unidad de manejo de JSON, descargable desde https://github.com/hydrobyte/McJSON

En la implementación agregás:

Código Delphi [-]
function TForm1.GetResponse(Verb, URL: String; AText: String): String;
var
  AHTTP: TIdHTTP;
  SSL: TIdSSLIOHandlerSocketOpenSSL;

  JsonToSend: TStringStream;
begin
  AHTTP:= TIdHTTP.Create(nil);
  SSL:= TIdSSLIOHandlerSocketOpenSSL.Create(nil);

  AHTTP.IOHandler:= SSL;
  AHTTP.AllowCookies:= True;
  AHTTP.HTTPOptions:= [hoForceEncodeParams];

  AHTTP.Request.BasicAuthentication:= True;

  AHTTP.Request.Accept:= 'application/json';
  AHTTP.Request.AcceptCharSet := 'utf-8';
  AHTTP.Request.ContentType:= 'application/json';
  AHTTP.Request.UserAgent:= 'Mozilla/5.0 (Windows NT 6.1; Win64; x64; rv:47.0) Gecko/20100101 Firefox/47.0';
  AHTTP.Request.CharSet:= 'utf-8';

  SSL.SSLOptions.Method:= sslvSSLv23;
  SSL.SSLOptions.Mode:= sslmUnassigned;
  SSL.SSLOptions.VerifyMode:= [];
  SSL.SSLOptions.VerifyDepth:= 0;
  SSL.SSLOptions.SSLVersions := [sslvSSLv23, sslvTLSv1, sslvTLSv1_1, sslvTLSv1_2];

  if AText <> '' then begin
    JsonToSend := TStringStream.Create(Utf8Encode(AText));
  end;

  Result:= '';
  if (URL <> '') then begin
    if UpperCase(Verb) = 'GET' then begin
      try
        Result:= AHTTP.Get(URL);
      except
        on E: Exception do begin
          Result:= '{"Error":"' +  E.Message + '"}';
        end;
      end;
    end
    else begin
      if UpperCase(Verb) = 'PUT' then begin
        try
          Result:= AHTTP.Put(URL, JsonToSend);
        except
          on E: Exception do begin
            Result:= '{"Error":"' +  E.Message + '"}';
          end;
        end;
      end
      else begin
        if UpperCase(Verb) = 'POST' then begin
          try
            Result:= AHTTP.Post(URL, JsonToSend);
          except
            on E: Exception do begin
              Result:= '{"Error":"' +  E.Message + '"}';
            end;
          end;
        end;
      end;
    end;
  end;

  SSL.Free;
  AHTTP.Free;
end;

Un ejemplo de llamada y creación del JSON:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var AJSonStr: String;
    AJSon: TMcJsonItem;
begin
  AJSon:= TMcJsonItem.Create;
  AJSon.Clear;
  AJSon.Add('pinpad').AsString:= '*';
  AJSon.Add('opType').AsString:= 'sale';
  AJSon.Add('cardNumberHashDomain').AsString:= 'branch';
  AJSon.Add('createReceipt').AsBoolean:= false;
  AJSon.Add('executeOptions', jitObject);
  AJSon.O['executeOptions'].Add('method').AsString:= 'pooling';
  AJSon.Add('language').AsString:= 'es';
  AJSon.Add('requestedAmount').AsNumber:= 200;
  AJSon.Add('requireConfirmation').AsBoolean:= false;
  AJSon.Add('transactionReference').AsString:= 'Operation N 45664';

  AJSonStr:= AJSon.AsJSON;

  AJSon.Free;
  Caption:= GetResponse('POST', 'http://192.168.1.34:8887/transaction/start', AJSonStr);
end;

En el Caption del form tendrás la respuesta del equipo.

Espero te ayude!
Saludos
Lucho

[[newtron]]

Lucho. Gracias por tu respuesta y tu código.


Estoy montándolo y me da error en la linea:

Código Delphi [-]
 AJSon.Add['executeOptions'].Add('method').AsString:= 'pooling';

Me dice: Object reference is nil: get item by key "executeOptions"


¿Alguna idea de qué puede ser?


Gracias de nuevo y un saludo.

[lucho6007]

Hola!
Fijate que el código que te envié es

Código Delphi [-]
  AJSon.Add('executeOptions', jitObject);   AJSon.O['executeOptions'].Add('method').AsString:= 'pooling';

y vos estás ejecutando

Código Delphi [-]
AJSon.Add['executeOptions'].Add('method').AsString:= 'pooling';

Primero tenés que agregar el objecto y luego el contenido.


SAludos

[[newtron]]

Buenas de nuevo.


Tienes razón, no estaba poniendo bien el código. Infeliz de mi pensaba que la parte .. AJSon.O[' ... por lo que fuera no estaba bien escrita y la había corregido cambiando la O por Add



Muchas gracias. Me ha servido muchísimo.


Saludos.