Saber a que procedimiento se llama en el evento de un objeto

[APO]

Hola,
El caso es que tengo un formulario con varios objetos (TcxButton) y casi todos tienen asociado el mismo evento 'OnClick', pero no todos. Pero el evento no se llama 'OnClick' sino que le cambio el nombre, 'ConfigurarForm'. Y algunos tienen el evento asociado 'ConfigurarForm' y otros no. Pero es algo que voy asignando a los botones en tiempo de ejecución.

Entonces, lo que me gustaría saber, es qué botones llaman al evento 'ConfigurarForm'.

No sé si me he explicado muy bien. Pero la idea, a grosso modo, es saber el nombre del evento 'OnClick' al que llama un determinado objeto.

Si existiese la instrucción, sería saber algo así:

if btnAceptar.OnClick.Name = 'ConfigurarForm' then ...

Gracias. Un saludo.

[*Caro*]

Hola APO, tu procedimiento ConfigurarForm seguramente tiene el parámetro Sender, es ese parámetro el que debes usar:

Código Delphi [-]
procedure TForm1.ConfigurarForm(Sender: TObject);
begin
  Showmessage(TcxButton(Sender).Name);
  ....................................

Saluditos

[APO]

Hola Caro,

Con lo que comentas lo único que obtengo es el nombre del objeto (eje: 'TcxButton1'). Pero lo que necesito saber es el nombre del evento al que llama. Es decir, el TcxButton1 en el evento 'OnClick', llama al evento llamado 'ConfigurarFrm(Sender: TObject)'.

Pero esto lo necesito saber sin tener que llamar al evento. Es decir, que yo mediante una función, recorreré todos los objetos de ese formulario y tengo que averiguar cuáles son los que llaman a 'ConfigurarFrm(Sender: TObject)'.

He estado mirando muchísimas conversaciones del foro, pero ninguna da con la solución. A ver si algún "gurú" sabe cómo se hace, jejeje.

Gracias. Un saludo.

[roman]

Empezado por APO

Si existiese la instrucción, sería saber algo así:

if btnAceptar.OnClick.Name = 'ConfigurarForm' then ...

A ver, intenta así:

Código Delphi [-]
var
  Method: TMethod;

begin
  Method := TMethod(btnAceptar.OnClick);
  if Method.Code = @TForm1.ConfigurarForm then
    ShowMessage('Mi evento OnClick es ConfigurarForm');
end;

// Saludos

[APO]

Empezado por roman

A ver, intenta así:


Código Delphi [-]
var
Method: TMethod;

begin
Method := TMethod(btnAceptar.OnClick);
if Method.Code = @TForm1.ConfigurarForm then
ShowMessage('Mi evento OnClick es ConfigurarForm');
end;





// Saludos

CORRECTO!

Muchas gracias Roman! Eso es justamente lo que quería. Y con el código que has puesto funciona perfectamente. Eres un crack!

Gracias a todos por vuestro tiempo. Un saludo.

[[maeyanes]]

Hola...

Ese código que usó roman, es un ejemplo de uso de RTTI (Información de Tipos en Tiempo de Ejecución, por sus siglas en inglés).

Te recomiendo que leas todo lo que puedas sobre el tema y verás que puedes conseguir muchas cosas más.



Saludos...

[ecfisa]

Hola.

Otra forma puede ser:

Código Delphi [-]
function GetObjMethodName(AObj: TObject;const OrigName: string): string;
var
  Mtd: TMethod;
begin
  Mtd:= GetMethodProp(AObj,OrigName);
  if (Mtd.Data <> nil) and (Mtd.Code <> nil) then
    Result:= TObject(Mtd.Data).MethodName(Mtd.Code);
end;

Ejemplo de llamada:

Código Delphi [-]
  ShowMessage(GetObjMethodName(Button1, 'OnClick'));

Saludos.