Insertar Imaganes en M$ Acce$$

[GerTorresM]

Hola a todos:

La cuestión es la siguiente:

Trabajo con una base de datos hecha en Acce$$, a la cual me conecto mediante el BDE, en la BD me progongo guardar una imagen (bmp, jpg, etc) en un campo de la misma para poder utilizarla en los encabezados del los reportes.

La verdad no tengo la mínima idea de como hacerlo y cualquier respuesta serie muy util.



Gertorresm
-- Colombia --

[[BlueSteel]]

Hola

cuantos registros tendran imagenes ???

te pregunto esto por que puede resultarte mejor almacenar la imagen en algun directorio del servidor y no en la base de datos, ya que dependiendo de la calidad y cantidad de imagen, se puede hacer más lento tu sistema..

Yo prefiero almacenar la imagen en un directorio y solo almaceno el patch de la imagen en el registro...

utiliza la busqueda, veras que el tema se ha tratado varias veces...

Salu2

[GerTorresM]

Gracias por tu respuesta, en la actualidad estoy haciendo lo mismo, es decir guardando la ruta de la imagen, pero lo que sucede es que cuando trabajo la aplicación en red tengo problemas con la localización de la imagen y por ende surguen los errores, por eso lo que tengo pensado es almacer una (1) imagen en la Bd.


gertorresm
-- Colombia --

[Nati1]

usa componentes ADO
ejemplo:
Crea un nuevo form
1- coloca un componente Timage en el form
2- coloca un componente adoConnection
3- coloca un componente adoTable
4- Coloca un componente datasource
5- coloca un componente OpenDialog
6- coloca un componente ScrollBox1 y pon el componente Timagen dentro.
7- coloca un componente tnavigator
8- coloca dos botones

sigue estos paso:

Código Delphi [-]
var
  Form1: TForm1;

implementation

{$R *.dfm}

uses jpeg;

var jpg: TJPEGImage;

procedure TForm1.FormCreate(Sender: TObject);
begin
 jpg := TJPEGImage.Create;        // Creamos el objeto que "entiende" al JPEG

end;

procedure TForm1.Button1Click(Sender: TObject);
var bmp: TBitmap; Stream: TStream;
begin
 if not OpenDialog1.Execute then Exit;

 bmp := TBitmap.Create;           // Creamos el objeto que "entiende" al Bitmap
 bmp.LoadFromFile(OpenDialog1.FileName);  // cargamos la imagen
 jpg.Assign(bmp);                 // signamos la imagen BMP al objeto del JPEG
 bmp.Destroy;                     // y liberamos el objeto. }

 ADOTable1.Open;                  // Abrimos la tabla
 ADOTable1.Insert;                // Insertamos una nueva tupla
 Stream := ADOTable1.CreateBlobStream(ADOTable1.FieldByName('photo'), bmWrite); // Asignamos el BLOB a un stream
 jpg.SaveToStream(Stream);        // y guardamos la imagen como JPEG (convertido), en el stream
 Stream.Destroy;                  // liberamos.
 ADOTable1.Post;                  // Guardamos.

end;

procedure TForm1.Button2Click(Sender: TObject);
var  Stream: TStream;
begin
 ADOTable1.Open;                 // Abrimos la tabla
 ADOTable1.Last;                 // Nos vamos a la última tupla para ver la ultima imagen añadida.
 Stream := ADOTable1.CreateBlobStream(ADOTable1.FieldByName('photo'), bmRead); // Lo mismo que el anterior caso pero ahora en modo de escritura.
 jpg.LoadFromStream(Stream);     // Cargamos el BLOB al objeto JPEG
 Stream.Destroy;                 // liberamos...
 Image1.Picture.Assign(jpg);     // y asignamos la imagen al TPicture.

 end;

procedure TForm1.DBNavigator1Click(Sender: TObject; Button: TNavigateBtn);
var  Stream: TStream;
begin
 Stream := ADOTable1.CreateBlobStream(ADOTable1.FieldByName('photo'), bmRead); // Lo mismo que el anterior caso pero ahora en modo de escritura.
 jpg.LoadFromStream(Stream);     // Cargamos el BLOB al objeto JPEG
 Stream.Destroy;                 // liberamos...
 Image1.Picture.Assign(jpg);     // y asignamos la imagen al TPicture.

end;

end.

Gracias al Maestro ChackAll.