Lista de procesos... pero 64 bits?

[BrunoBsso]

Hola foro.
Alguno me dirá "esto ya se trató" y espero que me ponga el link, porque por más que busco acá y en google, no encuentro la respuesta.
Ante todo, aclaro que lo que les voy a mostrar me devuelve todos los procesos que se ejecutan con arquitectura de 32 bits.

Para SO Windows 9x:

Código Delphi [-]
procedure CreateWin9xProcessList(List: TstringList);
var
  hSnapShot: THandle;
  ProcInfo: TProcessEntry32;
begin
  if List = nil then Exit;
  hSnapShot := CreateToolHelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  if (hSnapShot <> THandle(-1)) then
  begin
    ProcInfo.dwSize := SizeOf(ProcInfo);
    if (Process32First(hSnapshot, ProcInfo)) then
    begin
      List.Add(ProcInfo.szExeFile);
      while (Process32Next(hSnapShot, ProcInfo)) do
        List.Add(ProcInfo.szExeFile);
    end;
    CloseHandle(hSnapShot);
  end;
end;

Para SO Windows NT:

Código Delphi [-]
procedure CreateWinNTProcessList(List: TstringList);
var
  PIDArray: array [0..1023] of DWORD;
  cb: DWORD;
  I: Integer;
  ProcCount: Integer;
  hMod: HMODULE;
  hProcess: THandle;
  ModuleName: array [0..300] of Char;
begin
  if List = nil then Exit;
  EnumProcesses(@PIDArray, SizeOf(PIDArray), cb);
  ProcCount := cb div SizeOf(DWORD);
  for I := 0 to ProcCount - 1 do
  begin
    hProcess := OpenProcess(PROCESS_QUERY_INFORMATION or
      PROCESS_VM_READ,
      False,
      PIDArray[i]);
    if (hProcess <> 0) then
    begin
      EnumProcessModules(hProcess, @hMod, SizeOf(hMod), cb);
      GetModuleFilenameEx(hProcess, hMod, ModuleName, SizeOf(ModuleName));
      List.Add(ModuleName);
      CloseHandle(hProcess);
    end;
  end;
end;

Método global:

Código Delphi [-]
procedure GetProcessList(var List: TstringList);
var
  ovi: TOSVersionInfo;
begin
  if List = nil then Exit;
  ovi.dwOSVersionInfoSize := SizeOf(TOSVersionInfo);
  GetVersionEx(ovi);
  case ovi.dwPlatformId of
    VER_PLATFORM_WIN32_WINDOWS: CreateWin9xProcessList(List);
    VER_PLATFORM_WIN32_NT: CreateWinNTProcessList(List);
  end
end;

Bueno, eso lo saqué de Torry creo, ya no me acuerdo. Siempre lo usé, porque siempre trabajé sobre 32 bits.
Ahora estoy necesitando obtener la lista de procesos en, por ejemplo, Windows 7 a 64 bits.
El problema es que llamando al global (GetProcessList) solamente me devuelve los procesos basados en 32 bits, y como que no soy muy bueno para entender las API de Windows
Espero que alguien me pueda ayudar.
Pregunta en concreto -> ¿Cómo obtengo también los procesos en 64 bits?
Saludos.

[Neftali [Germán.Estévez]]

Puedes probar los componentes GLibWMI que hay en SourceForge o en mi página web.
Entre los componentes del paquete está el ProcessInfo, que te debería devolver las lista de procesos que hay en ejecución. Lo he probado en W7, aunque no en la versión de 64b, pero la teoría dice que debe funcionar sin problemas.

Si quieres probarlo, para ver si funciona en W7+64b antes de instalar nada, puedes bajar los ejecutables de las demos desde aquí y probarlos. entre las demos hay un GenericTest, donde puedes probar todos los componentes, entre ellos el que te he comentado.

[BrunoBsso]

Justamente me acabo de meter al foro para mandarte un MP a vos, Neftali, para preguntarte si tu GLibWMI me podría solucionar las cosas.
¡Qué casualidad!
Ahora bajo los demos y cuando pueda me fijo (solamente mi notebook tiene Win7, y mi vieja la está usando ahora).
Saludos y después te cuento!

[BrunoBsso]

Bueno, probada la GLibWMI en Win7 x86 y x64 y funciona en las 2.
Después lo implemento donde lo necesito.
Saludos!

[Neftali [Germán.Estévez]]

Empezado por BrunoBsso

Bueno, probada la GLibWMI en Win7 x86 y x64 y funciona en las 2.

Se agradece el Feedback...

[Firewind]

Hola.

He probado la libreria con delphi 2010, en mi pc me funciona correctamente, pero cuando intento ejecutar el programa creado en mi portatil (P3 dell) me da error, incluso no me funcionan los .exe descargados de la web.

Alguna idea?

Un saludo.

P.D. - Los 2 tienen el mismo windows xp

[Neftali [Germán.Estévez]]

La libería GLibWMI se basa en los componentes de Windows de "Windows Management instrumentation" (en principio deberían estar en marcha en las últimas versiones de Windows); Si esos componentes no están instalados o no están funcionando, la librería no podrá funcionar tampoco.

No comentas qué error te da en el sistema que falla.

Te recomiendo que leas esta introducción que hay en mi página sobre WMI y pruebes a las llamadas desde línea de comandos. Con eso podremos descartar que sea una cosa u otra.

[Firewind]

Hola.

Me he bajado el fichero : WindowsXP-KB933062-x86-ESN.exe , que contiene el el fichero : WGAPluginInstall.exe , lo he instalado en el portatil, reinicio y sigue sin funcionar.
El error que muestra es : Se ha intentando hacer referencia a un simbolo que no existe.
El la linea de comandos pongo : wmic process y no me muestra nada en el portatil, en el pc si. Pero lo raro es que no me da error de comando desconocido, simplemente me sale de nuevo el promt.
Alguna idea de algo más que pueda instalar?

Un saludo.

[Neftali [Germán.Estévez]]

En esta web tienes información de cómo instalar y reparar WMI en los diferentes sistemas Windows.
Ahí también hacen referencia a "The WMI Diagnosis Utility" de Microsoft (link)

Prueba a ve y dinos cual es el resultado.

[[escafandra]]

He tenido oportunidad de probar esto en un Windows 7 64 bits y funciona. Lista las aplicaciones de 32 y 64 bits.

Procedure TFTask.ProcList(Lista: TlistBox);
begin
   Lista.Clear;
   FTask.FSnapshotHandle:=CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS,0);
   FTask.FProcessEntry32.dwSize:=Sizeof(FTask.FProcessEntry32);
   if Process32First(FTask.FSnapshotHandle,FTask.FProcessEntry32) then
   begin
     repeat
          Lista.Items.Add(FTask.FProcessEntry32.szExeFile);
     until integer(Process32Next(FTask.FSnapshotHandle,FTask.FProcessEntry32))=0;
   end;
   CloseHandle(FTask.FSnapshotHandle);
end;

Saludos.

[[escafandra]]

Perdón, ese código pertenece a una clase y aislado pierde sentido. Pongo el código aislado e independiente. Devuelve el listado en un TStrings con lo que se podrá usar un TMemo, TListBox, o cualquier objeto que tenga un TStringList.

Lo he probado en Windows XP 32 bits y Windows 7 64 bits pero no en Vista.

Se que es equivalente a CreateWin9xProcessList. Quizás el proceso global de listado sólo deba llamar a CreateWin9xProcessList y éste procedimiento debería perder el -Win9x- de su nombre, para evitar confusiones.

Código Delphi [-]
procedure ProcList(Lista: TStrings);
var
   FSnapshotHandle: THandle;
   FProcessEntry32: TProcessEntry32;
begin
   Lista.Clear;
   FSnapshotHandle:=CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS,0);
   FProcessEntry32.dwSize:=Sizeof(FProcessEntry32);
   if FSnapshotHandle <> THandle(-1) then
   begin
     if Process32First(FSnapshotHandle, FProcessEntry32) then
     begin
       repeat
          Lista.Add(FProcessEntry32.szExeFile);
       until not Process32Next(FSnapshotHandle, FProcessEntry32);
     end;
     CloseHandle(FSnapshotHandle);
   end;
end;

Saludos.