Error extrañisimo prouducido por delphi

[lag_0]

tengo una aplicación que repite un proceso una y otra vez...
todo va bien...
hace una captura, la compara, muestra unos datos (Todo con forms pintados con imagenes y solo componentes originales de delphi )
Pero... a la hora hora y pico de estar ahi dandole que te pego me suelta:
Quien dice un error dice un par otres, en que uno de ellos se repite...:

CAPTURA:
http://img181.imageshack.us/img181/1855/cap009nh1.jpg


a ver si alguien me puede ayudar...

[jachguate]

He visto el error "canvas does not allow drawing" cuando la máquina se va quedando sin recursos. ¿estas segur@ que no es tu propia aplicación la que se los va comiendo... lo digo, porque si llega a ejecutarse bien cierta cantidad de veces al inicio, y siempre falla después de cierto tiempo/iteraciones, seguro hay algun recurso que creas y nunca liberas, con lo que estos se van agotando.

El error era muy comun en win9x, en winxp es mucho menos frecuente...

Hasta luego.

[lag_0]

Si, tenia una idea de que podia ser por eso... era la única opción que creia probable, de todos modos queria ver vuestra opinion.

Mi problema es que necesito los logs que guarda... intentaré ver que puedo liberar

Gracias!

[lag_0]

Pues ahora hago que el buffer que se llenaba (un TStrings), de todas maneras no podia ser por eso ya que haciendo el mismo bucle sin el proceso de las capturas no da error por más veces que lo repite.

pongo el codigo que al repetirse demasiado da el error
:

Código Delphi [-]
procedure TForm17.identificaTimer(Sender: TObject);
Var DeskHw,DeskHdC : Longint;
begin
 identifica.Enabled:=false;
 DeskHw:=getdesktopwindow;
 DeskHdc:=getdc(deskHw);
 cap.Picture.Bitmap:=nil;
 cap.height:=ff.autoini.ReadInteger('Ventana','AlOk',0);
 cap.width:=ff.autoini.ReadInteger('Ventana','AnOk',0);
 BitBlt(cap.Canvas.Handle,0,0,ff.autoini.ReadInteger('Ventana','AnOk',0),ff.autoini.ReadInteger('Vent  ana','AlOk',0),DeskHdc,ff.autoini.ReadInteger('Ventana','LeftOk',0),ff.autoini.ReadInteger('Ventana'  ,'TopOk',0),SRCCOPY);
 //cap.Repaint;
 //sleep(1000);
   guardada.Picture.Bitmap:=nil;
   guardada.Width:=cap.Width;
   guardada.Height:=cap.Height;
   guardada.Picture.Bitmap.LoadFromFile(ff.Appdir+'Perfiles\'+ff.CasinoPerfil+'\Tirada Ok.bmp');
   guardada.Repaint;
 if not soniguales() then begin
    guardada.Picture.Bitmap:=nil;
   guardada.Width:=cap.Width;
   guardada.Height:=cap.Height;
   guardada.Picture.Bitmap.LoadFromFile(ff.Appdir+'Perfiles\'+ff.CasinoPerfil+'\Tirada Ok1.bmp');
   guardada.Repaint;
 if soniguales() then begin
  //enxufas el proximo timer
    Form16.ae.Caption:='Resultado obtenido...';
    miranum.enabled:=true;
 end else begin
    Form16.ae.Caption:='Aún no se recibio resultado...';
   identifica.Enabled:=true;
 end;
 end else begin
     Form16.ae.Caption:='Resultado obtenido...';
    miranum.enabled:=true;
 end;
end;

Código Delphi [-]
procedure TForm17.miranumTimer(Sender: TObject);
var
 num:integer;
 i:integer;
 DeskHw,DeskHdC : Longint;
begin
  miranum.Enabled:=False;
  cap.Picture.Bitmap:=nil;
 DeskHw:=getdesktopwindow;
 DeskHdc:=getdc(deskHw);
 cap.height:=ff.autoini.ReadInteger('Ventana','AlNum',0);
 cap.width:=ff.autoini.ReadInteger('Ventana','AnNum',0);
 BitBlt(cap.Canvas.Handle,0,0,ff.autoini.ReadInteger('Ventana','AnNum',0),ff.autoini.ReadInteger('Ven  tana','AlNum',0),DeskHdc,ff.autoini.ReadInteger('Ventana','LeftNum',0),ff.autoini.ReadInteger('Venta  na','TopNum',0),SRCCOPY);
 //cap.Repaint;
 i:=0;
 num:=-1;
 form16.ae.Caption:='Comparando imagen...';
  while i < 37 do begin
     guardada.Picture.Bitmap:=nil;
     guardada.Picture.Bitmap.LoadFromFile(ff.Appdir+'Perfiles\'+ff.CasinoPerfil+'\'+inttostr(i)+'.bmp');
     if soniguales() then begin
      num:=i;
      i:=37;
     end;
     i:=i+1;
  end;
  form16.ae.Caption:='Imagen obtenida: Num. '+inttostr(num);
  if num > -1 then
    ff.AddNum(inttostr(num));
end

Y llega a addnum que por si solo no da ningún error.



Funcion sonIguales(); que utilizan los dos timers...:

Código Delphi [-]
function TForm17.SonIguales():bool;
var
   Cx,CY:integer;
begin
  cx:=0;
  Result:=True;
  while Cx <= cap.Width do begin
   cy:=0;
    while CY <= cap.Height do begin
      if cap.Canvas.Pixels[CX,CY] <> guardada.Canvas.Pixels[CX,CY] then begin
        Result:=false;
        cx:=cap.Width+1;
        cy:=cap.Height+1;
      end;
      cy:=cy+1;
    end;
    cx:=cx+1;
  end;
end;

se os ocurre por que puede darme ese error? no hay buffers grandes ya... no entiendo por que puede ser

[[seoane]]

Así entre tanto código lo que me llama la atención es que utilizas GetDc para obtener un handle, pero no lo liberas usando ReleaseDC cuando ya no lo necesitas. Después de una llamada a GetDc siempre has de llamar a ReleaseDC para liberar ese recurso. Es decir:

Código Delphi [-]
DeskHw:= Getdesktopwindow;
DeskHdc:= GetDc(deskHw);
// Haz lo que tengas que hacer con el
ReleaseDC(DeskHw,DeskHdc);

[lag_0]

gracias por la respuesta , respecto a por que no lo puse, ni lo pensé, se me pasaria en su momento.

Implementado. Ahora a probar... a ver si lanza el error.. lo dejaré toda la noche dale que te pego y a ver como amanezco mañana, a menos que salte antes y aviso!

De nuevo, mil gracias a los dos.

[lag_0]

De momento está ahi acomulando tiempo, aún no sé si saldrá o no, pero... si era por eso, me hace ir muuuuuuuuuuuchoooooooo más lento el tema.... necesito que haga ese proceso unas 150 veces por minuto o más... eso es lo ideal... y como entendereis es dificil..
aprobexo y pregunto: se os ocurre algún metodo para optimizar más el codigo?

graaaaaaaaaacias

[[seoane]]

Empezado por lag_0

si era por eso, me hace ir muuuuuuuuuuuchoooooooo más lento el tema

No entiendo porque.

Empezado por lag_0

se os ocurre algún metodo para optimizar más el codigo?

Tengo algunas ideas, pero estaría bien que dijeras lo que intentas hacer. A simple vista te puedo decir que el método que usas para comparar las imágenes usando la propiedad pixels es MUY ineficiente. Aquí te dejo una alternativa, aunque seguro que se puede mejorar.

Código Delphi [-]
function SonIguales(Bitmap1, Bitmap2: TBitmap): Boolean;
var
  i,j: integer;
begin
  Result:= FALSE;
  if (Bitmap1.Width = Bitmap2.Width) and (Bitmap1.Height = Bitmap2.Height) and
     (Bitmap1.PixelFormat = Bitmap2.PixelFormat) then
  begin
    case Bitmap1.PixelFormat of
      pf16bit: j:= (Bitmap1.Width*2) -1;
      pf24bit: j:= (Bitmap1.Width*3) -1;
      pf32bit: j:= (Bitmap1.Width*4) -1;
      else j:= Bitmap1.Width -1;
    end;
    for i:= 0 to Bitmap1.Height - 1 do
      if not CompareMem(Bitmap1.ScanLine[i],Bitmap2.ScanLine[i],j) then
        Exit;
    Result:= TRUE;
  end;
end;

[jachguate]

Al código de seoane añadiría, ya que siempre suelo hacerlo, la garantía de que el recurso será liberado:

Código Delphi [-]
  ObtenerRecurso;
  try
    HacerCualquierCosa;
    YDaleQueTeDale;
  finally
    LiberarElRecurso;
  end;

Sobre lo que comentas con respecto de la velocidad, valdrá la pena que hagas tus pruebas, pero la comparación de imágenes suele ir lenta... quizas haya forma de optimizar eso.

También se me ocurre que, dado que el DeviceContext que tomas es el del escritorio... ¿no valdría tomarlo una vez al inicio y reutilizarlo siempre?. Así te evitas el tiempo de tomarlo y de liberarlo, que francamente desconozco si será poco o mucho.

Hasta luego.

[[Crandel]]

Si lo que intuyo de la imagen es correcto estas haciendo un juego de ruleta e intentando simular tiradas y juegos muy rapidamente.

Mi recomendaci'on es separar la parte grafica del juego en si.

[lag_0]

ahora no tengo tiempo por que tengo que irme rapido, me leeei las respuestas por encima y solo deciros que muchas gracias, grandes ideas, despues programaré.


y... si!!! se arreglo el error de la ram!!!
muchisimas gracias =), luego sigo!

[[Delphius]]

Por curioso llegué hasta este hilo, y viendo los códigos... legué hasta el de seoane...

Suelo entender algunas códigos.. pero debo admitir que esta parte me dejó mudo.

Código Delphi [-]
case Bitmap1.PixelFormat of
      pf16bit: j:= (Bitmap1.Width*2) -1;
      pf24bit: j:= (Bitmap1.Width*3) -1;
      pf32bit: j:= (Bitmap1.Width*4) -1;
      else j:= Bitmap1.Width -1;
    end;
    for i:= 0 to Bitmap1.Height - 1 do
      if not CompareMem(Bitmap1.ScanLine[i],Bitmap2.ScanLine[i],j) then
        Exit;

En particular... lo que está en rojo. ¿Qué significa la operacion del case? La verdad es que me interesa esto ya que ando viendo cosas sobre tratamiento de imagen para mi tesis.

[[Lepe]]

Delphius el kit de la cuestion es el parámetro "j" que es la longitud a comparar.

si la imagen tienen 16 bit de profundidad, para almacenar un pixel hace falta 2 bytes de memoria (2 bytes x 8 bits = 16 bits).
si la imagen tienen 24 bit de profundidad, para almacenar un pixel hace falta 3 bytes de memoria (3 x 8 = 24).
En el caso de 32 bits... más de lo mismo.

En el "else" estamos diciendo que es de una profundidad de 8 bits (1 byte) o inferior... pero como mínimo necesitamos un byte.

Como la Imagen empieza en el índice cero, hay que restarle uno (se podría sacar fuera del case, ya que siempre se hará .

Saludos

[[seoane]]

La propiedad PixelFormat del bitmap nos indica el formato de la imagen, es decir, el numero de bits que utiliza para representar cada pixel. Necesitamos saber esa información ya que la propiedad Scanline es un puntero, pero no da información sobre el tamaño de la memoria a la que apunta. Para calcularlo multiplicamos el numero de pixels que hay en una linea de la imagen (width) por el numero bytes necesarios para representar cada pixel. Espero haberme explicado

Por ejemplo si la imagen es de 24bits (un formato muy habitual) cada pixel se representa con 3 bytes (RGB). Normalmente cuando trato con imágenes lo que hago es asegurarme de que la imagen tiene el formato pf24bit, asignando ese valor a la propiedad PixelFormat, de esta forma puedo trabajar con cada canal de color por separado sin problemas. En este caso sin embargo, como no se trata de trabajar con la imagen, sino solo de compararlas, evito asignar la propiedad PixelFormat ya que el proceso de conversión de un formato a otro seria una perdida de tiempo, y lo que hago es adaptarme al que ya tiene.

[[Delphius]]

Gracias Lepe y Seoane por aclararmelo.

Conocía bien la propiedad PixelFormat... y lo de los canales RGB (ahorita estoy investigando los otros formatos de representación)... me había llamado la atención aquella operatoria... aquellos valores constantes (2,3 y 4).. para mi eran sacados de la galera....

Gracias nuevamente,