Concatenar CheckBox

[novice]

Gracias por tu respuesta Lepe pero me esta marcando incompatibilidad

[Error] Unit1.pas(35): E2010 Incompatible types: 'TCheckBox' and 'TComponent'

en la linea:

check := Findcomponent('Checkbox'+inttostr(i));

//Este es el codigo
procedure TForm1.FormCreate(Sender: TObject);
var check:TcheckBox;
var i:integer;
begin
for i:=0 to 100 do
begin
check := Findcomponent('Checkbox'+inttostr(i));
if check <> nil then
begin
// codigo trabajo
end;
end;
end;

Tendras alguna sugerencia gracias.

[[maeyanes]]

Trata con esto:

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
var 
  Check: TcheckBox;
  I: Integer;

begin
  for I := 0 to ComponentCount - 1 do
    if Components[i] is TCheckBox then
    begin
      Check := Components[i] as TCheckBox;
      if Check.Checked then
        // codigo trabajo
    end
end;

Saludos...

[roman]

Una pequeña modificación:

En donde dice

Check := Components[i] as TCheckBox;

sería mejor poner

Check := TCheckBox(Components[i]);

El operador as implícitamente hace uso del operador is lo cual es innecesario porque ya se verificó antes.

Y una observación (a ver si repitiendo causa algún efecto): este código de maeyanes es mucho más recomendable que el uso de FindComponent ya que se hace el recorrido de los componentes del formulario una sólo vez y no multiplicado por 100.

// Saludos

[[maeyanes]]

Por cierto, me di cuenta que puse Check := Components[ I ] is TCheckBox en lugar de as... :P

[roman]

Pues no. Veo que ni reiterando quieren omitir el uso de FindComponent.

Una de las pocas (muy pocas) cosas en las que me gustaba más VB son sus arreglos de componentes con lo cual sería mucho más fácil trabajar en estos casos.

Dicha esta barbaridad, veamos cómo podemos arreglárnoslas con Delphi.

En el formulario declaren el arreglo necesitado:

Código Delphi [-]
type
  TForm1 = class(TForm)
  private
    CheckBoxes: array of TCheckBox;
  end;

En el constructor del formulario usen el código de maeyanes pero para llenar el arreglo:

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
var
  I: Integer; // para recorrer los componentes del formulario
  J: Integer; // para indexar el arreglo de check boxes

begin
  SetLength(CheckBoxes, 100);
  J := 0;

  for I := 0 to ComponentCount - 1 do
    if Components[i] is TCheckBox then
    begin
      CheckBoxes[J] := TCheckBox(Components[i]);
      Inc(J);
    end;
end;

Entonces, para el resto de la aplicación se dispondrá de un arreglo de check boxes mucho más fácil de manipular las veces que sea necesario:

Código Delphi [-]
var
  I: Integer;

begin
  for I := Low(CheckBoxes) to High(CheckBoxes) do
    // código para CheckBoxes[i]
end;

// Saludos

[[Lepe]]

Gracias Roman, no sé en que estaba pensando o:

Código Delphi [-]
procedure TForm1.FormCreate(Sender: TObject);
var c:TComponent;
begin

c := Findcomponent('Checkbox'+inttostr(i));
if c <> nil then
begin
  Tcheckbox(c).Propiedades del checkbox
  // codigo trabajo
end;

Solo un detalle.... Estas en el OnCreate del Form, en este evento puede que los checkboxes no se hayan construido

Un saludo

[jachguate]

Empezado por Lepe

Solo un detalle.... Estas en el OnCreate del Form, en este evento puede que los checkboxes no se hayan construido

Cuando el evento onCreate se dispara, ya todo lo que se dejó en el form en tiempo de diseño existe, incluso los apuntadores entre iguales están correctamente establecidos: los datasources apuntaran a los datasets, los dbedits a los fields, etc, etc. suponiendo que todo está en el mismo formulario.

Hasta luego.

[roman]

Empezado por jachguate

Cuando el evento onCreate se dispara, ya todo lo que se dejó en el form en tiempo de diseño existe, incluso los apuntadores entre iguales están correctamente establecidos: los datasources apuntaran a los datasets, los dbedits a los fields, etc, etc.

Suponiendo, si no mal recuerdo, que estamos hablando de Delphi > 3 y que la propiedad OldCreateOrder del formulario no ha sido cambiada a true.

// Saludos

[jachguate]

Empezado por roman

Suponiendo, si no mal recuerdo, que estamos hablando de Delphi > 3 y que la propiedad OldCreateOrder del formulario no ha sido cambiada a true.

// Saludos

Buen punto. En d3 e inferiores, OnCreate se llama dentro del constructor de la forma, y en ese momento ninguno de los componentes contenidos en ella existe.

Hasta luego.

[novice]

Muchas gracias a todos funciono muy bien