pasar valores de variables de un form a otro

[dec]

Hola,

Hay varias formas de conseguir lo que precisas. Puedes declarar las variables del "Form2" como variables públicas, de modo que estén accesibles desde "Form1". También puedes declarar dichas variables como propiedades de "TForm2", de manera que puedas acceder a las mismas, si es que las propiedades son públicas.

Si no lo son, o no quieres que lo sean, siempre puedes emplear algún método público que sirviera para iniciarlizar las propiedades/variables correspondientes desde "Form1". No sé yo si te he resuelto algo o te dejo con más dudas... si las tienes ya sabes que puedes exponerlas por aquí para que alguien trate de echarte una mano.

Un ejemplo utilizando propiedades públicas:

Código Delphi [-]
// Unit1.pas

unit Unit1;

interface

uses
  Forms, Classes, Controls, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses
  Unit2; // TForm2

procedure TForm1.Button1Click(Sender: TObject);
var
  frm: TForm2;
begin
  // Instanciamos
  frm := TForm2.Create(Self);
  {
    Damos el valor que sea menester
    a las propiedades "A" y "B" del
    formulario "TForm2"
  }
  frm.A := 'Una cadena';
  frm.B := 'Otra cadena';

  // Mostramos el formulario (por ejemplo)
  frm.ShowModal;

  // Y, por último, destruimos el objeto "frm"
  frm.Free;
end;

end.

Código Delphi [-]
// Unit2.pas

unit Unit2;

interface

uses
  Forms;

type
  TForm2 = class(TForm)
  private
    {
      Un par de variables privadas
      que almacenarán los valores de
      las propiedades de más abajo.
    }
    FA, FB: string;
  public
    // Propiedades públicas A y B
    property A: string read FA write FA;
    property B: string read FB write FB;
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

end.

[oscarpinog]

david muchas gracias por tu ayuda..

Sabes no entendi como funcionan las propiedades de las variables fa y fb en unit2 y como relaciono eso con un valor (por ejemplo, que provenga de una casilla de texto)

y no entiendo el procedimiento de unit1, que es frm y pq se crea?? que debe hacer en frm.A y frm.B ?? (que aparte no le lo reconoce como bueno en el script)

quede bien mas colgado... sabes donde pueda quiza leer al respecto??

saludos y mucha gracias denuevo.

[nemesio]

Hola

Yo te lo diría de la siguiente forma:

En la seccion var de el Form2, declaras las variables A y B. Luego desde el Form1 para accesarlas escribes: Unit2.A , Unit2.B.
Claro que debes incluir la unit2 en el use de la Unit1.

Suerte.

[oscarpinog]

Hola, Miren coloco esto... y por mas que le doy vueltas, no me pasa el valor de editabout.text hacia editform1.text.. de hecho me borra el contenido original de editform1 y seria todo...
aca va el codigo:

Código Delphi [-]
// codigo de unit1 (programa principal)
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Label1: TLabel;
    Editform1: TEdit;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;
  A,B: String;

implementation

uses about;

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
 frm: Taboutbox;
begin
  frm:= Taboutbox.Create(self);
//  frm.A:= z    ;
//  frm.B:= x    ;

  editform1.text:=frm.A;

  frm.showmodal;
  frm.free;



//aboutbox.ShowModal;
end;

end.

// codigo del about
unit ABOUT;

interface

uses Windows, Classes, Graphics, Forms, Controls, StdCtrls,
  Buttons, ExtCtrls;

type
  TAboutBox = class(TForm)
    Panel1: TPanel;
    OKButton: TButton;
    ProgramIcon: TImage;
    ProductName: TLabel;
    Version: TLabel;
    Copyright: TLabel;
    Comments: TLabel;
    editabout: TEdit;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    Fa, Fb: String;   { Private declarations }
  public
    Property A: String read Fa Write Fa; { Public declarations }
    Property B: String read Fb Write Fb;
  end;

var
  AboutBox: TAboutBox;

implementation

{$R *.dfm}

procedure TAboutBox.Button1Click(Sender: TObject);
begin
A:= editabout.Text ;
end;

end.

Gracias por todo, de verdad se pasaron chiquilllos!

[[Lepe]]

Si lo hace, pero no recoges el valor:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var
frm: Taboutbox;
begin
frm:= Taboutbox.Create(self);
// frm.A:= z ;
// frm.B:= x ;

if frm.showmodal =mrOk then
begin
  editform1.text:=frm.A;
  ShowMessage(editform1);
end;
frm.free;

El punto está que al ser modal, cuando se pulsa en el Button1 (que supongo será un TBitBtn y que devuelve mrOk) es donde se asigna a "A" el valor que debe retornar, por ello tienes que esperar a que se retorne mrOk o bien mrCancel.

Antes de pulsar el botón, la propiedad "A" tendrá un valor indefinido (o por defecto).

Saludos