Como saber si un Formulario ha sido creado

[[maeyanes]]

Tienes varias opciones, aquí te doy unas:

1. Agregar la unidad del formulario N1 a la claúsula uses del formulario padre:

Código Delphi [-]
implementation

uses { Lista de unidades... }, N1Unit;

ya con esto puedes hacer lo que te indican arriba:

Código Delphi [-]
if Assigned(N1) then
  // ...

2. Crear procedimientos o propiedades en el formulario N2 que permitan al formulario padre saber si ya está creado N1:

Código Delphi [-]
TN2 = class(TForm)
private
  //...
protected
  //...
public
  function IsN1Created: Boolean;
  procedure SetFileNameN1(const AFileName: string);
end;

implementation

uses N1Unit;

function TN2.IsN1Created: Boolean;
begin
  Result := Assigned(N1)
end;

procedure TN2.SetFileNameN1(const AFileName: string);
begin
  if IsN1Created then
    N1.Labe1.Caption := AFileName
end;

y desde el formulario padre:

Código Delphi [-]
begin
  if N2.IsN1Created then
    N2.SetFileNameN1(FileBox1.FileName);
  //...
end;

Espero que algo de esto te sirva...



Saludos...

[Durbed]

Ninguna de esas soluciones me funciono, gracias de todas formas, al final lo he conseguido con dos variables y un timer, asi cuando creo la ventana hija el timer empieza a comprobar en la variables (Estan en una unidad comun a toda la aplicacion) si la ruta del fichero se ha actualizado.

Un saludo y gracias.

[rounin]

Saludos,

Si solo un exemplar de TN1 puede existir,
deja la clase TN1 ser responsable de la existencia de exemplar.

if TN1.IsExemplarCreate then ...
//TN1.UniqueExemplar.DoSomething;

Código Delphi [-]
 
 
type
  TN1 = class(TForm)
  private
    { Private declarations }
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    class function UniqueExemplar: TN1;
    class function IsExemplarCreated: Boolean;
  end;
 
//var
// N1: TN1;
 
implementation
{$R *.dfm}
 
var
  theUniqueExemplar: TN1;
 
constructor TN1.Create(AOwner: TComponent);
begin
  inherited;
  if theUniqueExemplar = nil then
    theUniqueExemplar := Self else
    raise Exception.Create('Only one exemplar of TN1 is allowed');
end;
 
destructor TN1.Destroy;
begin
  theUniqueExemplar := nil;
  inherited;
end;
 
class function TN1.IsExemplarCreated: Boolean;
begin
  Result := Assigned(theUniqueExemplar);
end;
 
class function TN1.UniqueExemplar: TN1;
begin
  if not IsExemplarCreated then {theUniqueExemplar := } TN1.Create(Application);
  Result := theUniqueExemplar;
end;

PS Es no buen estilo usar variables globales para
MDI-formularios, porque frequente hay mas que un ejemplar.