Cerrar aplicacion y a la vez executar otra.

[lgarcia]

Hola:

Estoy trabajando en un actualizador de programas, que consta de 2 programas, el 1ro que es el principal que cuando el usuario se autentifica hace un chequeo de la version y si esta es menor te envia un mensaje de aviso se cierra y mandar a ejecutar el actualizador, que lo que hace es copiar desde un Path la nueva version para el directorio de trabajo. El actualizador solo trabaja perfectamente. Pero cuando cierro el programa se levanta el actualizador pero se cae sin terminar de actualizar. Esre es el codigo. Utilizo Deplhi 7.

Código Delphi [-]
  numero:= 110;
  with Version do
  begin
     Close;
     Open;
  end;
  if numero < Versionnumero.Value then
   begin
      ShowMessage('There is a new Version of the software' + chr(13) + 'The program will close to update it');
      Close;
      WinExec(PChar('C:\Ezdealers\Updater\Actualizador.exe'),SW_SHOWNORMAL);
   end
   else
      try
        Application.CreateForm(TFormMain, FormMain);
        FormMain.ShowModal;
     finally
       FormMain.Free;
    end;

Saludos
Luis Garcia

[ecfisa]

Hola lgarcia.

En la parte del código que mostras, la línea de WinExec nunca se ejecuta ya que llamas al método Close en la línea previa.

De todos modos pienso que es el programa actualizador quién debería evaluar la versión y de ser necesario, realizar las tareas de actualización.

Saludos

[lgarcia]

Muchas gracias eficsa por tu respuesta, con relacion a lo que me recomiendas de que el actualizador es el que debia lanzarse 1ro, el problemas es que la comparacion del numero de la version es a traves de una consulta a una tabla de la BD, por lo que antes necesito autenticarme para comprobar las versiones.

[ecfisa]

Hola lgarcia.

Empezado por lgarcia

..., el problemas es que la comparacion del numero de la version es a traves de una consulta a una tabla de la BD, por lo que antes necesito autenticarme para comprobar las versiones.

Entonces podrías verificar la versión y de ser necesario llamar al actualizador para que este último la cierre, la actualize y luego vuelva a ejecutarla. Eso sí, deberá autenticarse nuevamente...

Saludos

[Neftali [Germán.Estévez]]

Empezado por ecfisa

En la parte del código que mostras, la línea de WinExec nunca se ejecuta ya que llamas al método Close en la línea previa.

Yo creo que no.
El Close, realiza las tareas necesarias para cerrar el formulario, pero no detiene la ejecución del código.

Creo que en muchos casos (si no en todos) el WinExec sí se ejecuta.

Basta con poner un botón con el siguiente código:

Código Delphi [-]
    ShowMessage('There is a new Version of the software' + chr(13) + 'The program will close to update it');
    Close;
    WinExec(PChar('notepad.exe'), SW_SHOWNORMAL);

Y veremos que el Notepad se abre.

[Neftali [Germán.Estévez]]

Empezado por lgarcia

El actualizador solo trabaja perfectamente. Pero cuando cierro el programa se levanta el actualizador pero se cae sin terminar de actualizar. Esre es el codigo. Utilizo Deplhi 7.

Entonces el problema está en el actualizador, el código que pones está funcionando correctamente, pues el actualizador se abre.
Deberías explicar mejor que hace este segundo programa.

¿Es posible que el actualizador haga alguna operación y el programa principal todavía esté funcionando y por eso falla?

[lgarcia]

gracias por la respuesta Neftali

el codigo del actualizador es el siguiente:

Código Delphi [-]
procedure TFormMain.FormActivate(Sender: TObject);
begin
  CopyFile(Pchar('\\192.168.0.25\Upload\EZDealers.exe'), Pchar('C:\Ezdealers\EZDealers.exe'), False);
  Close;
  WinExec(PChar('C:\Ezdealers\EZDealers.exe'),SW_SHOWNORMAL);
end;

Saludos
Luis

[Neftali [Germán.Estévez]]

Añádele un try..except para detectar posibles problemas.
Algo Así:

Código Delphi [-]
procedure TFormMain.FormActivate(Sender: TObject);
begin
  try
     If CopyFile(Pchar('\\192.168.0.25\Upload\EZDealers.exe'), Pchar('C:\Ezdealers\EZDealers.exe'), False) then
       ShowMessage('Copia correcta')
     else
       RaiseLastOSError;
     
     Close;
     WinExec(PChar('C:\Ezdealers\EZDealers.exe'),SW_SHOWNORMAL);
  except
    on E:Exception do begin
      MessageDlg('Error al actualizar; ' + E.Message, mtError, [mbOK], 0);
    end;
  end;
end;

[Neftali [Germán.Estévez]]

A ver si te levanta algún error.

[lgarcia]

ok, voy a probar.

[ecfisa]

Hola lgarcia.

Si entendí bien, deseas copiar otra version de la aplicación llamando desde esta misma a un actualizador que sobreescribirá una nueva versión de la misma.

El problema es, que mientras la aplicación se esté ejecutando, el s.o. no permitirá que sobreescribas su archivo ejecutable. Y por otro lado, no veo manera que la aplicación ejecute al actualizador cuando no se está ejecutando (ya esta cerrada).

Yo me refería a que hicieras algo parecido a este ejemplo,

Aplicación:

Código Delphi [-]
...
implementation

uses ShellApi;

function NecesitaActualizar(): Boolean;
begin
  // verificar si necesita actualizar
  Result:= True;
end;

procedure TForm1.btnActualizarClick(Sender: TObject);
begin
  if NecesitaActualizar() then
  begin
    // Cerrar y/o liberar lo necesario
    ShellExecute(Handle,
                 'open',
                 'Actualizador.exe',
                 nil,
                 nil,
                 SW_SHOWNORMAL);
  end;
end;
...

Actualizador:

Código Delphi [-]
...
implementation 

uses tlhelp32, ShellApi;

procedure CloseApplication(const ExeFileName: string);
var
  Entry: PROCESSENTRY32;
  hSnapShot, hProcess: THandle;
begin
  hSnapShot:= CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  Entry.dwSize:= SizeOf(PROCESSENTRY32);
  if Process32First(hSnapShot, Entry) then
    while Process32Next(hSnapShot, Entry) do
      if Entry.szExeFile = ExeFileName then
      begin
        hProcess := OpenProcess(SYNCHRONIZE + PROCESS_TERMINATE,
                                False,
                                Entry.th32ProcessID);
        if hProcess <> 0 then
          TerminateProcess(hProcess, 0);
        CloseHandle(hProcess);
      end;
end;

procedure Actualizar;
begin
  // aquí iría el proceso de actualización
  Sleep(4000); 
  ShowMessage('Actualización terminada');
end;

procedure TForm1.FormActivate(Sender: TObject);
begin
  CloseApplication('Aplicacion.exe');
  Actualizar;
  ShellExecute(Handle,
               'open',
               'Aplicacion.exe',
               nil,
               nil,
               SW_SHOWNORMAL);
  Close;
end;
...

Saludos

[lgarcia]

Todo quedo Estelar con la última contribución de Ecfisa.

Muchas gracias a todos y saludos.

Saludos
Luis Garcia