[ecfisa]

Hola wile777.

Empezado por wile777

...y yo lo que quiero es que me busque coincidencias con el numero que ponga en el TEdit.. como hago?

Código Delphi [-]
..
procedure TForm1.FormCreate(Sender: TObject);
begin
   ADOTable1.Open;
end;

(* Busca un dato por igualdad sobre la columna indicada por el parámetro aFieldName 
   basado en el valor indicado por el parámetro aValue *)
procedure TForm1.SearchData(const aFieldName, aValue: string);
begin
  if not ADOTable1.Locate(aFieldName , aValue,[]) then
   MessageBox(0,'El dato buscado no se encontró', 'AVISO',MB_ICONWARNING)
end;

(* Filtra la tabla por los caracteres consecutivos coincidentes de la columna aFieldName,
    basado en el valor enviado en el parámetro aValue *)
procedure TForm1.FilterData(const aFieldName, aValue: string);
begin
  with ADOTable1 do
  begin
    Filtered:= False;
    Filter  := Format('(%s LIKE ''%s*'')', [aFieldName, aValue]);
    Filtered:= True;
    if RecordCount = 0 then
    begin
      Filtered:= False;
      MessageBox(0, 'El dato ingresado no se encontró', 'AVISO', MB_ICONWARNING)
    end
  end
end;
...

Ejemplo del uso:

Código Delphi [-]
...
procedure TForm1.btnSearchOneClick(Sender: TObject);
begin
  SearchData('TELEFONO', Edit1.Text);
end;

procedure TForm1.ButtonFilterClick(Sender: TObject);
begin
   FilterData('DIRECCION', Edit1.Text)
end;

(* Elimina cualquier filtro prefijado *)
procedure TForm1.btnFilterOffClick(Sender: TObject);
begin
  ADOTable1.Filtered:= False
end;
...

Tema aparte: No olvides encerrar el código Delphi de tus mensajes entre etiquetas: [delphi] tu_codigo [/delphi], de ese modo es mucho mas fácil de leer (ya las agregué a tu mensaje).

Saludos