[ecfisa]

Hola franco_cvm

Empezado por franco_cvm

Quisiera que me digan por que mi razonamiento en el boton2 esta mal

Por que tomas un mínimo antes de entrar a los ciclos, cuando tendrías que hacerlo una vez por cada fila. Te hice un código de ejemplo comentado para que puedas analizarlo:

Código Delphi [-]
const
  MAX_COL = 10;
  MAX_ROW =  6;

type
  TMatriz = array [1..MAX_COL, 1..MAX_ROW] of Integer;

var
  Matriz: TMatriz;

procedure TForm1.FormCreate(Sender: TObject);
var
  c, r : Integer;
begin
  // inicializar el generador aleatorio
  Randomize();
  // darle al StringGrid el espacio necesario para visualizar
  StringGrid1.ColCount := MAX_COL;
  StringGrid1.RowCount := MAX_ROW;
  // carga
  for r := 1 to MAX_ROW do
   for c := 1 to MAX_COL do
   begin
     Matriz[c, r] := Random(99) + 1;
     StringGrid1.Cells[c-1, r-1] := IntToStr(Matriz[c, r]); // visualizar
   end;
  Memo1.Clear; // limpiar memo
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  c, r, Minimo: Integer;
begin
  for r := 1 to MAX_ROW do    // recorrer las filas
  begin
    Minimo := Matriz[1, r];   // Minimo es la 1er columna
    for c := 2 to MAX_COL do  // recorrer desde la 2da col. hasta la última
      if Matriz[c, r] < Minimo then   // si Matriz[c, r] menor a Minimo,
        Minimo := Matriz[c, r];       // Matriz[c, r] es ahora el minimo
    Memo1.Lines.Add(IntToStr(Minimo));// mostrar
  end;
end;

Saludos