[Neftali [Germán.Estévez]]

Bueno, se pueden hacer cosas básicas; Cambiar algunas propiedades y ñadir algunos controles nuevos, pero si tienes que cambiar demasiado, tal vez es mejor que te crees un formulario personalizado.

Por ejemplo, con esto muestras un dialogo "estandard":

Código Delphi [-]
procedure TForm1.Button4Click(Sender: TObject);
var
  AMsgDialog: TForm;
  res:TModalresult;
begin
  AMsgDialog := CreateMessageDialog('Mensaje de prueba...', mtWarning, [mbYes, mbNo]) ;
  res := AMsgDialog.ShowModal;
end;

Con este código puedes apreciar algunos cambios, incluso puedes añadir algun componente nuevo (en este caso un checkbox):

Código Delphi [-]
procedure TForm1.Button2Click(Sender: TObject);
var
  AMsgDialog: TForm;
  res:TmodalResult;
  lbl:Tlabel;
  btn:TButton;
  img:TImage;
  chk:TCheckBox;
begin
  AMsgDialog := CreateMessageDialog('Mensaje de prueba...', mtWarning, [mbYes, mbNo]) ;
  AMsgDialog.Caption := 'Cambiando título...' ;

  // Cambiar el ancho
  AMsgDialog.Width := AMsgDialog.Width * 2;

  // Modificar el Label
  lbl := TLabel(AMsgDialog.FindComponent('Message'));
  lbl.Font.Style := lbl.Font.Style + [fsItalic];
  lbl.Font.Color := clRed;

  // Modificar el YES
  btn := TButton(AMsgDialog.FindComponent('YES'));
  btn.Font.Style := btn.Font.Style + [fsBold];

  // Modificar la imagen
  img := TImage(AMsgDialog.FindComponent('Image'));
  img.Stretch := true;
  img.Picture.LoadFromFile('r:\neftali.bmp');

  // Añadir un CheckBox
  chk := TCheckBox.Create(AMsgDialog);
  chk.Parent := AMsgDialog;
  chk.Caption := 'No volver a &recordarmelo.';
  chk.Width := 200;
  AMsgDialog.Height := AMsgDialog.Height + 30;
  chk.Left := 15;
  chk.Top := AMsgDialog.Height - 20 - 30;


  res := AMsgDialog.ShowModal;

  AMsgDialog.Free;

end;