[marcoszorrilla]

Bueno por si acaso la tabla fuera Paradox, y sería un cargo de conciencia que divorciaras por semejante caso.

Accessing Paradox Tables on CD or Read-Only Drive - by Borland Developer Support Staff

Technical Information Database

TI1333D.txt Accessing Paradox Tables on CD or Read-Only Drive
Category atabase Programming
Platform :All
Product elphi All

Description:
This Technical Information document will step through the concepts
regarding accessing Paradox tables which are located on a CD-ROM or
any read-only device.

The Paradox locking scheme requires the existence of a PDOXUSRS.LCK
file to handle its locking logic. This file is generally created at
run-time and resides in the directory which also contains the tables.
However, with a CD-ROM there is not a way to create this file at
run-time on the CD-ROM. The solution is simple, we create this file
and put it on the CD-ROM when the CD is pressed. The following steps
will give you a very simple utility program for creating the
PDOXUSRS.LCK file which you will then copy to the CD-ROM image.

1. Starting with a blank project add the following components: TEdit,
TButton and TDatabase.


2. In the OnClick event for the button use the following code:

   procedure TForm1.Button1Click(Sender: TObject);
   begin
     if ChkPath then
       Check(DbiAcqPersistTableLock(Database1.Handle,
                  'PARADOX.DRO','PARADOX'));
   end;


   3. The ChkPath function is a user defined method of the form. It will 
   simply check the path entered in the Edit box and make sure it exists. 
   Here is the function:

   function TForm1.ChkPath : Boolean;
   var
     s : array[0..100] of char;
   begin
     If DirectoryExists(Edit1.Text) then begin
       DataBase1.DatabaseName:= 'TempDB';
       DataBase1.DriverName:= 'Standard';
       DataBase1.LoginPrompt:= false;
       DataBase1.Connected := False;
       DataBase1.Params.Add('Path=' + Edit1.Text);
       DataBase1.Connected := TRUE;
       Result := TRUE;
     end
     else begin
       StrPCopy(s,'Directory : ' + Edit1.text + ' Does Not Exist');
       Application.MessageBox(s, 'Error!', MB_ICONSTOP);
       Result := FALSE;
     end;
   end;

   { Note: Don't forget to put the function header in the public section 
           of the form.}


   4. There is one more thing you need to add before compiling, in the 
   Uses statement at the top of the unit add the following units: 
     Delphi 1.0: FileCtrl, DbiProcs, DbiTypes, DbiErrs.
     Delphi 2.0: FileCtrl , BDE


   When you have compiled and executed the utility program, it will 
   create two files in the directory you specified. The two files created 
   are: PDOXUSRS.LCK and PARADOX.LCK. 

   Note: The PARADOX.LCK file is only necessary when accessing Paradox for 
   DOS tables so you can delete it. 


   5. The only thing left for you to do is copy the remaining file 
   (PDOXUSRS.LCK) to the CD-ROM image. Of course your tables will be 
   Read-Only. 

   Note: If you want to clean up this utility for future use, you can 
   change the text property of the Edit box to be some default directory 
   and change the Caption property of the Button to be something more 
   meaningful.


   Here is the final version of the code:

   unit Unit1;

   interface

   uses
     Windows, Messages, SysUtils, Classes, Graphics, Controls, 
     Forms, Dialogs,  DB, StdCtrls, FileCtrl,

     {$IFDEF WIN32}
       BDE;
     {$ELSE}
       DbiProcs, DbiTypes, DbiErrs;
     {$ENDIF }


   type
     TForm1 = class(TForm)
       Edit1: TEdit;
       Button1: TButton;
       Database1: TDatabase;
       procedure Button1Click(Sender: TObject);
     private
       { Private declarations }
     public
       { Public declarations }
       function ChkPath : Boolean;
     end;

   var
     Form1: TForm1;

   implementation

   {$R *.DFM}

   function TForm1.ChkPath : Boolean;
   var
     s : array[0..100] of char;
   begin
     If DirectoryExists(Edit1.Text) then begin
       DataBase1.DatabaseName:= 'TempDB';
       DataBase1.DriverName:= 'Standard';
       DataBase1.LoginPrompt:= false;
       DataBase1.Connected := False;
       DataBase1.Params.Add('Path=' + Edit1.Text);
       DataBase1.Connected := TRUE;
       Result := TRUE;
     end
     else begin
       StrPCopy(s,'Directory : ' + Edit1.text + ' Does Not Exist');
       Application.MessageBox(s, 'Error!', MB_ICONSTOP);
       Result := FALSE;
     end;
   end;

   procedure TForm1.Button1Click(Sender: TObject);
   begin
     if ChkPath then
       Check(DbiAcqPersistTableLock(Database1.Handle,
                  'PARADOX.DRO','PARADOX'));
   end;

   end.

Un Saludo.