Guardar ICOs en BlOB y después recuperarlos

[Aprendiz]

Hola a todos

Resumo el problema. Tengo una base de datos donde se guardan un campo BLOB que corresponde a iconos que quiero que se muestren en un menú de diferentes aplicaciones.

Posteriormente estas imágenes son leidas directamente de la base de datos con una consulta y asignando el campo obtenido a un DBImage.

El problema radica en que el BLOB, que gestiono mediante una pantalla con otro DBImage solo acepta que recupere en este componentes fichero .bmp y no acepta ICOs. A mi me interesa tener ICOs para cuando los recupero en el menú mediante el componente TDBImage no se produzca ese efecto tan desagradable que es que el fondo de la imagen sea de un color diferente al fondo de la aplicación.

Alguien tiene alguna pista de como se podría hacer esto.

Gracias por adelantado.

Saludos

[roman]

Empezado por Aprendiz

Alguien tiene alguna pista de como se podría hacer esto.

Un campo blob puedes pasarlo a un Stream: TBlobField.SaveToStream y un icono lo puedes cargar desde un stream: TIcon.LoadFromStream. Así que, a falta de otra cosa más sencilla puedes usar un TMemoryStream paa pasar el Blob a un Icon.

// Saludos

[Aprendiz]

Sí ya había visto el procedimiento pero no me sirve, al menos según me ha parecido.

A la hora de guardar la imagen en la base de datos hago algo así:

var
  Icono: TIcon;
  Stream: TMemoryStream;
begin
      if Taula.State=dsBrowse then Taula.Edit;
      //Creación del objeto Icono
      Icono := TIcon.Create();
      //Recuperación del objeto Icono
      Icono.LoadFromFile(opdImagen.Filename);
      //Creación del Stream
      Stream:=TMemoryStream.Create();
      //Salvamos el Icono al Stream
      Icono.SaveToStream(Stream);
      //Cargamos la imagen seleccionada del Stream
      TaulaIMAGEN.LoadFromStream(Stream);
...
end;

Esto produce un error del tipo "Bitmap is nos valid", como si solo aceptase BMPs, cosa que según la ayuda no debería ser, y puede aceptar ICOs y Metafiles.

Alguna idea?

Saludos

[roman]

Pero ¿qué es TAulaIMAGEN? ¿Un TDBImage? Pero el TDBImage no tiene este método ¿o sí? Y si es un TDBImage ¿no tendría que ser

TAulaIMAGEN.Picture.Icon.LoadFromStream?

Y por cierto, ¿qué base estás usando? Por ejemplo en Paradox, a pesar de que el TDBImage puede cargar un icono, el campo Graphic no así que de poco sirve el TDBImage.

// Saludos

[Aprendiz]

TaulaImagen es un campo llamado "IMAGEN" del tipo TBlobField que pertenece a la tabla "Taula".

El método que comentas para los dbimages es correcto, funciona. Pero lo malo que tiene es que cuando haces un POST de la tabla que contiene el campo al que está enlazado el DBImage no se guarda la imagen del Icono que has recuperado sobre el DBImage.

Como base de datos, perdona no me di cuenta que no lo había comentado, utilizo Interbase 6.0.

Saludos

[roman]

Desconozco si puede usarse directamente un TDBImage. Haciendo unas pruebas en FireBird he podido guardar y leer iconos pero mostrándolos en un TImage.

Para guardar un icono:

Código Delphi [-]
var
  Stream: TMemoryStream;

begin
  if OpenPictureDialog1.Execute then
  begin
    Image1.Picture.Icon.LoadFromFile(OpenPictureDialog1.FileName);

    Stream := TMemoryStream.Create;
    try
      Image1.Picture.Icon.SaveToStream(Stream);

      Taula.Append;
      TaulaIMAGEN.LoadFromStream(Stream);
      Taula.Post;
    finally
      Stream.Free;
    end;
  end;
end;

Para cargar el icono uso el evento AfterScroll de Taula:

Código Delphi [-]
var
  Stream: TMemoryStream;

begin
  Stream := TMemoryStream.Create;

  try
    TaulaIMAGEN.SaveToStream(Stream);
    Stream.Seek(0, soFromBeginning);
    Image1.Picture.Icon.LoadFromStream(Stream);
  finally
    Stream.Free;
  end;
end;

// Saludos

[paren]

Yo uso delphi 5.0 con Interbase 6.0

Puse dos TDBLookUpComboBox uno para seleccionar a un cliente o persona a la que se le guardaron las imagenes
El otro es para seleccionar las imagen que queremos ver

Para desplegarla use un TImage

Ademas use los componentes GraphicEx, QCadDraw que la verdad no recuerdo de donde los baje, pero de GraphicEx encontre la liga en estos foros

Espero que les sirva, perdon por no comentarlo, si quieren el fuente pos ahi me avisan

Código Delphi [-]
 uses
   Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
   ExtCtrls, FileCtrl, StdCtrls, ComCtrls, ToolWin, Menus, DBCtrls, Db,
   ImgList, JPEG, GraphicEx, QCadDraw;
 
 
 ....
 type
   TfrmPrincipal = class(TForm)
     imgImagen: TImage;
     cdrwImagenCad: TCadDraw;
 ....
 
 
 procedure TfrmPrincipal.dblucbxDescripcionClick(Sender: TObject);
 Var
  Jpeg : TJpegImage;
  Gif : TGIFGraphic;
  Png : TPNGGraphic;
  Tif : TTIFFGraphic;
  Corriente : TMemoryStream;
  Buffer : Word;
  ImagenValida : Boolean;
 begin
  ImagenValida := True;
  imgImagen.Picture.Graphic := Nil;
  If dtamdlDatos.qryImagenIMAGEN.BlobSize > 0 Then
  Begin
   Corriente := TMemoryStream.Create;
   Try
    dtamdlDatos.qryImagenIMAGEN.SaveToStream(Corriente);
    Corriente.Seek(0,soFromBeginning);
    If Corriente.Read(Buffer, 2) > 0 Then
    Begin
     Corriente.Seek(0,soFromBeginning);
     If (Buffer = $2020) Or (Buffer = $3A44) Or (Buffer = $4956) Then
     Begin
      cdrwImagenCad.Visible := True;
      cdrwImagenCad.ZoomAll;
      tbtnEstirar.Enabled := False;
      imgImagen.Visible := False;
     End
     Else
     Begin
      tbtnEstirar.Enabled := True;
      cdrwImagenCad.Visible := False;
      imgImagen.Visible := True;
     End;
     Case Buffer Of
      $4D42 : imgImagen.Picture.Bitmap.LoadFromStream(Corriente); //Imagen BMP
      $0000 : imgImagen.Picture.Icon.LoadFromStream(Corriente); //Imagen ICO
      $0001 : imgImagen.Picture.Metafile.LoadFromStream(Corriente); //Imagen EMF
      $CDD7 : imgImagen.Picture.Metafile.LoadFromStream(Corriente); //Imagen WMF
      $D8FF : //Imagen JPG, JPEG
      Begin
       Jpeg := TJpegImage.Create;
       Jpeg.LoadFromStream(Corriente);
       imgImagen.Picture.Assign(Jpeg);
       Jpeg.Free;
      End;
      $4947 : //Imagen GIF
      Begin
       Gif := TGifGraphic.Create;
       Gif.LoadFromStream(Corriente);
       imgImagen.Picture.Assign(Gif);
       Gif.Free;
      End;
      $4949 : //Imagen TIF, TIFF
      Begin
       Tif := TTIFFGraphic.Create;
       Tif.LoadFromStream(Corriente);
       imgImagen.Picture.Assign(Tif);
       Tif.Free;
      End;
      $5089 : //Imagen PNG
      Begin
       Png := TPNGGraphic.Create;
       Png.LoadFromStream(Corriente);
       imgImagen.Picture.Assign(Png);
       Png.Free;
      End;
      $4956 : //Imagen CDL
      Begin
       cdrwImagenCad.CadType := 1;
       Corriente.SaveToFile(ExtractFilePath(ParamStr(0)) + 'imgtmp.cdl');
       cdrwImagenCad.LoadFromFile(ExtractFilePath(ParamStr(0)) + 'imgtmp.cdl');
       If FileExists(ExtractFilePath(ParamStr(0)) + 'imgtmp.cdl')
       Then DeleteFile(ExtractFilePath(ParamStr(0)) + 'imgtmp.cdl');
      End;
      $2020 : //Imagen DXF
      Begin
       cdrwImagenCad.CadType := 2;
       Corriente.SaveToFile(ExtractFilePath(ParamStr(0)) + 'imgtmp.dxf');
       cdrwImagenCad.LoadFromFile(ExtractFilePath(ParamStr(0)) + 'imgtmp.dxf');
       If FileExists(ExtractFilePath(ParamStr(0)) + 'imgtmp.dxf')
       Then DeleteFile(ExtractFilePath(ParamStr(0)) + 'imgtmp.dxf');
      End;
      $3A44 : //Imagen IGS
      Begin
       cdrwImagenCad.CadType := 3;
       Corriente.SaveToFile(ExtractFilePath(ParamStr(0)) + 'imgtmp.igs');
       cdrwImagenCad.LoadFromFile(ExtractFilePath(ParamStr(0)) + 'imgtmp.igs');
       If FileExists(ExtractFilePath(ParamStr(0)) + 'imgtmp.igs')
       Then DeleteFile(ExtractFilePath(ParamStr(0)) + 'imgtmp.igs');
      End;
      Else
      Begin
       imgImagen.Picture.Graphic := Nil;
       ImagenValida := False;
      End;
     End;
     If ImagenValida
     Then stbrBarraEstado.Panels[1].Text := Format('%d x %d', [imgImagen.Picture.Width, imgImagen.Picture.Height])
     Else stbrBarraEstado.Panels[1].Text := 'Formato de Imagen Invalido';
     If stbrBarraEstado.Panels[1].Text = '0 x 0'
     Then stbrBarraEstado.Panels[1].Text := 'Imagen CAD';
    End;
   Finally
    Corriente.Free;
   End;
  End;
 end;

[Aprendiz]

Hola a todos,

Bueno, el problema que tenía yo es que quería el fondo de los Bitmaps transparentes, para un menú, y por eso quería guardar los ICOs. Finalmente y como todo lo dicho hasta ahora es más que válido pero quizás complicarse, en mi caso para el aplicativo que desarrollo, demasiado he obtado por una solución intermedia y rápida.

  

  DBImage1.Picture.Bitmap.Transparent:=True;
  DBImage1.Picture.Bitmap.TransparentMode:=tmAuto;
  DBImage1.Picture.Bitmap.TransparentColor:=Self.DBImage1.Picture.BitMap.canvas.pixels[1,1]

Establezco mo transparente un color del Bitmap y palante.

Gracias a todos

[Delfino]

pq no revisas este hilo? http://www.clubdelphi.com/foros/show...highlight=blob