Ley antifraude 2021 (VERIFACTU) - Programas informáticos

[ermendalenda]

Empezado por Neftali [Germán.Estévez]

Acaban de publicar esto (25/20/2024 14:06):

VERI*FACTU - Actualización esquemas XSD de sistemas VERI*FACTU
----------------------------------------------------------------------------------------------------------
A peticiones de varias empresas desarrolladoras y habiéndose estudiado por parte del DIT-AEAT, se ha modificado levemente la estructura de los esquemas XSD, entendiéndose la necesidad de generar y realizar validaciones registros de facturación de forma independientemente, sin necesidad de incluirlos en un envío para ello. El esquema actual no permitía dicha posibilidad.
El cambio supone tan solo un cambio en el namespace de alguno de los nodos XML que forman parte de los esquemas (Cabecera, RegistroAlta y RegistroAnulacion). Con el cambio realizado los esquemas dan cabida a este requisito y son más fácilmente comprensibles.
También se incluye un cambio en la respuesta de las remisiones en el formato del campo TimestampPresentacion, añadiendo el huso horario de los servidores de la AEAT.
Estos cambios no afectan a la información necesaria para la remisión de registros de facturación, pero puede requerir de algún ajuste en los sistemas informáticos de facturación para poder seguir operando con el sistema VERI*FACTU.


La url es esta, que con el sistema de publicación que tienen, los ficheros estarán por ahí...
https://www.agenciatributaria.es/AEA...ERI_FACTU.html


Actualizo el mensaje#1

Si alguno puede traducir donde se produce el cambio, a nivel del xml, se lo agradeceria, ya que yo genero los xlm a pelo y me cuesta muchisimo leer el xsd

[novatico]

Empezado por ermendalenda

Si alguno puede traducir donde se produce el cambio, a nivel del xml, se lo agradeceria, ya que yo genero los xlm a pelo y me cuesta muchisimo leer el xsd

Si, lo que han cambiado es que, en algunos nodos pasa de "sum" a "sum1" y viceversa.
Por ejemplo:
- la cabecera antes era "<sum1:Cabecera>" uy ahora es "<sum:Cabecera>"
- "RegistroAlta" justo al reves,

y sigo mirando.

Uno más:
- "<sum:RegistroAnulacion>" pasa a "<sum1:RegistroAnulacion>"

[ermendalenda]

Empezado por novatico

Si, lo que han cambiado es que, en algunos nodos pasa de "sum" a "sum1" y viceversa.
Por ejemplo:
- la cabecera antes era "<sum1:Cabecera>" uy ahora es "<sum:Cabecera>"
- "RegistroAlta" justo al reves,

y sigo mirando.

Uno más:
- "<sum:RegistroAnulacion>" pasa a "<sum1:RegistroAnulacion>"

Ok muchas Gracias
Pero aún no lo deben haber actualizado, por que me da error.

[novatico]

Empezado por ermendalenda

Ok muchas Gracias
Pero aún no lo deben haber actualizado, por que me da error.

Acabo de probar con lo antiguo y funciona bien.

Ahora probaré cambiando.

Pues de momento, con lo nuevo falla.

[ermendalenda]

Empezado por novatico

Acabo de probar con lo antiguo y funciona bien.

Ahora probaré cambiando.

Pues de momento, con lo nuevo falla.

Ok, pero gracias, ya he tomado nota. habrá que esperar que lo pongan en el apartado de desarrolladores, de momento no se ven cambios.

[novatico]

Empezado por ermendalenda

Ok, pero gracias, ya he tomado nota. habrá que esperar que lo pongan en el apartado de desarrolladores, de momento no se ven cambios.

Yo solo lo he notado comparando el nuevo xsd con el antiguo.

[bmfranky]

An cambiado algunas chorradas, por ejemplo antes Se llamaba -> ahora.

Cabecera -> CabeceraType
CabeceraRemisionVoluntaria -> CabeceraTypeRemisionVoluntaria
CabeceraRemisionRequerimiento -> CabeceraTypeRemisionRequerimiento.
Han cambiado los namespaces generados en la importacion.


Xml Generado y enviado.

<?xml version="1.0" encoding="utf-16"?>
<RegFactuSistemaFacturacion xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
<Cabecera xmlns="https://www2.agenciatributaria.gob.es/static_files/common/internet/dep/aplicaciones/es/aeat/tike/cont/ws/SuministroLR.xsd">
<ObligadoEmision xmlns="https://www2.agenciatributaria.gob.es/static_files/common/internet/dep/aplicaciones/es/aeat/tike/cont/ws/SuministroInformacion.xsd">
<NombreRazon>OBLIGADO</NombreRazon>
<NIF>XXNIFXX</NIF>
</ObligadoEmision>
<RemisionVoluntaria xmlns="https://www2.agenciatributaria.gob.es/static_files/common/internet/dep/aplicaciones/es/aeat/tike/cont/ws/SuministroInformacion.xsd">
<FechaFinVeriFactu />
<Incidencia>N</Incidencia>
</RemisionVoluntaria>
</Cabecera>
<RegistroFactura xmlns="https://www2.agenciatributaria.gob.es/static_files/common/internet/dep/aplicaciones/es/aeat/tike/cont/ws/SuministroLR.xsd">
<RegistroAlta xmlns="https://www2.agenciatributaria.gob.es/static_files/common/internet/dep/aplicaciones/es/aeat/tike/cont/ws/SuministroInformacion.xsd">
<IDVersion>1.0</IDVersion>
<IDFactura>
<IDEmisorFactura>XXNIFXX</IDEmisorFactura>
<NumSerieFactura>VC1-24-100011</NumSerieFactura>
<FechaExpedicionFactura>25/10/2024</FechaExpedicionFactura>
</IDFactura>
<NombreRazonEmisor>OBLIGADO</NombreRazonEmisor>
<TipoFactura>F2</TipoFactura>
<FechaOperacion>25-10-2024</FechaOperacion>
<DescripcionOperacion>Venta de materiales servidos cliente contado.</DescripcionOperacion>
<Desglose>
<DetalleDesglose>
<ClaveRegimen>01</ClaveRegimen>
<CalificacionOperacion>S1</CalificacionOperacion>
<TipoImpositivo>21.00</TipoImpositivo>
<BaseImponibleOimporteNoSujeto>12.23</BaseImponibleOimporteNoSujeto>
<CuotaRepercutida>2.57</CuotaRepercutida>
</DetalleDesglose>
</Desglose>
<CuotaTotal>2.57</CuotaTotal>
<ImporteTotal>14.80</ImporteTotal>
<Encadenamiento>
<RegistroAnterior>
<IDEmisorFactura>XXNIFXX</IDEmisorFactura>
<NumSerieFactura>VC1-24-100010</NumSerieFactura>
<FechaExpedicionFactura>22-10-2024</FechaExpedicionFactura>
<Huella>FF2116821784D657D18CAF5EE5FD3B61E480EBE3187415DFB8E4F52A335692D3</Huella>
</RegistroAnterior>
</Encadenamiento>
<SistemaInformatico>
<NombreRazon>Yo mismo</NombreRazon>
<NIF>Mi Nif</NIF>
<NombreSistemaInformatico>Facturas Taller 2024</NombreSistemaInformatico>
<IdSistemaInformatico>A1</IdSistemaInformatico>
<Version>5.1.531.1509</Version>
<NumeroInstalacion>001</NumeroInstalacion>
<TipoUsoPosibleSoloVerifactu>S</TipoUsoPosibleSoloVerifactu>
<TipoUsoPosibleMultiOT>N</TipoUsoPosibleMultiOT>
<IndicadorMultiplesOT>N</IndicadorMultiplesOT>
</SistemaInformatico>
<FechaHoraHusoGenRegistro>2024-10-25T16:10:58+02:00</FechaHoraHusoGenRegistro>
<TipoHuella>01</TipoHuella>
<Huella>402CCF9B22FDB0F599C80AA3D5B677423B63060D3E76DAF34E48D5D44A56662C</Huella>
</RegistroAlta>
</RegistroFactura>
</RegFactuSistemaFacturacion>

Da Ko, con el nuevo dice que justamente no se ha encontrado la cabecera en el envio...

Codigo[4102].El XML no cumple el esquema. Falta informar campo obligatorio.: Cabecera

Hbra que esperarse un par de dias a ver si actualizan?

[novatico]

Empezado por ermendalenda

Si alguno puede traducir donde se produce el cambio, a nivel del xml, se lo agradeceria, ya que yo genero los xlm a pelo y me cuesta muchisimo leer el xsd

Yo trabajo igual que tú, genero el XML "a pelo".
Para ayudarme, cada vez que publican cambios en la estructura, me descargo el "wsdl" y los "xsd", en una carpeta nueva y vacía cada vez, y usando "SoapUI", tal como explicó algún compañero en este mismo foro, se puede generar un "xml" a modo de plantilla, lo que permite revisar más facilmente.

[ermendalenda]

Empezado por novatico

Yo trabajo igual que tú, genero el XML "a pelo".
Para ayudarme, cada vez que publican cambios en la estructura, me descargo el "wsdl" y los "xsd", en una carpeta nueva y vacía cada vez, y usando "SoapUI", tal como explicó algún compañero en este mismo foro, se puede generar un "xml" a modo de plantilla, lo que permite revisar más facilmente.

Llevas razón , desde el inicio del hilo
ll han dicho varias veces. Me tengo que instalar la herramienta y aun no la he puesto

[ermendalenda]

Por cierto sabéis que significa esto

...entendiéndose la necesidad de generar y realizar validaciones registros de facturación de forma independientemente, sin necesidad de incluirlos en un envío para ello...

Puede ser que haya que quitar el encapsulamiento soap?

[bmfranky]

Hombre algo an cambiado.
Antes.

<Cabecera xmlns="https://www2.agenciatributaria.gob.es/static_files/common/internet/dep/aplicaciones/es/aeat/tike/cont/ws/SuministroInformacion.xsd">

Ahora.

<Cabecera xmlns="https://www2.agenciatributaria.gob.es/static_files/common/internet/dep/aplicaciones/es/aeat/tike/cont/ws/SuministroLR.xsd">

[ermendalenda]

Empezado por ermendalenda

Por cierto sabéis que significa esto

Puede ser que haya que quitar el encapsulamiento soap?

Ya lo he entendido.
Bufff me cuesta
Significa que necesitan validar el xml contra xsd o wdsl sin tener que enviar.. y con el nuevo esquema lo.permite.

[bmfranky]

Empezado por ermendalenda

Ya lo he entendido.
Bufff me cuesta
Significa que necesitan validar el xml contra xsd o wdsl sin tener que enviar.. y con el nuevo esquema lo.permite.

Osea, para verifica la estrucktura del envio e integridad antes de enviar... y para los pobres mortales como yo, eso como se hace??

[bmfranky]

Hola, alguien sabe que es esto ?

ServicioVerifactu.IdOperacionesTrascendenciaTributariaType

Otra cosa ahora an añadido suministro de factura...

EstadoRegistroSFType
AceptadaConErrorres
Anulada
Correcta

Se viene envio de facturas tambien ademas de los registros?

[ermendalenda]

Empezado por bmfranky

Osea, para verifica la estrucktura del envio e integridad antes de enviar... y para los pobres mortales como yo, eso como se hace??

Tienes que tener opciones de importarte el xml y validarlo contra el xsd cada sistema de desarrollo lo tiene: vb, php...
Las funciones te devuelven si es correcto o donde tiene algun error,.por ejemplo un formato numérico que.le falte algún decimal obligatorio en el esquema xsd... eso te da más tranquilidad al enviar por que haces una co.probacion previa,y ea lógico que hayan solicitado a verifactu que modifiquen el esquema por que no se podía validar sin enviar, y lo lógico es que se pueda validar previamente

[antoine0]

Empezado por ermendalenda

Si alguno puede traducir donde se produce el cambio, a nivel del xml, se lo agradeceria, ya que yo genero los xlm a pelo y me cuesta muchisimo leer el xsd

Hago dos cosas a cada cambio de XSD:

1. Comparo con la versión anterior; lo hago con la herramienta diff (de Unix) pero es solo por costumbre, cualquiera herramienta valga. Por ejemplo, ponerlos en un sistema de control de versión lo hace de manera automática.
2. Paso el XSD por una transformación en formato HTML, que me resulta muchísimo más sencillo de leer

Hay que pasar todos los esquemas involucrados en un determinado WSDL, y dejar los HTML en el mismo repertorio.

La transformación que uso está derivada de una que encontró hace años (y tiene aún más años) y que creo es de uso libre.

<?xml version="1.0" encoding="UTF-8"?>
<!-- Stylesheet for NHSiS Schemas - David Brazier 17/11/00
     Work in progress, free for use as-is.
     (C) Common Services Agency 2000
 Modifications (C) 2017-2024 Antoine Leca (free to use) -->
<xsl:stylesheet version="1.0"
		xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
		xmlns:xsd="http://www.w3.org/2001/XMLSchema">
<xsl:output encoding="UTF-8"/>
<xsl:strip-space elements="*"/>

	<xsl:template match="xsd:schema">
		<html>
			<head>
				<title>Schema: <xsl:value-of select="@targetNamespace"/>
				</title>
			</head>
			<style>
   table { border-collapse: collapse }
   td { vertical-align: top }
   </style>
			<!-- for testing:
   td { border: 1px solid blue; vertical-align: top }
-->
			<body>
				<h3>Schema: <xsl:value-of select="@targetNamespace"/></h3>
				<p>Version: <xsl:value-of select="@version"/>
				</p>
				<xsl:apply-templates/>
			</body>
		</html>
	</xsl:template>
	<xsl:template match="xsd:import">
		<hr/>
		<i>Import Schema <xsl:value-of select="@namespace"/> from 
		<a>
			<xsl:attribute name="href">
				<xsl:value-of select="@schemaLocation"/>.html
			</xsl:attribute>
			{<xsl:value-of select="@schemaLocation"/>}
		</a>
		</i>
	</xsl:template>

	<xsl:template match="xsd:element">
		<xsl:if test="..=/">
			<hr/>
		</xsl:if>
		<table>
			<tr>
				<td colspan="2">
					<b>
						<xsl:value-of select="@name"/>
					</b>
					 
					<xsl:if test="@type">
					: <a>
<!--
	<xsl:variable name="prefix" select="substring-before(name(), concat(':', local-name()) )"/>
 -->
						<xsl:variable name="prefix" select="substring-before(@type,':')"/>

						<xsl:variable name="ns" select="namespace::*[name()=$prefix]"/>
<!--
bug if name(.) contains a namespace... (= if #default namespace is NOT xsd)
Could check that namespace::*[name()=''] == "http://www.w3.org/2001/XMLSchema"
BUGBUG following does not work (double declaration?)
						<xsl:choose>
							<xsl:when test="contains(name(), ':')">
								<xsl:variable name="ns0" select="namespace::*[substring-after(name(.),':')=$prefix]"/>
							</xsl:when>
							<xsl:otherwise>
								<xsl:variable name="ns" select="namespace::*[name()=$prefix]"/>
							</xsl:otherwise>
						</xsl:choose>
 -->
						<xsl:choose>
							<xsl:when test="@type = 'string' or @type = 'double' ">
								<b><xsl:value-of select="@type"/></b>
							</xsl:when>
							<xsl:when test="not($prefix)">
								<xsl:attribute name="href">#<xsl:value-of select="@type"/></xsl:attribute>
								<b>!<xsl:value-of select="@type"/>!</b>
							</xsl:when>
							<xsl:when test="$ns=/xsd:schema/@targetNamespace">
								<xsl:attribute name="href">#<xsl:value-of select="substring-after(@type,':')"/></xsl:attribute>
							</xsl:when>
							<xsl:when test="/xsd:schema/xsd:import[@namespace=$ns]">
								<xsl:attribute name="href"><xsl:value-of select="/xsd:schema/xsd:import[@namespace=$ns]/@schemaLocation"/>.html#<xsl:value-of select="substring-after(@type,':')"/></xsl:attribute>
								{<xsl:value-of select="/xsd:schema/xsd:import[@namespace=$ns]/@schemaLocation"/>}
							</xsl:when>
						</xsl:choose>
						<xsl:value-of select="substring-after(@type,':')"/>
					</a>
					</xsl:if>
					(<xsl:choose>
						<xsl:when test="@minOccurs"><xsl:value-of select="@minOccurs"/></xsl:when>
						<xsl:otherwise>1</xsl:otherwise>
					</xsl:choose>-<xsl:choose>
						<xsl:when test="@maxOccurs"><xsl:value-of select="@maxOccurs"/></xsl:when>
						<xsl:otherwise>1</xsl:otherwise>
					</xsl:choose>)
				</td>
			</tr>
			<tr>
				<td width="25"/>
				<td>
					<xsl:apply-templates select="*"/>
				</td>
			</tr>
		</table>
	</xsl:template>

	<xsl:template match="xsd:simpleType">
		<xsl:if test="..=/">
			<hr/>
		</xsl:if>
		<table>
			<xsl:attribute name="id">
				<xsl:value-of select="@name"/>
			</xsl:attribute>
			<tr>
				<td colspan="2">
					<i>type </i><b>
						<xsl:value-of select="@name"/>
					</b>:
					 <xsl:value-of select="@type"/>
				</td>
			</tr>
			<tr>
				<td width="25"/>
				<td>
					<xsl:apply-templates select="*"/>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template match="xsd:complexType">
		<xsl:if test="..=/">
			<hr/>
		</xsl:if>
		<table>
			<xsl:if test="@name">
			<xsl:attribute name="id">
				<xsl:value-of select="@name"/>
			</xsl:attribute>
			<tr>
				<td colspan="2">
					<i>type </i><b>
						<xsl:value-of select="@name"/>
					</b>:
					 <xsl:value-of select="@type"/>
				</td>
			</tr>
			</xsl:if><!-- test="@name" -->
			<tr>
				<td width="25"/>
				<td>
					<xsl:apply-templates select="*"/>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template match="xsd:sequence">
		<xsl:if test="..=/">
			<hr/>
		</xsl:if>
		<table>
			<tr>
				<td width="25" style="border-right: 1px solid black"/>
				<td>
					<xsl:apply-templates select="*"/>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template match="xsd:choice">
		<xsl:if test="..=/">
			<hr/>
		</xsl:if>
		<table>
			<tr>
				<td width="25" style="vertical-align: middle; border-right: double black">
				choice
				</td>
				<td>
					<xsl:apply-templates select="*"/>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template match="xsd:extension">
		<i>extends </i> 
		<xsl:variable name="prefix" select="substring-before(@base,':')"/>
		<xsl:variable name="ns" select="namespace::*[name()=$prefix]"/>
		<a>
		<xsl:choose>
			<xsl:when test="@base = 'string' or @base = 'double' ">
			<!-- bug: missing @href; can we simply drop it? -->
				<b><xsl:value-of select="@base"/></b>
			</xsl:when>
			<xsl:when test="not($prefix)">
				<xsl:attribute name="href">#<xsl:value-of select="@base"/></xsl:attribute>
				<xsl:value-of select="@base"/>
			</xsl:when>
			<xsl:when test="$ns=/xsd:schema/@targetNamespace">
				<xsl:attribute name="href">#<xsl:value-of select="substring-after(@base,':')"/></xsl:attribute>
				<xsl:value-of select="substring-after(@base,':')"/>
			</xsl:when>
			<xsl:when test="/xsd:schema/xsd:import[@namespace=$ns]">
				<xsl:attribute name="href"><xsl:value-of select="/xsd:schema/xsd:import[@namespace=$ns]/@schemaLocation"/>.html#<xsl:value-of select="substring-after(@base,':')"/></xsl:attribute>
				{<xsl:value-of select="/xsd:schema/xsd:import[@namespace=$ns]/@schemaLocation"/>}
				<xsl:value-of select="substring-after(@base,':')"/>
			</xsl:when>
		</xsl:choose>
		</a>
		<xsl:apply-templates select="*"/>
	</xsl:template>

	<xsl:template match="xsd:restriction">
		<xsl:choose>
			<xsl:when test="contains(@base, ':')">
				<xsl:variable name="prefix" select="substring-before(@base,':')"/>
				<xsl:variable name="ns" select="namespace::*[name()=$prefix]"/>
		<i>is new </i> 
		<a>
				<xsl:choose>
					<xsl:when test="@base = 'string' or @base = 'double' ">
						<b><xsl:value-of select="@base"/></b>
					</xsl:when>
					<xsl:when test="not($prefix)">
						<xsl:attribute name="href">#<xsl:value-of select="@base"/></xsl:attribute>
						<xsl:value-of select="@base"/>
					</xsl:when>
					<xsl:when test="$ns=/xsd:schema/@targetNamespace">
						<xsl:attribute name="href">#<xsl:value-of select="substring-after(@base,':')"/></xsl:attribute>
						<xsl:value-of select="substring-after(@base,':')"/>
					</xsl:when>
					<xsl:when test="/xsd:schema/xsd:import[@namespace=$ns]">
						<xsl:attribute name="href"><xsl:value-of select="/xsd:schema/xsd:import[@namespace=$ns]/@schemaLocation"/>.html#<xsl:value-of select="substring-after(@base,':')"/></xsl:attribute>
						{<xsl:value-of select="/xsd:schema/xsd:import[@namespace=$ns]/@schemaLocation"/>}
						<xsl:value-of select="substring-after(@base,':')"/>
					</xsl:when>
				</xsl:choose>
		</a>  
			</xsl:when>
			<xsl:when test="./xsd:enumeration">
			<!-- nothing -->
			</xsl:when>
			<xsl:otherwise>
				<i>&lt;<xsl:value-of select="@base"/>&gt;</i>  
			</xsl:otherwise>
		</xsl:choose>
		<xsl:apply-templates select="*"/>
	</xsl:template>
	<xsl:template match="xsd:length">
		[<xsl:value-of select="@value"/>]
	</xsl:template>
	<xsl:template match="xsd:minLength">
		[<xsl:value-of select="@value"/> ..
	</xsl:template>
	<xsl:template match="xsd:maxLength">
		<!-- add [0.. if there are no minLength -->
		<xsl:if test="not(../xsd:minLength)">[0..</xsl:if>
		<xsl:value-of select="@value"/>]
	</xsl:template>
	<xsl:template match="xsd:enumeration">
		"<xsl:value-of select="@value"/>"
		<xsl:apply-templates select="*"/>
	</xsl:template>
	<xsl:template match="xsd:pattern">
		<i> like </i>/<xsl:value-of select="@value"/>/
		<xsl:apply-templates select="*"/>
	</xsl:template>
	<xsl:template match="xsd:annotation">
		<xsl:for-each select="xsd:documentation">
			<small>
				<xsl:value-of select="."/>
			</small>
			<br/>
		</xsl:for-each>
		<xsl:for-each select="xsd:appinfo">
			<small>
				<i>
					<xsl:value-of select="."/>
				</i>
			</small>
			<br/>
		</xsl:for-each>
	</xsl:template>
</xsl:stylesheet>

Si los moderadores lo consideran oportuno, se puede recortar el código, ponerlo análisis de sintaxis XML, o mover este post a otro hilo más adecuado.