Problema con archivo .csv y campos en blanco en StringGrid

[Jetzuvely21]

Hola a todos!!

Escribo para preguntarles sobre una duda que me ha traido de cabeza, he leido ya los post e hilos del foro en lo que refiere a importar archivos a delphi. Estoy programando en Delphi5 y archivos .csv .Ya tengo la importación, mi problema ahora radica en que si tengo en mi archivo:

1,18042012,Abono,15,00,6446,,FMC1998I,464.00,00075272,
2,18042012,Abono,07,32,6446,,,464.00,0.00,00075272,

En mi StringGrid los datos los mueve de columna por los campos en blanco. He probado
la función de:

Código Delphi [-]
ExtractStrings([','],[], PChar(Strings[i]), StringGrid1.Rows[i]);

para los delimitadores y si funciona bien cuando tengo todos los campos completos.

Todo lo que hasta ahorita llevo lo he aprendido de este maravilloso Foro y de los hilos que muchos de los usuarios han posteado, asi como las sugerencias y dudas que han tenido, los cuales me han servido de mucho y ayudado también, pero no sé como poder resolver esto =(.

El archivo .csv me lo pasan así con esos datos y campos.

Espero de verdad me puedan orientar y ayudar, ¡se los agradeceria mucho!

Saludos, Karen

[ecfisa]

Hola Karen.

Espero haberte entendido bién, proba si te funciona de este modo:

Código Delphi [-]
procedure PasarAStrGrd(const Cad: string; const aRow: Integer; aGrid: TStringGrid);
var
  i: Integer;
  TS: TStrings;
begin
  with TStringList.Create do
  try
    DelimitedText:= Cad;
    Delimiter:= ',';
    for i:= Count-1 downto 0 do
      if Strings[i] = '' then 
        Strings[i] := ' ';   
    aGrid.ColCount:= Count-1; // (*)    
    for i:= 0 to Count-1 do
      aGrid.Cells[i + aGrid.FixedCols, aRow]:= Strings[i];
  finally
    Free;
  end;
end;

Llamada de prueba:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var
  Cadena: string;
begin
  Cadena:= '1,18042012,Abono,15,00,6446,,FMC1998I,464.00,00075272,2,18042012,Abono,07,32,6446,,464.00,0.00,0007  5272,';
  PasarAStrGrd(Cadena , 1, StringGrid1);
end;

Saludos.

Edito: (*) Esta línea la usé para garantizar que existan en el StringGrid tantas columnas como campos se le envían. La podés quitar si ya tenes definido con anterioridad cuantas columnas serán. ( si hay algo en lo que no fuí claro por favor decime )

[Casimiro Noteví]

¿Y exactamente el problema que tienes cual es?

[Jetzuvely21]

Probé lo que me sugeriste, pero me marca error:

[Error] Unit1.pas(386): Undeclared identifier: 'DelimitedText'

Tengo entendido que StringList pertenece a la clase TStrings de la unidad Classes.

Pero no me acepta el DelimitedText :S

[Jetzuvely21]

Originally Posted by Casimiro Notevi

¿Y exactamente el problema que tienes cual es?

Gracias por interesarte, lo que pasa es que al leer mi archivo .csv tengo algunos campos en blanco
como puse en un principio:

1,18042012,Abono,15,00,6446,,FMC1998I,464.00,00075272,
2,18042012,Abono,07,32,6446,,,464.00,0.00,00075272,

y al mostrarlos en el StringGrid me los pone en la columna que no corresponde, es decir los recorre a la izquierda.

[ecfisa]

Hola Karen.

No sé por que te puede estar mostrando ese error, pero para que controles con tranquilidad te adjunto un ejemplo muy simple que me funciona correctamente.


Saludos.

[Jetzuvely21]

Originally Posted by ecfisa

Hola Karen.

No sé por que te puede estar mostrando ese error, pero para que controles con tranquilidad te adjunto un ejemplo muy simple que me funciona correctamente.

Saludos.

Gracias de nuevo ecfisa, me marca que me falta la unidad "Variants.dcu". ¿Sería mucha molestia que me pudieras indicar dónde la puedo obtener?

Te agradezco tu atención y tiempo. =)

[ecfisa]

Hola Karen.

Fijate en las líneas:

Código Delphi [-]
uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids;

Si no figura Variants, como es el caso de arriba, sólo agregalo:

Código Delphi [-]
uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, Grids ,Variants;

Saludos.

[Jetzuvely21]

Gracias Ecfisa,

Hice lo siguiente: abri en delphi el zip que me enviaste, al tratar de compilar me marcaba que la unidad Variants no se encontraba, aun así la comenté del uses, y me volvio a marcar el error que te comenté hace rato:

[Error] Unit1.pas(386): Undeclared identifier: 'DelimitedText'

Investigando un poco dentro de los hilos del foro, parece ser que la unidad Variants para Delphi5 no está disponible, solo para Delphi6 en adelante.

Por otra parte tambien investigué la propiedad DelimitedText del StringList porque en el la clase TStrings que tengo no me aparece y me encontré que para Delphi5 tampoco está incluida

¿Qué puedo hacer? gracias mil nuevamente por contestarme

[ecfisa]

Hola Karen.

Y bueno... si no la trae, no nos queda más remedio que hacerla

Una opción para que pruebes si funciona en Delphi 5:

Código Delphi [-]
...
(* Esta función reemplaza a DelimitedText/Delimiter *)
function SplitString(Cadena: string; const Delimitadores: string): TStrings;
var
  c,i,p:Integer;
  s: string;
begin
  Result:= TStringList.Create;
  Cadena:= Cadena+Delimitadores[1];
  c:= 0;
  p:= 1;
  for i:= 1 to Length(Cadena) do
  begin
    if Pos(Cadena[i], Delimitadores) <> 0 then
    begin
      s:= Copy(Cadena, p, i-p);
      Result.Add(s);
      p:= i + 1;
      Inc(c);
    end;
  end;
end;

(* Separar por comas *)
procedure PasarAStrGrd(const Cad: string; const aRow: Integer; aGrid: TStringGrid);
var
  i: Integer;
  TS: TStrings;
begin
  TS:= TStringList.Create;
  try
    TS:= SplitString(Cad, ',');  // Aca la llamamos con el delimitador ','
    for i:= 0 to TS.Count-1 do
      aGrid.Cells[i + aGrid.FixedCols, aRow]:= TS[i];
  finally
    TS.Free;
  end;
end;

Llamada de ejemplo:

Código Delphi [-]
procedure TForm1.Button1Click(Sender: TObject);
var
  Cadena: string;
begin
  Cadena:= '1,18042012,Abono,15,00,6446,,FMC1998I,464.00,00075272,2,18042012,Abono,07,32,6446,,464.00,0.00,0007  5272,';
  PasarAStrGrd(Cadena , 1, StringGrid1);
end;

La función que hice tiene la ventaja que podés pasarle varios delimitadores, por ejemplo:

Código Delphi [-]
  Cadena:= 'ho.la,m/un do';
  ListBox1.Items:= SplitString(Cadena, ', -./');

Saludos.

[Jetzuvely21]

Hola de nuevo ecfisa, tardé en contestar porque estuve probando lo que tuviste atención de ayudarme (;, tuve algunos detalles para mostrar en mi grid el archivo cargado. Porque me lo mostraba todo en una sola línea....aunque si me respetaba mis campos en blanco.

Tras otras pruebas y modificaciónes, me encontré con una cadena dentro de mi archivo :

6,18042012,Abono,13,00,666,,,"8,671.00",06666666,

Y con la solución que me enviaste, me ponia en una columna "8 y en otra 671.00 porque
el delimitador es la "," esto teoricamente estaba bien porque respetaba el delimitador, pero en mi caso estaba mal porque es una cantidad completa...

Lo que hice fue lo siguiente :

Código Delphi [-]
procedure TForm1.BAbrirClick(Sender: TObject);
function ExtractStrings1(Separators, WhiteSpace: TSysCharSet; Content: PChar;
  Strings: TStrings): Integer;
var
  Head, Tail: PChar;
  EOS, InQuote: Boolean;
  QuoteChar: Char;
  Item: string;
begin
  Result := 0;
  if (Content = nil) or (Content^=#0) or (Strings = nil) then Exit;
  Tail := Content;
  InQuote := False;
  QuoteChar := #0;

  Strings.BeginUpdate;
  try
    repeat
      while Tail^ in WhiteSpace + [#13, #10] do Inc(Tail);
      Head := Tail;
      while True do
      begin
        while (InQuote and not (Tail^ in ['''', '"', #0])) or
          not (Tail^ in Separators + [#0, #13, #10, '''', '"']) do Inc(Tail);
        if Tail^ in ['''', '"'] then
        begin
          if (QuoteChar <> #0) and (QuoteChar = Tail^) then
            QuoteChar := #0
          else QuoteChar := Tail^;
          InQuote := QuoteChar <> #0;
          Inc(Tail);
        end else Break;
      end;
      EOS := Tail^ = #0;
      if (Head <> Tail) and (Head^ <> #0) then
      begin
        if Strings <> nil then
        begin
          SetString(Item, Head, Tail - Head);
          Strings.Add(Item);
        end;
        Inc(Result);
      end
      else
      begin
        Strings.Add(' ');
      end;
      Inc(Tail);
    until EOS;
  finally
    Strings.EndUpdate;
  end;
end;

Var
  i, filas : Integer;
  Fichero : TStringList;
  cadena : String;
  const SaltoLinea = #13#10;
begin
  If ODArchivo.Execute Then Begin
    Fichero := Nil;
    Try
      Fichero := TStringList.Create;
      Fichero.LoadFromFile(ODArchivo.FileName);
      filas  := Fichero.Count;
      SGDatos.RowCount := filas;
      filas := filas - 1;
      for i:= 0 to filas do begin
        ExtractStrings1([','], [' '], PChar(Fichero[i]), SGDatos.Rows[i]);
      end;
    Finally
      Fichero.Free;
    End;
  End;
end;

Hice una pequeña modificacion a la funcion ExtractStrings original. Como te puedes dar cuenta en la linea

Strings.Add(' ');

.

Y asi me muestra ya mis campos como en el excel. ¿Crees que no tenga problema alguno con datos posteriores, el haber hecho esa modificación en la función? :S

Espero tu valioso comentario.

Un gran saludo y muchas gracias por demostrar tu interés y ayuda. Si tienes alguna observación o comentario para que mejore este asunto, te lo agradeceré demás.

P.D.:El archivo con datos incompletos es similar a este (.csv):

No. Cliente:,22222222,
Nombre del Cliente:,INTERNACIONAL,
Fecha de la Consulta:,19042012,
Total de Cuentas:,1,
Movimientos,18042012,
Movimientos de Cargos:,0,
Movimientos de Abonos:,15,
Resumen General,
Nombre de la Cuenta:,F NORMAL,
Sucursal:,0000,
Cuenta:,'1111111',
Moneda:,Pesos,
Saldo Inicial:,+,"44,142.10",
Saldo Final:,+,"199,222.41",
Total de Número de Cargos:,0,
Total de Cargos:,0.00,
Total de Número de Abonos:,15,
Total de Abonos:,"150,377.36",
Detalle de Movimientos:,
Num,Fecha,Tipo,Código,Subcódigo,Sucursal,Referencia Numérica,Referencia Alfanumérica,Importe,Autorización,
1,18042012,Abono,15,00,1111,,FMC1111I,464.00,88888888,
2,18042012,Abono,07,32,2222,,464.00,0.00,99999999,
3,18042012,Abono,15,00,3333,,FMC10111,464.00,66666666,
4,18042012,Abono,07,32,4444,,464.00,0.00,88888888,
5,18042012,Abono,71,01,555,2222222,AUT. 11111 SER ELEC.,"103,000.00",01222222,
6,18042012,Abono,13,00,666,,,"8,671.00",06666666,
7,18042012,Abono,13,00,777,,,"3,389.06",03333333,
8,18042012,Abono,11,03,888,,,"4,841.06",02222222,
9,18042012,Abono,07,32,999,,"4,841.06",0.00,14444444,
10,18042012,Abono,11,03,000,,,"9,349.89",14444444,
11,18042012,Abono,07,32,777,,"9,349.89",0.00,15555555,
12,18042012,Abono,11,03,888,,,"4,951.44",18888888,
13,18042012,Abono,07,32,999,,"4,951.44",0.00,19999999,
14,18042012,Abono,13,00,666,,,"8,246.91",14444444,
15,18042012,Abono,11,00,555,,,"7,000.00",17777777,

[ecfisa]

Hola Jetzuvely21.

¿Crees que no tenga problema alguno con datos posteriores, el haber hecho esa modificación en la función?

Si te está funcionando bién dudo que te dé problemas.

Es posible que si cambian algún formato al guardar, o encuentras alguna ocurrencia no prevista, tengas que retocar el código, pero teniéndolo ya tán avanzado no serán cambios mayores.

Saludos.

[Jetzuvely21]

Gracias por responderme tan pronto. (=

Si ahorita solo ando revisando formateo de campos una que otra validación, pero si anda bien.

Agradezco ampliamente tu atención y colaboración.

Un enorme saludo!

^^